Detect host and port number from babashka nREPL conn msg (#3087)

Author: ikappaki

nrepl-client.el

@@ -1043,6 +1043,20 @@ been determined."
                (propertize cmd 'face 'font-lock-keyword-face))
       serv-proc)))
 
+(defconst nrepl-listening-address-regexp
+  (rx (or
+       ;; standard
+       (and "nREPL server started on port " (group-n 1 (+ (any "0-9"))))
+       ;; babashka
+       (and "Started nREPL server at "
+            (group-n 2 (+? any)) ":" (group-n 1 (+ (any "0-9"))))))
+  "A regexp to search an nREPL's stdout for the address it is listening on.
+
+If it matches, the address components can be extracted using the following
+match groups:
+1  for the port, and
+2  for the host (babashka only).")
+
 (defun nrepl-server-filter (process output)
   "Process nREPL server output from PROCESS contained in OUTPUT."
   ;; In Windows this can be false:
@@ -1062,10 +1076,12 @@ been determined."
               (set-window-point win (point)))))
         ;; detect the port the server is listening on from its output
         (when (and (null nrepl-endpoint)
-                   (string-match "nREPL server started on port \\([0-9]+\\)" output))
-          (let ((port (string-to-number (match-string 1 output))))
-            (setq nrepl-endpoint (list :host (or (file-remote-p default-directory 'host)
-                                                 "localhost")
+                   (string-match nrepl-listening-address-regexp output))
+          (let ((host (or (match-string 2 output)
+                          (file-remote-p default-directory 'host)
+                          "localhost"))
+                (port (string-to-number (match-string 1 output))))
+            (setq nrepl-endpoint (list :host host
                                        :port port))
             (message "[nREPL] server started on %s" port)
             (when nrepl-on-port-callback

test/nrepl-client-tests.el

@@ -111,6 +111,32 @@
         (expect (nrepl-make-buffer-name "*buff-name %r:%S*" params)
                 :to-equal "*buff-name cljs*")))))
 
+(describe "nrepl-parse-port"
+  (it "standard"
+      (let ((msg "nREPL server started on port 58882 on host kubernetes.docker.internal - nrepl://kubernetes.docker.internal:58882"))
+        (expect (string-match nrepl-listening-address-regexp msg)
+                :not :to-be nil)
+        (expect (match-string 1 msg)
+                :to-equal "58882")
+        (expect (match-string 2 msg)
+                :to-be nil)))
+  (it "babashka"
+      (let ((msg "Started nREPL server at 127.0.0.1:1667"))
+        (expect (string-match nrepl-listening-address-regexp msg)
+                :not :to-be nil)
+        (expect (match-string 1 msg)
+                :to-equal "1667")
+        (expect (match-string 2 msg)
+                :to-equal "127.0.0.1")))
+    (it "shadow"
+      (let ((msg "shadow-cljs - nREPL server started on port 50999"))
+        (expect (string-match nrepl-listening-address-regexp msg)
+                :not :to-be nil)
+        (expect (match-string 1 msg)
+                :to-equal "50999")
+        (expect (match-string 2 msg)
+                :to-be nil))))
+
 (describe "nrepl-client-lifecycle"
   (it "start and stop nrepl client process"