[Fix #3179] Introduce cider-jack-in-universal command (#3300)

ikappaki · web-flow · commit ec31a4614bf6 · 2023-02-05T07:43:10.000+01:00
It supports jacking-in without a project from a set of pre-configured Clojure project tools. The new command can also be used for both Clojure and ClojureScript (and potentially other platforms down the road).
diff --git a/CHANGELOG.md b/CHANGELOG.md
@@ -8,6 +8,7 @@
 - [#3262](https://github.com/clojure-emacs/cider/issues/3262): Add navigation functionality to `npfb` keys inside the data inspector's buffer.
 - [#3310](https://github.com/clojure-emacs/cider/issues/3310): Add ability to use custom coordinates in jack-in-dependencies.
 * [#766](https://github.com/clojure-emacs/cider-nrepl/issues/766): Complete local bindings for ClojureScript files.
+- [#3179](https://github.com/clojure-emacs/cider/issues/3179): Introduce `cider-jack-in-universal` to support jacking-in without a project from a set of pre-configured Clojure project tools.
 
 ### Changes
 
diff --git a/cider.el b/cider.el
@@ -86,6 +86,7 @@
 (require 'cider-debug)
 (require 'cider-util)
 
+(require 'cl-lib)
 (require 'tramp-sh)
 (require 'subr-x)
 (require 'seq)
@@ -346,6 +347,26 @@ Sub-match 1 must be the project path.")
 (defvar cider-host-history nil
   "Completion history for connection hosts.")
 
+(defvar cider-jack-in-universal-options
+  '((clojure-cli (:prefix-arg 1 :cmd (:jack-in-type clj  :project-type babashka :edit-project-dir t)))
+    (lein        (:prefix-arg 2 :cmd (:jack-in-type clj  :project-type clojure-cli :edit-project-dir t)))
+    (babashka    (:prefix-arg 3 :cmd (:jack-in-type clj  :project-type lein :edit-project-dir t)))
+    (nbb         (:prefix-arg 4 :cmd (:jack-in-type cljs :project-type nbb :cljs-repl-type nbb :edit-project-dir t))))
+  "The list of project tools that are supported by the universal jack in command.
+
+Each item in the list consists of the tool name and its plist options.
+
+The plist supports the following keys
+
+- :prefix-arg the numerical prefix arg to use to jack in to the tool.
+
+- :cmd a plist of instructions how to invoke the jack in command, with keys
+
+  - :jack-in-type 'clj to start a clj repl and 'cljs for a cljs repl.
+
+  - &rest the same set of params supported by the `cider-jack-in-clj' and
+    `cider-jack-in-cljs' commands.")
+
 ;;;###autoload
 (defun cider-version ()
   "Display CIDER's version."
@@ -1169,6 +1190,7 @@ nil."
     (define-key map (kbd "j j") #'cider-jack-in-clj)
     (define-key map (kbd "j s") #'cider-jack-in-cljs)
     (define-key map (kbd "j m") #'cider-jack-in-clj&cljs)
+    (define-key map (kbd "j u") #'cider-jack-in-universal)
     (define-key map (kbd "C-j j") #'cider-jack-in-clj)
     (define-key map (kbd "C-j s") #'cider-jack-in-cljs)
     (define-key map (kbd "C-j m") #'cider-jack-in-clj&cljs)
@@ -1393,9 +1415,15 @@ non-nil, don't start if ClojureScript requirements are not met."
         (t params)))
 
 (defun cider--update-project-dir (params)
-  "Update :project-dir in PARAMS."
+  "Update :project-dir in PARAMS.
+
+Params is a plist with the following keys (non-exhaustive)
+
+ :edit-project-dir prompt (optional) ask user to confirm the project root
+ directory."
   (let* ((params (cider--update-do-prompt params))
-         (proj-dir (if (plist-get params :do-prompt)
+         (proj-dir (if (or (plist-get params :do-prompt)
+                           (plist-get params :edit-project-dir))
                        (read-directory-name "Project: "
                                             (clojure-project-dir (cider-current-dir)))
                      (plist-get params :project-dir)))
@@ -1460,10 +1488,17 @@ non-nil, don't start if ClojureScript requirements are not met."
     (format "-encodedCommand %s" (base64-encode-string utf-16le-command t))))
 
 (defun cider--update-jack-in-cmd (params)
-  "Update :jack-in-cmd key in PARAMS."
+  "Update :jack-in-cmd key in PARAMS.
+
+PARAMS is a plist with the following keys (non-exhaustive list)
+
+:project-type optional, the project type to create the command for; see
+`cider-jack-in-command' for the list of valid types)."
   (let* ((params (cider--update-do-prompt params))
          (project-dir (plist-get params :project-dir))
-         (project-type (cider-project-type project-dir))
+         (params-project-type (plist-get params :project-type))
+         (project-type (or params-project-type
+                           (cider-project-type project-dir)))
          (command (cider-jack-in-command project-type))
          (command-resolved (cider-jack-in-resolve-command project-type))
          (command-global-opts (cider-jack-in-global-options project-type))
@@ -1484,7 +1519,8 @@ non-nil, don't start if ClojureScript requirements are not met."
                           (eq cider-allow-jack-in-without-project t)
                           (and (null project-dir)
                                (eq cider-allow-jack-in-without-project 'warn)
-                               (y-or-n-p "Are you sure you want to run `cider-jack-in' without a Clojure project? ")))
+                               (or params-project-type
+                                   (y-or-n-p "Are you sure you want to run `cider-jack-in' without a Clojure project? "))))
                   (let ((cmd (format "%s %s" command-resolved (if (or (string-equal command "powershell")
                                                                       (string-equal command "pwsh"))
                                                                   (cider--powershell-encode-command cmd-params)
@@ -1767,6 +1803,55 @@ PROJECT-DIR defaults to the current project."
           ;; 0.18, therefore the need for `cider-maybe-intern'
           (t (cider-maybe-intern cider-jack-in-default)))))
 
+;;;###autoload
+(defun cider-jack-in-universal (arg)
+  "Start and connect to an nREPL server for the current project or ARG project id.
+
+If a project is found in current dir, call `cider-jack-in' passing ARG as
+first parameter, of which see.  Otherwise, ask user which project type to
+start an nREPL server and connect to without a project.
+
+But if invoked with a numeric prefix ARG, then start an nREPL server for
+the project type denoted by ARG number and connect to it, even if there is
+no project for it in the current dir.
+
+The supported project tools and their assigned numeric prefix ids are
+sourced from `cider-jack-in-universal-options', of which see.
+
+You can pass a numeric prefix argument n with `M-n` or `C-u n`.
+
+For example, to jack in to leiningen which is assigned to prefix arg 2 type
+
+M-2 \\[cider-jack-in-universal]."
+  (interactive "P")
+  (let ((cpt (clojure-project-dir (cider-current-dir))))
+    (if (or (integerp arg) (null cpt))
+        (let* ((project-types-available (mapcar #'car cider-jack-in-universal-options))
+               (project-type (if (null arg)
+                                 (intern (completing-read
+                                          "No project found in current dir, select project type to jack in: "
+                                          project-types-available
+                                          nil t))
+
+                               (or (seq-some (lambda (elt)
+                                               (cl-destructuring-bind
+                                                   (project-type (&key prefix-arg &allow-other-keys)) elt
+                                                 (when (= arg prefix-arg)
+                                                   project-type)))
+                                             cider-jack-in-universal-options)
+                                   (error ":cider-jack-in-universal :unsupported-prefix-argument %S :no-such-project"
+                                          arg))))
+               (project-options (cadr (seq-find (lambda (elt) (equal project-type (car elt)))
+                                                cider-jack-in-universal-options)))
+               (jack-in-opts (plist-get project-options :cmd))
+               (jack-in-type (plist-get jack-in-opts :jack-in-type)))
+          (pcase jack-in-type
+            ('clj (cider-jack-in-clj jack-in-opts))
+            ('cljs (cider-jack-in-cljs jack-in-opts))
+            (_ (error ":cider-jack-in-universal :jack-in-type-unsupported %S" jack-in-type))))
+
+      (cider-jack-in-clj arg))))
+
 
 ;; TODO: Implement a check for command presence over tramp
 (defun cider--resolve-command (command)
diff --git a/doc/modules/ROOT/pages/basics/up_and_running.adoc b/doc/modules/ROOT/pages/basics/up_and_running.adoc
@@ -125,6 +125,57 @@ but was subsequently switched to `clj`, Clojure's basic startup command.
 TIP: You can set `cider-allow-jack-in-without-project` to `t` if you'd like to
 disable the warning displayed when jacking-in outside a project.
 
+==== Universal jack-in
+
+`cider-jack-in-universal` kbd:[C-c C-x j u] is another way to quickly
+jack in without a project choosing from a list of pre-configured
+Clojure build tools. When this command is called from outside of a
+project, the user is given the option to select to jack in with one of
+the pre-configured tools, as well as to confirm the root directory to
+use as a base. If the command is called from within a project
+directory, it behaves exactly the same as `cider-jack-in` does.
+
+It utilizes Emacs's
+https://www.gnu.org/software/emacs/manual/html_node/elisp/Prefix-Command-Arguments.html[numeric
+prefix arguments] to quickly jack in to a project type. Numeric prefix
+arguments can be set with the Meta key followed by a number.
+
+The following clojure build tools are supported so far
+
+- kbd:[M-1 C-c C-x j u] jack-in using clojure-cli.
+- kbd:[M-2 C-c C-x j u] jack-in using leiningen.
+- kbd:[M-3 C-c C-x j u] jack-in using babashka.
+- kbd:[M-4 C-c C-x j u] jack-in using nbb.
+
+Here is an example of how to bind F12 for quickly bringing up a
+babashka REPL:
+
+[source,lisp]
+----
+(global-set-key (kbd "<f12>") (lambda ()
+                                (interactive)
+                                (cider-jack-in-universal 3)))
+----
+
+The list of available build tools to consider is configured in
+`cider-jack-in-universal-options`. Each element of the list consists
+of the tool name and its setup options. Taking `nbb` as an example
+from the list:
+
+[source,lisp]
+----
+(nbb         (:prefix-arg 4 :cmd (:jack-in-type cljs :project-type nbb :cljs-repl-type nbb :edit-project-dir t)))
+----
+
+with
+
+. `:prefix-arg` assigns the `nbb` tool name a numerical argument prefix of 4.
+. `:cmd` how to invoke the command.
+.. `:jack-in-type` use a `cljs` repl.
+.. `:project-type` use `nbb` (see `jack-in-command`) to bring up the nREPL server.
+.. `:cljs-repl-type` client uses the `nbb` cljs repl type (see `cider-cljs-repl-types`) to initialize server.
+.. `:edit-project-dir` ask the user to confirm root directory to use as base.
+
 === Customizing the Jack-in Command Behavior
 
 You can use kbd:[C-u M-x] `cider-jack-in` kbd:[RET] to
diff --git a/test/integration/integration-tests.el b/test/integration/integration-tests.el
@@ -263,7 +263,7 @@
               (cider-itu-poll-until (eq (gv-deref client-is-connected*) 'connected) 5)
 
               ;; give it some time to setup the clj REPL
-              (cider-itu-poll-until (cider-repls 'clj nil) 5)
+              (cider-itu-poll-until (cider-repls 'cljs nil) 5)
 
               ;; send command to the REPL, and push stdout/stderr to
               ;; corresponding eval-xxx variables.
@@ -393,7 +393,144 @@
                    (with-temp-buffer
                      (insert-file-contents "nrepl-mdlw-log.log")
                      (message ":ikappaki/nrepl-mdlw-log-dump\n%s\n" (buffer-string)))
-                 (message ":!nrepl-mdlw-log-found"))))))))))
+                 (message ":!nrepl-mdlw-log-found")))))))))
+
+  ;; jacking in without a current project
+  ;;
+  (it "no project, user choice to nbb"
+    (with-cider-test-sandbox
+      (with-temp-dir temp-dir
+        ;; setup empty project dir
+        (let* ((project-dir temp-dir))
+          ;; fake user input
+          (spy-on 'completing-read
+                  :and-call-fake (lambda (prompt _collection &optional _predicate _require-match
+                                                 initial-input _hist _def _inherit-input-method)
+                                   (pcase prompt
+                                     ;; select nbb
+                                     ("No project found in current dir, select project type to jack in: "
+                                      "nbb")
+                                     ;; project src directory, use suggested
+                                     ("Project: " initial-input)
+                                     (_ (error ":integration-test-unsupported-prompt-error %S" prompt)))))
+
+          (with-temp-buffer
+            ;; set default directory to temp project
+            (setq-local default-directory project-dir)
+
+            (let* (;; Get a gv reference so as to poll if the client has
+                   ;; connected to the nREPL server.
+                   (client-is-connected* (cider-itu-nrepl-client-connected-ref-make!))
+
+                   ;; jack in and get repl buffer
+                   (nrepl-proc (cider-jack-in-universal '()))
+                   (nrepl-buf (process-buffer nrepl-proc)))
+
+              ;; wait until the client has successfully connected to the
+              ;; nREPL server.
+              (cider-itu-poll-until (eq (gv-deref client-is-connected*) 'connected) 5)
+
+              ;; give it some time to setup the clj REPL
+              (cider-itu-poll-until (cider-repls 'cljs nil) 5)
+
+              ;; send command to the REPL, and push stdout/stderr to
+              ;; corresponding eval-xxx variables.
+              (let ((repl-buffer (cider-current-repl))
+                    (eval-err '())
+                    (eval-out '()))
+                (expect repl-buffer :not :to-be nil)
+
+                ;; send command to the REPL
+                (cider-interactive-eval
+                 ;; ask REPL to return a string that uniquely identifies it.
+                 "(print :nbb? (some? (nbb.core/version)))"
+                 (lambda (return)
+                   (nrepl-dbind-response
+                       return
+                       (out err)
+                     (when err (push err eval-err))
+                     (when out (push out eval-out)))) )
+
+                ;; wait for a response to come back.
+                (cider-itu-poll-until (or eval-err eval-out) 5)
+
+                ;; ensure there are no errors and response is as expected.
+                (expect eval-err :to-equal '())
+                (expect eval-out :to-equal '(":nbb? true"))
+
+                ;; exit the REPL.
+                (cider-quit repl-buffer)
+
+                ;; wait for the REPL to exit
+                (cider-itu-poll-until (not (eq (process-status nrepl-proc) 'run)) 5)
+                (expect (member (process-status nrepl-proc) '(exit signal))))))))))
+
+  (it "no project, numeric prefix argument, to leiningen"
+    (with-cider-test-sandbox
+      (with-temp-dir temp-dir
+        ;; setup empty dir
+        (let* ((project-dir temp-dir))
+          ;; fake user input
+          (spy-on 'completing-read
+                  :and-call-fake (lambda (prompt _collection &optional _predicate _require-match
+                                                 initial-input _hist _def _inherit-input-method)
+                                   (pcase prompt
+                                     ;; project src directory
+                                     ("Project: " initial-input)
+                                     (_ (error ":integration-test-unsupported-prompt-error %S" prompt)))))
+          (with-temp-buffer
+            ;; set default directory to temp project
+            (setq-local default-directory project-dir)
+
+            (let* (;; Get a gv reference so as to poll if the client has
+                   ;; connected to the nREPL server.
+                   (client-is-connected* (cider-itu-nrepl-client-connected-ref-make!))
+
+                   ;; jack in and get repl buffer.
+                   ;;
+                   ;; The numerical prefix arg for `lein` in
+                   ;; `cider-jack-in-universal-options' is 2.
+                   (nrepl-proc (cider-jack-in-universal 2))
+                   (nrepl-buf (process-buffer nrepl-proc)))
+
+              ;; wait until the client has successfully connected to the
+              ;; nREPL server.
+              (cider-itu-poll-until (eq (gv-deref client-is-connected*) 'connected) 90)
+
+              ;; give it some time to setup the clj REPL
+              (cider-itu-poll-until (cider-repls 'clj nil) 90)
+
+              ;; send command to the REPL, and push stdout/stderr to
+              ;; corresponding eval-xxx variables.
+              (let ((repl-buffer (cider-current-repl))
+                    (eval-err '())
+                    (eval-out '()))
+                (expect repl-buffer :not :to-be nil)
+
+                ;; send command to the REPL
+                (cider-interactive-eval
+                 ;; ask REPL to return a string that uniquely identifies it.
+                 "(print :clojure? (some? (clojure-version)))"
+                 (lambda (return)
+                   (nrepl-dbind-response
+                       return
+                       (out err)
+                     (when err (push err eval-err))
+                     (when out (push out eval-out)))) )
+
+                ;; wait for a response to come back.
+                (cider-itu-poll-until (or eval-err eval-out) 10)
+
+                ;; ensure there are no errors and response is as expected.
+                (expect eval-err :to-equal '())
+                (expect eval-out :to-equal '(":clojure? true"))
+
+                ;; exit the REPL.
+                (cider-quit repl-buffer)
+
+                ;; wait for the REPL to exit
+                (cider-itu-poll-until (not (eq (process-status nrepl-proc) 'run)) 15)
+                (expect (member (process-status nrepl-proc) '(exit signal)))))))))))
 
 (provide 'integration-tests)
 
