Default to silent class cache initialization

Fixes clojure-emacs/refactor-nrepl#290

Author: vemv

CHANGELOG.md

@@ -2,6 +2,10 @@
 
 ## master (unreleased)
 
+* The _class info cache_ is now initialized silently by default. This results in less confusing output.
+  * You can now `@orchard.java/cache-initializer` for deterministically waiting for this cache workload to complete.
+  * You can control its verbosity by setting `"-Dorchard.initialize-cache.silent=false"` (or `[...]=true`).
+
 ## 0.6.5 (2021-02-13)
 
 ### Bugs Fixed

README.md

@@ -86,6 +86,14 @@ Just add `orchard` as a dependency and start hacking.
 Consult the [API documentation](https://cljdoc.org/d/cider/orchard/CURRENT) to get a better idea about the
 functionality that's provided.
 
+## Configuration options
+
+So far, Orchard follows these options, which can be specified as Java system properties
+(which means that end users can choose to set them globally without fiddling with tooling internals):
+
+* `"-Dorchard.initialize-cache.silent=true"` (default: `true`)
+  * if false, the _class info cache_ initialization may print warnings (possibly spurious ones).
+
 ## History
 
 Originally [SLIME][] was the most

project.clj

@@ -38,7 +38,9 @@
                       :dependencies [[org.clojure/clojure "1.11.0-master-SNAPSHOT"]
                                      [org.clojure/clojure "1.11.0-master-SNAPSHOT" :classifier "sources"]]}
 
-             :test {:resource-paths ["test-resources"]}
+             :test {:resource-paths ["test-resources"]
+                    ;; Initialize the cache verbosely, as usual, so that possible issues can be more easily diagnosed:
+                    :jvm-opts ["-Dorchard.initialize-cache.silent=false"]}
 
              ;; Development tools
              :dev {:dependencies [[pjstadig/humane-test-output "0.10.0"]]

src/orchard/java.clj

@@ -8,7 +8,8 @@
    [clojure.string :as str]
    [orchard.java.classpath :as cp]
    [orchard.misc :as misc]
-   [orchard.java.resource :as resource])
+   [orchard.java.resource :as resource]
+   [orchard.util.io :as util.io])
   (:import
    (clojure.lang IPersistentMap)
    (clojure.reflect Constructor Field JavaReflector Method)
@@ -421,10 +422,22 @@
                                       (javadoc-base-urls 11))))))
       path))
 
-;;; ## Initialization
-;;
-;; On startup, cache info for the most commonly referenced classes.
-(future
+(defn- initialize-cache!* []
   (doseq [class (->> (ns-imports 'clojure.core)
                      (map #(-> % ^Class val .getName symbol)))]
     (class-info class)))
+
+(def initialize-cache-silently?
+  "Should `#'cache-initializer` refrain from printing to `System/out`?"
+  (= "true" (System/getProperty "orchard.initialize-cache.silent" "true")))
+
+(def ^:private initialize-cache!
+  (cond-> initialize-cache!*
+    initialize-cache-silently? util.io/wrap-silently))
+
+(def cache-initializer
+  "On startup, cache info for the most commonly referenced classes.
+
+  This is a def for allowing others to wait for this workload to complete (can be useful sometimes)."
+  (future
+   (initialize-cache!)))

src/orchard/util/io.clj

@@ -0,0 +1,24 @@
+(ns orchard.util.io)
+
+(defn wrap-silently
+  "Middleware that executes `(f)` without printing to `System/out` or `System/err`.
+
+  (Note that `System/out` is different from `*out*`)"
+  [f]
+  (fn []
+    (let [old-out System/out
+          old-err System/err
+          ps (java.io.PrintStream. (proxy [java.io.OutputStream] []
+                                     (write
+                                       ([a])
+                                       ([a b c])
+                                       ([a b c d e]))))]
+      (try
+        (System/setOut ps)
+        (System/setErr ps)
+        (f)
+        (finally
+          (when (= ps System/out) ;; `System/out` may have changed in the meantime (in face of concurrency)
+            (System/setOut old-out))
+          (when (= ps System/err) ;; `System/err` may have changed in the meantime (in face of concurrency)
+            (System/setErr old-err)))))))