CLJS-1224: cljs.repl: Memoize stack frame mapping

When evaluating an expression that results
in a stack overflow, and the resulting trace
is source mapped by cljs.repl, this can result
in thousands of frames being mapped which
can take a few minutes. But, oftentimes stack
overflow is the result of recursion, so many
of the mapped frames are identical. This is
trivial to optimize using memoize, resulting in
the mapping occurring in a couple of seconds.

Author: mfikes

src/clj/cljs/repl.clj

@@ -263,6 +263,46 @@
             [:line :col :name])))
       default)))
 
+(defn- mapped-frame
+  "Given opts and a canonicalized JavaScript stacktrace frame, return the
+  ClojureScript frame."
+  [{:keys [function file line column]} opts]
+  (let [no-source-file? (if-not file
+                          true
+                          (.startsWith file "<"))
+        rfile (when-not no-source-file?
+                (io/file (URL. (.toURL (io/file (util/output-directory opts))) file)))
+        [sm {:keys [ns source-file] :as ns-info}]
+        (when-not no-source-file?
+          ((juxt read-source-map ns-info) rfile))
+        [line' column' call] (if ns-info
+                               (mapped-line-column-call sm line column)
+                               [line column])
+        name' (when (and ns-info function)
+                function)
+        file' (if no-source-file?
+                file
+                (string/replace
+                  (.getCanonicalFile
+                    (if ns-info
+                      source-file
+                      (io/file rfile)))
+                  (str (System/getProperty "user.dir") File/separator) ""))
+        url (or (and ns-info (util/ns->source ns))
+                (and file (io/resource file)))]
+    (merge
+      {:function name'
+       :call     call
+       :file     (if no-source-file?
+                   (str "NO_SOURCE_FILE"
+                        (when file
+                          (str " " file)))
+                   (io/file file'))
+       :line     line'
+       :column   column'}
+      (when url
+        {:url url}))))
+
 (defn mapped-stacktrace
   "Given a vector representing the canonicalized JavaScript stacktrace
    return the ClojureScript stacktrace. The canonical stacktrace must be
@@ -280,55 +320,18 @@
   ([stacktrace] (mapped-stacktrace stacktrace nil))
   ([stacktrace opts]
    (vec
-     (let [with-calls
-           (for [{:keys [function file line column] :as frame} stacktrace]
-             ;; need to convert file, a relative URL style path, to host-specific file
-             (let [no-source-file? (if-not file
-                                     true
-                                     (.startsWith file "<"))
-                   rfile (when-not no-source-file?
-                           (io/file (URL. (.toURL (io/file (util/output-directory opts))) file)))
-                   [sm {:keys [ns source-file] :as ns-info}]
-                   (when-not no-source-file?
-                     ((juxt read-source-map ns-info) rfile))
-                   [line' column' call] (if ns-info
-                                          (mapped-line-column-call sm line column)
-                                          [line column])
-                   name' (when (and ns-info function)
-                           function)
-                   file' (if no-source-file?
-                           file
-                           (string/replace
-                             (.getCanonicalFile
-                               (if ns-info
-                                 source-file
-                                 (io/file rfile)))
-                             (str (System/getProperty "user.dir") File/separator) ""))
-                   url (or (and ns-info (util/ns->source ns))
-                           (and file (io/resource file)))]
-               (merge
-                 {:function name'
-                  :call call
-                  :file (if no-source-file?
-                          (str "NO_SOURCE_FILE"
-                            (when file
-                              (str " " file)))
-                          (io/file file'))
-                  :line line'
-                  :column column'}
-                 (when url
-                   {:url url}))))]
+     (let [mapped-frames (map (memoize #(mapped-frame % opts)) stacktrace)]
        ;; take each non-nil :call and optionally merge it into :function one-level up
        ;; to avoid replacing with local symbols, we only replace munged name if we can munge call symbol back to it
        (map #(merge-with (fn [munged-fn-name unmunged-call-name]
                            (if (= munged-fn-name (string/replace (cljs.compiler/munge unmunged-call-name) "." "$"))
                              unmunged-call-name
                              munged-fn-name)) %1 %2)
-         (map #(dissoc % :call) with-calls)
+         (map #(dissoc % :call) mapped-frames)
          (concat (rest (map #(if (:call %)
                               (hash-map :function (:call %))
                               {})
-                         with-calls)) [{}]))))))
+                         mapped-frames)) [{}]))))))
 
 (defn print-mapped-stacktrace
   "Given a vector representing the canonicalized JavaScript stacktrace