CLJS-2929: Port datafy

Author: mfikes

src/main/cljs/cljs/core.cljs

@@ -867,6 +867,13 @@
   (-iterator [coll]
     "Returns an iterator for coll."))
 
+(defprotocol IDatafiable
+  (-datafy [o] "return a representation of o as data (default identity)"))
+
+(defprotocol INavigable
+  (-nav [coll k v] "return (possibly transformed) v in the context of coll and k (a key/index or nil),
+defaults to returning v."))
+
 ;; Printing support
 
 (deftype StringBufferWriter [sb]
@@ -1356,7 +1363,10 @@
 
 (extend-type nil
   ICounted
-  (-count [_] 0))
+  (-count [_] 0)
+
+  IDatafiable
+  (-datafy [_] nil))
 
 ;; TODO: we should remove this and handle date equality checking
 ;; by some other means, probably by adding a new primitive type
@@ -1405,7 +1415,13 @@
 (extend-type default
   IHash
   (-hash [o]
-    (goog/getUid o)))
+    (goog/getUid o))
+
+  IDatafiable
+  (-datafy [o] o)
+
+  INavigable
+  (-nav [_ _ x] x))
 
 ;;this is primitive because & emits call to array-seq
 (defn inc

src/main/cljs/clojure/datafy.cljs

@@ -0,0 +1,55 @@
+;   Copyright (c) Rich Hickey. All rights reserved.
+;   The use and distribution terms for this software are covered by the
+;   Eclipse Public License 1.0 (http://opensource.org/licenses/eclipse-1.0.php)
+;   which can be found in the file epl-v10.html at the root of this distribution.
+;   By using this software in any fashion, you are agreeing to be bound by
+;   the terms of this license.
+;   You must not remove this notice, or any other, from this software.
+
+(ns
+  ^{:doc "Functions to turn objects into data. Alpha, subject to change"}
+  clojure.datafy)
+
+(defn datafy
+  "Attempts to return x as data. If :clojure.datafy/datafy is present
+  as metadata of x, it will be called with x as an argument, else
+  datafy will return the value of clojure.protocols/datafy. If the
+  value has been transformed and the result supports
+  metadata, :clojure.datafy/obj will be set on the metadata to the
+  original value of x."
+  [x]
+  (let [v ((or (-> x meta ::datafy) -datafy) x)]
+    (if (identical? v x)
+      v
+      (if (object? v)
+        (vary-meta v assoc ::obj x)
+        v))))
+
+(defn nav
+  "Returns (possibly transformed) v in the context of coll and k (a
+  key/index or nil). Callers should attempt to provide the key/index
+  context k for Indexed/Associative/ILookup colls if possible, but not
+  to fabricate one e.g. for sequences (pass nil). If :clojure.datafy/nav is
+  present as metadata on coll, it will be called with coll, k and v as
+  arguments, else nav will call :clojure.protocols/nav."
+  [coll k v]
+  ((or (-> coll meta ::nav) -nav) coll k v))
+
+(defn- datify-ref [r]
+  (with-meta [(deref r)] (meta r)))
+
+(extend-protocol IDatafiable
+  Var
+  (-datafy [r] (datify-ref r))
+
+  Reduced
+  (-datafy [r] (datify-ref r))
+
+  Atom
+  (-datafy [r] (datify-ref r))
+
+  Volatile
+  (-datafy [r] (datify-ref r))
+
+  Delay
+  (-datafy [r] (datify-ref r)))