TDEPS-212 Support local file git repos

Author: puredanger

src/main/clojure/clojure/tools/gitlibs/impl.clj

@@ -45,14 +45,40 @@
   ^File [lib]
   (jio/file (:gitlibs/dir @config/CONFIG) "libs" (namespace lib) (name lib)))
 
+(def ^:private git-url-regex
+  #"([a-z0-9+.-]+):\/\/(?:(?:(?:[^@]+?)@)?([^/]+?)(?::[0-9]*)?)?(/[^:]+)")
+
+(def ^:private git-scp-regex
+  #"(?:(?:[^@]+?)@)?(.+?):([^:]+)")
+
 (defn- clean-url
-  "Chop leading protocol, trailing .git, replace :'s with /"
+  "Convert url into a safe relative path (this is not a reversible transformation)
+  based on scheme, host, and path (drop user and port).
+
+  Examples:
+    ssh://[email protected]:3333/org/repo.git     => ssh/gitlab.com/org/repo
+    [email protected]:dotted.org/dotted.repo.git  => ssh/github.com/dotted.org/dotted.repo
+    file://../foo                              => file/REL/_DOTDOT_/foo
+    file:///Users/user/foo.git                 => file/Users/user/foo
+    ../foo                                     => file/REL/_DOTDOT_/foo
+    ~user/foo.git                              => file/REL/_TILDE_user/foo
+
+  * https://git-scm.com/docs/git-clone#_git_urls
+  * https://git-scm.com/book/en/v2/Git-on-the-Server-The-Protocols
+  "
   [url]
-  (-> url
-    (str/split #"://")
-    last
-    (str/replace #"\.git$" "")
-    (str/replace #":" "/")))
+  (let [[scheme host path] (cond
+                             (str/starts-with? url "file://") ["file" nil (-> url (subs 7) (str/replace #"^([^/])" "REL/$1"))]
+                             (str/includes? url "://") (let [[_ s h p] (re-matches git-url-regex url)] [s h p])
+                             (str/includes? url ":") (let [[_ h p] (re-matches git-scp-regex url)] ["ssh" h p])
+                             :local-repo ["file" nil (str/replace url #"^([^/])" "REL/$1")])
+        clean-path (-> path
+                     (str/replace #"\.git/?$" "") ;; remove trailing .git or .git/
+                     (str/replace #"~" "_TILDE_")) ;; replace ~ with _TILDE_
+        dir-parts (->> (concat [scheme host] (str/split clean-path #"/")) ;; split on /
+                    (remove str/blank?) ;; remove any missing path segments
+                    (map #(-> % ({"." "_DOT_", ".." "_DOTDOT_"} %))))] ;; replace . or .. segments
+    (str/join "/" dir-parts)))
 
 (defn git-dir
   ^File [url]

src/test/clojure/clojure/tools/gitlibs/test_impl.clj

@@ -0,0 +1,36 @@
+(ns clojure.tools.gitlibs.test-impl
+  (:require
+    [clojure.test :refer :all]
+    [clojure.tools.gitlibs.impl :as impl]))
+
+(deftest test-clean-url
+  (are [url expected-path]
+    (= expected-path (#'impl/clean-url url))
+
+    ;; url formats - don't use user or port
+    "ssh://[email protected]:3333/org/repo.git" "ssh/gitlab.com/org/repo"
+    "ssh://[email protected]/org/repo.git"  "ssh/gitlab.org.net/org/repo"
+    "ssh://[email protected]/~user/repo.git/"     "ssh/host.xz/_TILDE_user/repo"
+    "https://github.com/org/repo.git"        "https/github.com/org/repo"
+    "git://host.xz/path/to/repo.git/"        "git/host.xz/path/to/repo"
+
+    ;; scp style url (most common github ssh url format)
+    "[email protected]:org/repo.git"               "ssh/github.com/org/repo"
+    "[email protected]:dotted.org/dotted.repo.git" "ssh/github.com/dotted.org/dotted.repo"
+    "host.xz:~user/path/to/repo.git/"           "ssh/host.xz/_TILDE_user/path/to/repo"
+
+    ;; file scheme
+    "file:///Users/me/code/repo.git" "file/Users/me/code/repo"
+    "file://../foo.git"              "file/REL/_DOTDOT_/foo"
+    "file://~/path/repo.git"         "file/REL/_TILDE_/path/repo"
+
+    ;; file repos - handle relative vs absolute, handle . .. ~
+    "/Users/me/code/repo.git" "file/Users/me/code/repo"
+    "../foo.git"              "file/REL/_DOTDOT_/foo"
+    "./foo.git"               "file/REL/_DOT_/foo"
+    "~user/foo.git"           "file/REL/_TILDE_user/foo"
+
+    ;; git - unknown transport with url rewrite in gitconfig (unusual, but do something useful)
+    "work:repo.git" "ssh/work/repo"))
+
+

src/test/clojure/clojure/tools/test_gitlibs.clj

@@ -21,7 +21,7 @@
 (deftest test-procure
   (let [wt1 (gl/procure repo-url 'org.clojure/spec.alpha "739c1af")
         wt2 (gl/procure repo-url 'org.clojure/spec.alpha "6a56327")]
-    (is (.exists (jio/file (gl/cache-dir) "_repos" "github.com" "clojure" "spec.alpha")))
+    (is (.exists (jio/file (gl/cache-dir) "_repos" "https" "github.com" "clojure" "spec.alpha")))
     (is (= wt1 (.getAbsolutePath (jio/file (gl/cache-dir) "libs" "org.clojure" "spec.alpha" "739c1af56dae621aedf1bb282025a0d676eff713"))))
     (is (= wt2 (.getAbsolutePath (jio/file (gl/cache-dir) "libs" "org.clojure" "spec.alpha" "6a56327446c909db0d11ecf93a3c3d659b739be9"))))))