[build] Transition Rust+cargo to bzlmod

Author: fhanau

MODULE.bazel

@@ -37,9 +37,6 @@ git_override(
     remote = "https://chromium.googlesource.com/chromium/src/third_party/zlib.git",
 )
 
-# Rust
-bazel_dep(name = "rules_rust", version = "0.68.1")
-
 # BoringSSL may subtly break backwards compatibility and behave differently than the latest FIPS
 # version, often by rejecting key values that it considers invalid/unsafe even though they are still
 # accepted by BoringSSL. Update with caution and only after confirming this is compatible with the
@@ -60,6 +57,7 @@ archive_override(
 include("//build/deps:deps.MODULE.bazel")
 include("//build/deps:nodejs.MODULE.bazel")
 include("//build/deps:python.MODULE.bazel")
+include("//build/deps:rust.MODULE.bazel")
 include("//build/deps:v8.MODULE.bazel")
 include("//build/deps:oci.MODULE.bazel")
 

WORKSPACE

@@ -16,10 +16,6 @@ http_archive(
     url = "https://github.com/cloudflare/workerd-cxx/tarball/916f0e7be8f1d43fe5ece1b72edd3c5844243d7b",
 )
 
-load("//:build/rust_toolchains.bzl", "rust_toolchains")
-
-rust_toolchains()
-
 # rust-based lolhtml dependency, including the API header.
 # Presented as a separate repository to allow overrides.
 new_local_repository(

build/deps/rust.MODULE.bazel

@@ -0,0 +1,45 @@
+bazel_dep(name = "rules_rust", version = "0.68.1")
+
+RUST_STABLE_VERSION = "1.91.0"  # LLVM 21
+
+RUST_NIGHTLY_VERSION = "nightly/2025-10-30"
+
+# List of additional triples to be configured on top of the local platform triple
+RUST_TARGET_TRIPLES = [
+    # Add support for macOS cross-compilation
+    "x86_64-apple-darwin",
+    # Add support for macOS rosetta
+    "aarch64-unknown-linux-gnu",
+]
+
+rust = use_extension("@rules_rust//rust:extensions.bzl", "rust")
+rust.toolchain(
+    allocator_library = "@rules_rust//ffi/rs:empty",
+    edition = "2024",
+    extra_rustc_flags_triples = {
+        # Enable ISA extensions matching the ones used for C++. The clmul feature is not included as
+        # it is still "unstable" as of 1.86.0.
+        "x86_64-unknown-linux-gnu": ["-Ctarget-feature=+sse4.2"],
+        "x86_64-apple-darwin": ["-Ctarget-feature=+sse4.2"],
+        "x86_64-pc-windows-msvc": ["-Ctarget-feature=+sse4.2"],
+        "aarch64-unknown-linux-gnu": ["-Ctarget-feature=+crc"],
+        # No options needed for aarch64-apple-darwin: CRC feature is enabled by default.
+    },
+    extra_target_triples = RUST_TARGET_TRIPLES,
+    rustfmt_version = RUST_NIGHTLY_VERSION,
+    versions = [
+        RUST_STABLE_VERSION,
+        RUST_NIGHTLY_VERSION,
+    ],
+)
+use_repo(rust, "rust_toolchains")
+
+register_toolchains("@rust_toolchains//:all")
+
+crate_repositories = use_extension("//deps/rust:extension.bzl", "crate_repositories")
+use_repo(
+    crate_repositories,
+    "crates_vendor",
+    # Needed to retrieve lol-html header
+    "crates_vendor__lol_html_c_api-1.3.0",
+)

build/rust_toolchains.bzl

@@ -0,0 +1,14 @@
+"""Module extensions for using vendored crates with bzlmod. Derived from https://github.com/bazelbuild/rules_rust/blob/0.68.1/examples/hello_world/third-party-in-workspace/extension.bzl. """
+
+load("//deps/rust/crates:crates.bzl", _crate_repositories = "crate_repositories")
+
+def _crate_repositories_impl(module_ctx):
+    direct_deps = _crate_repositories()
+    return module_ctx.extension_metadata(
+        root_module_direct_deps = ["crates_vendor", "crates_vendor__lol_html_c_api-1.3.0"],
+        root_module_direct_dev_deps = [],
+    )
+
+crate_repositories = module_extension(
+    implementation = _crate_repositories_impl,
+)