Add TaskSkill table, model and tests

Author: begedin

priv/repo/migrations/20170131234029_create_task_skill.exs

@@ -0,0 +1,16 @@
+defmodule CodeCorps.Repo.Migrations.CreateTaskSkill do
+  @moduledoc false
+
+  use Ecto.Migration
+
+  def change do
+    create table(:task_skills) do
+      add :skill_id, references(:skills), null: false
+      add :task_id, references(:tasks), null: false
+
+      timestamps()
+    end
+
+    create index :task_skills, [:task_id, :skill_id], unique: true
+  end
+end

test/models/task_skill_test.exs

@@ -0,0 +1,43 @@
+defmodule CodeCorps.TaskSkillTest do
+  @moduledoc false
+
+  use CodeCorps.ModelCase
+
+  alias CodeCorps.TaskSkill
+
+  describe "create_changeset/2" do
+    @required_attrs ~w(task_id skill_id)
+
+    test "requires #{@required_attrs}" do
+      changeset = TaskSkill.create_changeset(%TaskSkill{}, %{})
+
+      assert_validation_triggered(changeset, :task_id, :required)
+      assert_validation_triggered(changeset, :skill_id, :required)
+    end
+
+    test "ensures associated Task record exists" do
+      skill = insert(:skill)
+      changeset = TaskSkill.create_changeset(%TaskSkill{}, %{task_id: -1, skill_id: skill.id})
+
+      {:error, response_changeset} = Repo.insert(changeset)
+      assert_error_message(response_changeset, :task, "does not exist")
+    end
+
+    test "ensures associated Skill record exists" do
+      task = insert(:task)
+      changeset = TaskSkill.create_changeset(%TaskSkill{}, %{task_id: task.id, skill_id: -1})
+
+      {:error, response_changeset} = Repo.insert(changeset)
+      assert_error_message(response_changeset, :skill, "does not exist")
+    end
+
+    test "ensures uniqueness of Skill/Task combination" do
+      task_skill = insert(:task_skill)
+
+      changeset = TaskSkill.create_changeset(%TaskSkill{}, %{task_id: task_skill.task_id, skill_id: task_skill.skill_id})
+
+      {:error, response_changeset} = Repo.insert(changeset)
+      assert_error_message(response_changeset, :skill, "has already been taken")
+    end
+  end
+end

test/support/factories.ex

@@ -1,4 +1,6 @@
 defmodule CodeCorps.Factories do
+  @moduledoc false
+
   # with Ecto
   use ExMachina.Ecto, repo: CodeCorps.Repo
 
@@ -64,6 +66,13 @@ defmodule CodeCorps.Factories do
     }
   end
 
+  def task_skill_factory do
+    %CodeCorps.TaskSkill{
+      skill: build(:skill),
+      task: build(:task)
+    }
+  end
+
   def project_factory do
     %CodeCorps.Project{
       title: sequence(:title, &"Project #{&1}"),
@@ -94,6 +103,7 @@ defmodule CodeCorps.Factories do
     }
   end
 
+  @spec set_password(CodeCorps.User.t, String.t) :: CodeCorps.User.t
   def set_password(user, password) do
     hashed_password = Comeonin.Bcrypt.hashpwsalt(password)
     %{user | encrypted_password: hashed_password}

web/models/task_skill.ex

@@ -0,0 +1,33 @@
+defmodule CodeCorps.TaskSkill do
+  @moduledoc """
+  Represents a link record between a task and a skill, indicating that
+  for a user to be suitable to work on a task, they need to posses skills
+  associated with that task.
+  """
+  use CodeCorps.Web, :model
+
+  @type t :: %__MODULE__{}
+
+  schema "task_skills" do
+    belongs_to :skill, CodeCorps.Skill
+    belongs_to :task, CodeCorps.Task
+
+    timestamps()
+  end
+
+  @permitted_attrs [:skill_id, :task_id]
+  @required_attrs @permitted_attrs
+
+  @doc """
+  Builds a changeset used to insert a record into the database
+  """
+  @spec create_changeset(CodeCorps.TaskSkill.t, map) :: Ecto.Changeset.t
+  def create_changeset(struct, params \\ %{}) do
+    struct
+    |> cast(params, @permitted_attrs)
+    |> validate_required(@required_attrs)
+    |> assoc_constraint(:task)
+    |> assoc_constraint(:skill)
+    |> unique_constraint(:skill, name: :task_skills_task_id_skill_id_index)
+  end
+end