Assembler: add simple implementation.

Author: ForNeVeR

Naggum.Assembler/Assembler.fs

@@ -1,9 +1,62 @@
 module Naggum.Assembler.Assembler
 
+open System
+open System.Reflection
 open System.Reflection.Emit
 
 open Naggum.Assembler.Representation
 
-/// Assembles the intermediate program representation. Returns a list of assemblies ready for saving.
+let private getMethodAttributes (m : MethodDefinition) =
+    let empty = enum 0
+    let conditions =
+        [ (m.Visibility = Public, MethodAttributes.Public)
+          (true, MethodAttributes.Static) ] // TODO: Proper static method detection
+    
+    conditions
+    |> List.map (fun (c, r) -> if c then r else empty)
+    |> List.fold (|||) empty
+
+let private findMethod (signature : MethodSignature) =
+    // TODO: Add method overload resolution etc. (see ClrGenerator module)
+    let ``type`` = signature.ContainingType.Value
+    ``type``.GetMethod (signature.Name, Array.ofList signature.ArgumentTypes)
+
+let private buildMethodBody (m : MethodDefinition) (builder : MethodBuilder) =
+    let generator = builder.GetILGenerator ()
+    
+    m.Body
+    |> List.iter (function
+                  | Call signature ->
+                      let methodInfo = findMethod signature
+                      generator.Emit (OpCodes.Call, methodInfo)
+                  | Ldstr string -> generator.Emit (OpCodes.Ldstr, string)
+                  | Ret -> generator.Emit (OpCodes.Ret))
+
+let private assembleUnit (builder : ModuleBuilder) = function
+    | Method m ->
+        let name = m.Name
+        let attributes = getMethodAttributes m
+        let returnType = m.ReturnType
+        let argumentTypes = Array.ofList m.ArgumentTypes
+        let methodBuilder = builder.DefineGlobalMethod (name,
+                                                        attributes,
+                                                        returnType,
+                                                        argumentTypes)
+        buildMethodBody m methodBuilder
+        
+
+let private assembleAssembly (assembly : Assembly) =
+    let name = AssemblyName assembly.Name
+    let domain = AppDomain.CurrentDomain
+    let builder = domain.DefineDynamicAssembly (name,
+                                                AssemblyBuilderAccess.Save)
+    let fileName = assembly.Name + ".dll" // TODO: Proper file naming
+    let moduleBuilder = builder.DefineDynamicModule (assembly.Name, fileName)
+    assembly.Units |> List.iter (assembleUnit moduleBuilder)
+    builder
+
+/// Assembles the intermediate program representation. Returns a list of
+/// assemblies ready for saving.
 let assemble (assemblies : Assembly seq) : AssemblyBuilder seq =
-    Seq.empty
+    assemblies
+    |> Seq.map assembleAssembly

Naggum.Assembler/Representation.fs

@@ -18,8 +18,8 @@ type MethodSignature =
       ReturnType : Type }
 
 type Instruction =
-    | Ldstr of string
     | Call of MethodSignature
+    | Ldstr of string
     | Ret
 
 type MethodDefinition =

Naggum.Test/AssemblerTests.fs

@@ -0,0 +1,25 @@
+module Naggum.Test.AssemblerTests
+
+open System
+open System.IO
+open System.Reflection
+open System.Text
+
+open Xunit
+
+open Naggum.Assembler
+open Naggum.Assembler.Representation
+
+let assemble (source : string) =
+    use stream = new MemoryStream(Encoding.UTF8.GetBytes source)
+    let repr = Processor.prepare "file.ngi" stream
+    let assemblies = Assembler.assemble repr
+    Array.ofSeq assemblies
+
+[<Fact>]
+let ``Empty assembly should be assembled`` () =
+    let source = "(.assembly Empty)"
+    let result = assemble source
+    Assert.Equal (1, result.Length)
+
+// TODO: Additional integration tests

Naggum.Test/Naggum.Test.fsproj

@@ -52,8 +52,9 @@
       <CopyToOutputDirectory>PreserveNewest</CopyToOutputDirectory>
     </Content>
     <Content Include="packages.config" />
-    <Compile Include="ProcessorTests.fs" />
     <Compile Include="CompilerTest.fs" />
+    <Compile Include="AssemblerTests.fs" />
+    <Compile Include="ProcessorTests.fs" />
   </ItemGroup>
   <ItemGroup>
     <Reference Include="FSharp.Core, Version=$(TargetFSharpCoreVersion), Culture=neutral, PublicKeyToken=b03f5f7f11d50a3a">