Merge pull request #43 from com-pas/auto-alignment-test

Added some basic tests for SCL Auto Alignment

Author: Rob Tjalma

integration-testing/TestSuite004-auto-alignment.robot

@@ -0,0 +1,66 @@
+# SPDX-FileCopyrightText: 2021 Alliander N.V.
+#
+# SPDX-License-Identifier: Apache-2.0
+
+*** Settings ***
+Documentation   Basic test cases for executing the SCL Auto Alignment Service.
+Resource        ./include/general-compas.robot
+
+Test Setup      Initialize and Start OpenSCD
+Test Teardown   Make screenshot and Stop OpenSCD
+
+*** Variables ***
+${substation1VoltageLevel}      _af9a4ae3-ba2e-4c34-8e47-5af894ee20f4>S1 110kV
+${substation3VoltageLevel}      _974565b1-ac55-4901-9f48-afc7ef5486df>S3 110kV
+
+*** Keywords ***
+Execute SCL Auto Alignment
+    [Arguments]                 @{substationNames}
+    Open Menu                   Auto Align SLD
+    FOR   ${substationName}    IN   @{substationNames}
+       Check Checkbox           ${dialog-selector} compas-auto-alignment section#substationsToAlign > mwc-list > mwc-check-list-item:has-text("${substationName}") input[type="checkbox"]
+    END
+    Click                       ${dialog-selector} mwc-button[slot="primaryAction"] > button
+    Wait for dialog is closed
+    Close Menu
+
+Check X/Y Coordinates
+    [Arguments]         ${id}   ${x}    ${y}
+    Get Attribute       single-line-diagram-plugin svg > g[id="${id}"]   sxy:x   ==  ${x}
+    Get Attribute       single-line-diagram-plugin svg > g[id="${id}"]   sxy:y   ==  ${y}
+
+*** Test Cases ***
+TestCase004-01
+    [Documentation]     Execute the SCL Auto Alignment for a single Substation.
+    Set Test Variable   ${sclname}  MiniGrid
+    Set Test Variable   ${scltype}  SCD
+
+    Enable Extension    Single Line Diagram
+    Enable Extension    Auto Align SLD
+
+    Open Menu           Open project
+    Open local file     ${sclname}    ${scltype}
+
+    Execute SCL Auto Alignment  Sub1
+
+    Select Tab               Single Line Diagram
+    Check X/Y Coordinates    ${substation1VoltageLevel}    36    10
+    Check X/Y Coordinates    ${substation3VoltageLevel}    0     0
+
+TestCase004-02
+    [Documentation]     Execute the SCL Auto Alignment for a multiple Substation.
+    Set Test Variable   ${sclname}  MiniGrid
+    Set Test Variable   ${scltype}  SCD
+
+    Enable Extension    Single Line Diagram
+    Enable Extension    Auto Align SLD
+
+    Open Menu           Open project
+    Open local file     ${sclname}    ${scltype}
+
+    Execute SCL Auto Alignment  Sub1   Sub3
+
+    Select Tab               Single Line Diagram
+    Check X/Y Coordinates    ${substation1VoltageLevel}    36    10
+    Check X/Y Coordinates    ${substation3VoltageLevel}    12    8
+

integration-testing/include/general-openscd.robot

@@ -52,6 +52,19 @@ Close Menu
     # To make the editors visible again we need to close the menu.
     # We click outside the menu somewhere in the browser.
     Mouse Button    click   x=350   y=350
+    Sleep           100 milliseconds
+
+Enable Extension
+    [Arguments]         ${extensionName}
+    Open Menu           Extensions
+    ${checkboxState}=   Get Element State   mwc-list#pluginList > mwc-check-list-item:has-text("${extensionName}") input[type="checkbox"]   Checked
+    IF                  ${checkboxState} == False
+      Check Checkbox    mwc-list#pluginList > mwc-check-list-item:has-text("${extensionName}") input[type="checkbox"]
+    END
+    # Press the escape key to close the dialog.
+    Keyboard Key        press    Escape
+    Sleep               100 milliseconds
+    Close Menu
 
 Select Tab
     [Arguments]     ${tabname}