Warn when binary installed by "stack upgrade" isn't visible on PATH

Author: mgsloan

ChangeLog.md

@@ -174,6 +174,8 @@ Other enhancements:
 * Upgraded `http-client-tls` version, which now offers support for the
   `socks5://` and `socks5h://` values in the `http_proxy` and `https_proxy`
   environment variables.
+* Binary "stack upgrade" will now warn if the installed executable is not
+  on the PATH or shadowed by another entry.
 
 Bug fixes:
 

src/Path/CheckInstall.hs

@@ -0,0 +1,60 @@
+{-# LANGUAGE FlexibleContexts #-}
+{-# LANGUAGE TemplateHaskell #-}
+{-# LANGUAGE OverloadedStrings #-}
+
+module Path.CheckInstall where
+
+import           Control.Monad (unless)
+import           Control.Monad.Extra (anyM, (&&^))
+import           Control.Monad.IO.Class
+import           Control.Monad.Logger
+import           Data.Foldable (forM_)
+import           Data.Text (Text)
+import qualified Data.Text as T
+import qualified System.Directory as D
+import qualified System.FilePath as FP
+
+-- | Checks if the installed executable will be available on the user's
+-- PATH. This doesn't use @envSearchPath menv@ because it includes paths
+-- only visible when running in the stack environment.
+warnInstallSearchPathIssues :: (MonadIO m, MonadLogger m) => FilePath -> [Text] -> m ()
+warnInstallSearchPathIssues destDir installed = do
+    searchPath <- liftIO FP.getSearchPath
+    destDirIsInPATH <- liftIO $
+        anyM (\dir -> D.doesDirectoryExist dir &&^ fmap (FP.equalFilePath destDir) (D.canonicalizePath dir)) searchPath
+    if destDirIsInPATH
+        then forM_ installed $ \exe -> do
+            mexePath <- (liftIO . D.findExecutable . T.unpack) exe
+            case mexePath of
+                Just exePath -> do
+                    exeDir <- (liftIO . fmap FP.takeDirectory . D.canonicalizePath) exePath
+                    unless (exeDir `FP.equalFilePath` destDir) $ do
+                        $logWarn ""
+                        $logWarn $ T.concat
+                            [ "WARNING: The \""
+                            , exe
+                            , "\" executable found on the PATH environment variable is "
+                            , T.pack exePath
+                            , ", and not the version that was just installed."
+                            ]
+                        $logWarn $ T.concat
+                            [ "This means that \""
+                            , exe
+                            , "\" calls on the command line will not use this version."
+                            ]
+                Nothing -> do
+                    $logWarn ""
+                    $logWarn $ T.concat
+                        [ "WARNING: Installation path "
+                        , T.pack destDir
+                        , " is on the PATH but the \""
+                        , exe
+                        , "\" executable that was just installed could not be found on the PATH."
+                        ]
+        else do
+            $logWarn ""
+            $logWarn $ T.concat
+                [ "WARNING: Installation path "
+                , T.pack destDir
+                , " not found on the PATH environment variable"
+                ]

src/Stack/Build/Execute.hs

@@ -29,7 +29,6 @@ import           Control.Exception.Safe (catchIO)
 import           Control.Exception.Lifted
 import           Control.Monad (liftM, when, unless, void)
 import           Control.Monad.Catch (MonadCatch)
-import           Control.Monad.Extra (anyM, (&&^))
 import           Control.Monad.IO.Class
 import           Control.Monad.Logger
 import           Control.Monad.Trans.Control (liftBaseWith)
@@ -74,6 +73,7 @@ import           Distribution.System            (OS (Windows),
 import qualified Distribution.Text as C
 import           Language.Haskell.TH as TH (location)
 import           Path
+import           Path.CheckInstall
 import           Path.Extra (toFilePathNoTrailingSep, rejectMissingFile)
 import           Path.IO hiding (findExecutable, makeAbsolute)
 import           Prelude hiding (FilePath, writeFile, any)
@@ -551,46 +551,8 @@ copyExecutables exes = do
             , T.pack destDir'
             , ":"]
     forM_ installed $ \exe -> $logInfo ("- " <> exe)
+    warnInstallSearchPathIssues destDir' installed
 
-    searchPath <- liftIO FP.getSearchPath
-    destDirIsInPATH <- liftIO $
-        anyM (\dir -> D.doesDirectoryExist dir &&^ fmap (FP.equalFilePath destDir') (D.canonicalizePath dir)) searchPath
-    if destDirIsInPATH
-        then forM_ installed $ \exe -> do
-            mexePath <- (liftIO . D.findExecutable . T.unpack) exe
-            case mexePath of
-                Just exePath -> do
-                    exeDir <- (liftIO . fmap FP.takeDirectory . D.canonicalizePath) exePath
-                    unless (exeDir `FP.equalFilePath` destDir') $ do
-                        $logWarn ""
-                        $logWarn $ T.concat
-                            [ "WARNING: The \""
-                            , exe
-                            , "\" executable found on the PATH environment variable is "
-                            , T.pack exePath
-                            , ", and not the version that was just installed."
-                            ]
-                        $logWarn $ T.concat
-                            [ "This means that \""
-                            , exe
-                            , "\" calls on the command line will not use this version."
-                            ]
-                Nothing -> do
-                    $logWarn ""
-                    $logWarn $ T.concat
-                        [ "WARNING: Installation path "
-                        , T.pack destDir'
-                        , " is on the PATH but the \""
-                        , exe
-                        , "\" executable that was just installed could not be found on the PATH."
-                        ]
-        else do
-            $logWarn ""
-            $logWarn $ T.concat
-                [ "WARNING: Installation path "
-                , T.pack destDir'
-                , " not found on the PATH environment variable"
-                ]
 
 -- | Windows can't write over the current executable. Instead, we rename the
 -- current executable to something else and then do the copy.

src/Stack/Setup.hs

@@ -81,6 +81,7 @@ import              Lens.Micro (set)
 import              Network.HTTP.Simple (getResponseBody, httpLBS, withResponse, getResponseStatusCode)
 import              Network.HTTP.Download
 import              Path
+import              Path.CheckInstall (warnInstallSearchPathIssues)
 import              Path.Extra (toFilePathNoTrailingSep)
 import              Path.IO hiding (findExecutable)
 import qualified    Paths_stack as Meta
@@ -1765,6 +1766,9 @@ downloadStackExe platforms0 archiveInfo destDir testExe = do
               renameFile tmpFile destFile
           _ -> renameFile tmpFile destFile
 
+    destDir' <- liftIO . D.canonicalizePath . toFilePath $ destDir
+    warnInstallSearchPathIssues destDir' ["stack"]
+
     $logInfo $ T.pack $ "New stack executable available at " ++ toFilePath destFile
   where