Implement setting environment variables for exec.

This only works if the remote sshd permits it. By default, most do not.

Fixes: #11

Author: conormcd

src/clj_libssh2/channel.clj

@@ -138,6 +138,40 @@
   [session channel]
   (block session (handle-errors session (libssh2-channel/send-eof channel))))
 
+(defn setenv
+  "Set a selection of environment variables on the channel. These will be
+   visible to the next exec command. Setting environment variables may be
+   prohibited by the remote sshd based on the value of the AcceptEnv
+   configuration value.
+
+   Arguments:
+
+   channel
+   env      A map where the keys are environment variable names and the values
+            are the values for those environment variables. If either the name
+            or value is a keyword, they will be stringified using the name
+            function. Everything else will be stringified using str. Nil values
+            will be converted to empty strings. For maximum predictability, you
+            should provide a map of String -> String only.
+
+   Return:
+
+   0 on success. Errors will result in exceptions."
+  [session channel env]
+  (let [->str (fn [v]
+                (cond (nil? v) ""
+                      (keyword? v) (name v)
+                      :else (str v)))
+        fail-if-forbidden (fn [ret]
+                            (if (= libssh2/ERROR_CHANNEL_REQUEST_DENIED ret)
+                              (throw (Exception. "Setting environment variables is not permitted."))
+                              ret))]
+    (doseq [[k v] env]
+      (block session
+        (handle-errors session
+          (fail-if-forbidden
+            (libssh2-channel/setenv channel (->str k) (->str v))))))))
+
 (defn pull
   "Read some output from a given stream on a channel.
 

src/clj_libssh2/ssh.clj

@@ -50,6 +50,11 @@
         If this is not provided, then the output will be returned as a String.
    :err An OutputStream which will be connected to the standard error of the
         remote process and in every other way behaves like :out.
+   :env A map of environment variables which will be set before the command is
+        executed. The keys are the environment variable names. The values are
+        the values for those variables. The setting of environment variables is
+        controlled by the remote sshd and the value of its AcceptEnv
+        configuration variable.
 
    Return:
 
@@ -78,6 +83,7 @@
           inputs (if stdin {0 stdin} {})
           outputs {0 stdout 1 stderr}]
       (channel/with-channel session channel
+        (channel/setenv session channel (:env io))
         (channel/exec session channel commandline)
         (let [streams (channel/pump session channel inputs outputs)
               out (:stream (get streams 0))

test/clj_libssh2/test_ssh.clj

@@ -65,6 +65,23 @@
           (is (= "" (:err result)))
           (is (= 0 (:exit result))))))))
 
+(deftest exec-can-be-given-environment-variables
+  (testing "Exec can be given environment variables."
+    (ssh/with-session session {:port 2222}
+      (let [env {:FOO "foo" :BAR :bar :BAZ 1 :QUUX nil}
+            result (ssh/exec session "env" :env env)
+            out-env (->> result
+                         :out
+                         str/split-lines
+                         (map #(str/split % #"=" 2))
+                         (into {}))]
+        (is (= "foo" (get out-env "FOO")))
+        (is (= "bar" (get out-env "BAR")))
+        (is (= "1" (get out-env "BAZ")))
+        (is (= "" (get out-env "QUUX")))
+        (is (= "" (:err result)))
+        (is (= 0 (:exit result)))))))
+
 (deftest exec-times-out-when-commands-take-too-long
   (testing "Commands that take too long result in a timeout"
     (is (thrown? Exception (ssh/exec {:port 2222 :read-timeout 500}

test/script/setup.sh

@@ -104,6 +104,7 @@ launch_sshd() {
           -h "${TMP_DIR}/ssh_host_key" \
           -h "${TMP_DIR}/ssh_host_dsa_key" \
           -h "${TMP_DIR}/ssh_host_rsa_key" \
+          -o "AcceptEnv=*" \
           -o "AuthorizedKeysFile=${TMP_DIR}/authorized_keys" \
           -o "ListenAddress=${host}:${port}"
   SSHD_PID=$(pgrep -f "${TMP_DIR}/ssh_host_dsa_key")