Summarize large data structures when logging at level :trace.

If we don't do this, the test can run extremely slowly or OOM the JVM.

Author: conormcd

src/clj_libssh2/logging.clj

@@ -3,7 +3,61 @@
    clj-libssh2."
   (:require [clojure.tools.logging :as log]
             [clojure.pprint :refer [pprint]]
-            [robert.hooke :as hook]))
+            [robert.hooke :as hook])
+  (:import [java.io InputStream OutputStream]
+           [com.sun.jna Pointer]))
+
+(def ^:const byte-array-type (type (byte-array 0)))
+(defmulti summarize-structure
+  "Given an object, trim down the larger items so that logging them doesn't
+   result in a combination of extreme performance degradataion and lack of
+   readability.
+
+   Arguments:
+
+   object The object to summarize.
+
+   Return:
+
+   An object of the same type and shape as the input, but with the larger parts
+   of the object summarized into a brief description of their contents."
+  (fn [object]
+    (cond (map? object) :map
+          (sequential? object) :sequence
+          (instance? Pointer object) :summarize
+          (instance? InputStream object) :summarize
+          (instance? OutputStream object) :summarize
+          (string? object) :string
+          (= (type object) byte-array-type) :bytes
+          :else :passthru)))
+
+(defmethod summarize-structure :map
+  [object]
+  (->> object
+       (map #(hash-map (key %) (summarize-structure (val %))))
+       (apply merge)))
+
+(defmethod summarize-structure :sequence
+  [object]
+  (map summarize-structure object))
+
+(defmethod summarize-structure :summarize
+  [object]
+  (type object))
+
+(defmethod summarize-structure :string
+  [object]
+  (if (< 1024 (count object))
+    (format "String[%d]" (count object))
+    object))
+
+(defmethod summarize-structure :bytes
+  [object]
+  (format "byte[%d]" (count object)))
+
+(defmethod summarize-structure :passthru
+  [object]
+  object)
 
 (defn- spy-fn
   "Create a function that can be used as a hook to log the call and result from
@@ -24,8 +78,8 @@
         fn-name (symbol (str (ns-name (:ns fn-meta))) (str (:name fn-meta)))
         make-message (fn [args result]
                        (format "%s => %s"
-                               (with-out-str (pprint (cons fn-name args)))
-                               (with-out-str (pprint result))))]
+                               (with-out-str (pprint (cons fn-name (summarize-structure args))))
+                               (with-out-str (pprint (summarize-structure result)))))]
     (fn [f & args]
       (try
         (let [result (apply f args)]