Add BigInt.from_digits (#16259)

Author: HertzDevil

spec/std/big/big_int_spec.cr

@@ -59,6 +59,41 @@ describe "BigInt" do
     BigInt.new(12.3).to_s.should eq("12")
   end
 
+  describe ".from_digits" do
+    it "creates from digits" do
+      BigInt.from_digits([] of Int32).should eq(0.to_big_i)
+      BigInt.from_digits([3, 2, 1]).should eq(123.to_big_i)
+      BigInt.from_digits({3, 2, 1}, base: 16).should eq(0x123.to_big_i)
+      BigInt.from_digits((0xfa..0xff), base: 256).should eq(0xfffefdfcfbfa.to_big_i)
+      BigInt.from_digits([UInt128::MAX, UInt128::MAX, UInt128::MAX, UInt128::MAX], base: 2.to_big_i ** 128).should eq(2.to_big_i ** 512 - 1)
+      BigInt.from_digits(Deque{1, 0.to_big_i, 0, 1.to_big_i}, base: 2).should eq(9.to_big_i)
+    end
+
+    it "raises for base less than 2" do
+      [-1, 0, 1].each do |base|
+        expect_raises(ArgumentError, "Invalid base #{base}") do
+          BigInt.from_digits([1, 2, 3], base)
+        end
+      end
+    end
+
+    it "raises for digits greater than base" do
+      expect_raises(ArgumentError, "Invalid digit 2 for base 2") do
+        BigInt.from_digits([1, 0, 2], 2)
+      end
+
+      expect_raises(ArgumentError, "Invalid digit 10 for base 2") do
+        BigInt.from_digits([1, 0, 10], 2)
+      end
+    end
+
+    it "raises for negative digits" do
+      expect_raises(ArgumentError, "Invalid digit -1") do
+        BigInt.from_digits([1, 2, -1])
+      end
+    end
+  end
+
   it "compares" do
     1.to_big_i.should eq(1.to_big_i)
     1.to_big_i.should eq(1)

src/big/big_int.cr

@@ -141,6 +141,63 @@ struct BigInt < Int
     new(mpz)
   end
 
+  # Returns a number for given *digits* and *base*. The digits are expected as
+  # an `Enumerable` with the least significant digit as the first element.
+  #
+  # *base* must not be less than 2.
+  #
+  # All digits must be within `0...base`.
+  def self.from_digits(digits : Enumerable(Int), base : Int = 10) : self
+    if base < 2
+      raise ArgumentError.new("Invalid base #{base}")
+    end
+
+    new do |mpz|
+      multiplier = new(1)
+      first_element = true
+
+      digits.each do |digit|
+        if digit < 0
+          raise ArgumentError.new("Invalid digit #{digit}")
+        end
+
+        if digit >= base
+          raise ArgumentError.new("Invalid digit #{digit} for base #{base}")
+        end
+
+        # don't calculate multiplier upfront for the next digit
+        # to avoid overflow at the last iteration
+        if first_element
+          first_element = false
+
+          # mpz = digit
+          Int.primitive_ui_check(digit) do |ui, _, big_i|
+            {
+              ui:    LibGMP.set_ui(mpz, {{ ui }}),
+              big_i: LibGMP.set(mpz, {{ big_i }}),
+            }
+          end
+        else
+          # multiplier *= base
+          Int.primitive_ui_check(base) do |ui, _, big_i|
+            {
+              ui:    LibGMP.mul_ui(multiplier, multiplier, {{ ui }}),
+              big_i: LibGMP.mul(multiplier, multiplier, {{ big_i }}),
+            }
+          end
+
+          # mpz += base * digits
+          Int.primitive_ui_check(digit) do |ui, _, big_i|
+            {
+              ui:    LibGMP.addmul_ui(mpz, multiplier, {{ ui }}),
+              big_i: LibGMP.addmul(mpz, multiplier, {{ big_i }}),
+            }
+          end
+        end
+      end
+    end
+  end
+
   def <=>(other : BigInt)
     LibGMP.cmp(mpz, other)
   end

src/big/lib_gmp.cr

@@ -65,6 +65,7 @@ lib LibGMP
 
   # # I/O
 
+  fun set = __gmpz_set(rop : MPZ*, op : MPZ*)
   fun set_ui = __gmpz_set_ui(rop : MPZ*, op : UI)
   fun set_si = __gmpz_set_si(rop : MPZ*, op : SI)
   fun set_d = __gmpz_set_d(rop : MPZ*, op : Double)
@@ -90,6 +91,9 @@ lib LibGMP
   fun mul_si = __gmpz_mul_si(rop : MPZ*, op1 : MPZ*, op2 : SI)
   fun mul_ui = __gmpz_mul_ui(rop : MPZ*, op1 : MPZ*, op2 : UI)
 
+  fun addmul = __gmpz_addmul(rop : MPZ*, op1 : MPZ*, op2 : MPZ*)
+  fun addmul_ui = __gmpz_addmul_ui(rop : MPZ*, op1 : MPZ*, op2 : UI)
+
   fun fdiv_q = __gmpz_fdiv_q(rop : MPZ*, op1 : MPZ*, op2 : MPZ*)
   fun fdiv_q_ui = __gmpz_fdiv_q_ui(rop : MPZ*, op1 : MPZ*, op2 : UI)