Improve cursor window format in StringScanner#inspect (#16594)

Discussion: #16455 (comment)

---------

Co-authored-by: jneen <jneen@jneen.net>
Co-authored-by: Johannes Müller <straightshoota@gmail.com>

Author: 3 people

spec/std/string_scanner_spec.cr

@@ -391,20 +391,52 @@ describe StringScanner do
   describe "#inspect" do
     it "has information on the scanner" do
       s = StringScanner.new("this is a string")
-      s.inspect.should eq(%(#<StringScanner 0/16 "this " >))
+      s.inspect.should eq(%(#<StringScanner 0/16 "‣this …>))
       s.scan(/\w+\s/)
-      s.inspect.should eq(%(#<StringScanner 5/16 "s is " >))
+      s.inspect.should eq(%(#<StringScanner 5/16 …s ‣is …>))
+      s.scan(1)
+      s.inspect.should eq(%(#<StringScanner 6/16 … i‣s a…>))
       s.scan(/\w+\s/)
-      s.inspect.should eq(%(#<StringScanner 8/16 "s a s" >))
+      s.inspect.should eq(%(#<StringScanner 8/16 …s ‣a s…>))
       s.scan(/\w+\s\w+/)
-      s.inspect.should eq(%(#<StringScanner 16/16 "tring" >))
+      s.inspect.should eq(%(#<StringScanner 16/16 …tring‣">))
     end
 
     it "works with small strings" do
       s = StringScanner.new("hi")
-      s.inspect.should eq(%(#<StringScanner 0/2 "hi" >))
-      s.scan(/\w\w/)
-      s.inspect.should eq(%(#<StringScanner 2/2 "hi" >))
+      s.inspect.should eq(%(#<StringScanner 0/2 "‣hi">))
+      s.scan(/\w/)
+      s.inspect.should eq(%(#<StringScanner 1/2 "h‣i">))
+      s.scan(/\w/)
+      s.inspect.should eq(%(#<StringScanner 2/2 "hi‣">))
+
+      s = StringScanner.new(" a\n\t ")
+      s.skip(1)
+      s.inspect.should eq(%(#<StringScanner 1/5 " ‣a\\n\\t ">))
+
+      s = StringScanner.new("\0\e")
+      s.skip(1)
+      s.inspect.should eq(%(#<StringScanner 1/2 "\\u0000‣\\e">))
+    end
+
+    it "works with multi-byte strings" do
+      s = StringScanner.new("これは文字列である")
+      s.inspect.should eq(%(#<StringScanner 0/9 "‣これは文字…>))
+      s.scan(1)
+      s.inspect.should eq(%(#<StringScanner 1/9 "こ‣れは文字…>))
+      s.scan(1)
+      s.inspect.should eq(%(#<StringScanner 2/9 "これ‣は文字…>))
+      s.scan(1)
+      s.inspect.should eq(%(#<StringScanner 3/9 …れは‣文字列…>))
+      s.scan(3)
+      s.inspect.should eq(%(#<StringScanner 6/9 …字列‣である">))
+      s.terminate
+      s.inspect.should eq(%(#<StringScanner 9/9 …字列である‣">))
+    end
+
+    it "works with empty string" do
+      s = StringScanner.new("")
+      s.inspect.should eq(%(#<StringScanner 0/0 "‣">))
     end
   end
 

src/string_scanner.cr

@@ -531,16 +531,34 @@ class StringScanner
     @str.byte_slice(@byte_offset, @str.bytesize - @byte_offset)
   end
 
+  private INSPECT_INDICATOR_CHAR = '‣'
+  private INSPECT_ELLIPSIS_CHAR  = '…'
+  private INSPECT_ENDING_CHAR    = '"'
+
   # Writes a representation of the scanner.
   #
   # Includes the current position of the offset, the total size of the string,
   # and five characters near the current position.
   def inspect(io : IO) : Nil
+    offset = self.offset
+    size = @str.size
+    remaining = size - offset
+
     io << "#<StringScanner "
-    offset = offset()
-    io << offset << '/' << @str.size
-    start = Math.min(Math.max(offset - 2, 0), Math.max(0, @str.size - 5))
-    io << " \"" << @str[start, 5] << "\" >"
+    io << offset << '/' << size << ' '
+
+    # find a range of 5 characters with the scan head as close to
+    # the middle as possible.
+    chars_after = Math.max(3, 5 - offset).clamp(0, remaining)
+    chars_before = (5 - chars_after).clamp(0, offset)
+
+    io << (chars_before < offset ? INSPECT_ELLIPSIS_CHAR : INSPECT_ENDING_CHAR)
+    peek_behind(chars_before).inspect_unquoted(io) if chars_before > 0
+    io << INSPECT_INDICATOR_CHAR
+    peek(chars_after).inspect_unquoted(io) if chars_after > 0
+    io << (chars_after < remaining ? INSPECT_ELLIPSIS_CHAR : INSPECT_ENDING_CHAR)
+
+    io << '>'
   end
 
   private def make_char_reader : Char::Reader