Deprecate single-letter macro fresh variables with indices (#16267)

Crystal supports 6 sigils which modify the meaning of string literals. Curly braces may be used instead of the usual double quotation marks for those strings:

```crystal
%i{1}
%q{2}
%Q{3}
%r{4}
%x{5}
%w{6}
```

The same syntax is used for fresh variables inside macros:

```crystal
macro foo
  {% for i in 1..6 %}
    %b{i} = {{ i }}
  {% end %}
  {% for i in 1..6 %}
    p %b{i}
  {% end %}
end

foo
```

It is a syntax error here to use a fresh variable name that coincides with one of the sigils, because the sigil has precedence and assignment to a string literal is never allowed. This is problematic since adding _any_ new sigil to the language, e.g. `%b` for #2886, immediately introduces a breaking change by making those macros no longer valid.

I believe the language should be more future-proof here, unless we can say for sure that new sigils must not be introduced.

Co-authored-by: fn ⌃ ⌥ <[email protected]>

Author: HertzDevil

spec/compiler/parser/warnings_spec.cr

@@ -19,6 +19,8 @@ private def assert_no_parser_warning(source, *, file = __FILE__, line = __LINE__
   warnings.should eq([] of String), file: file, line: line
 end
 
+VALID_SIGILS = ['i', 'q', 'r', 'w', 'x', 'Q']
+
 describe "Parser warnings" do
   it "warns on suffix-less UInt64 literals > Int64::MAX" do
     values = [
@@ -64,4 +66,36 @@ describe "Parser warnings" do
       assert_no_parser_warning("def foo : Foo\nend")
     end
   end
+
+  it "warns on single-letter macro fresh variables with indices" do
+    chars = ('A'..'Z').to_a + ('a'..'z').to_a - VALID_SIGILS
+    chars.each do |letter|
+      assert_parser_warning <<-CRYSTAL, "Warning: single-letter macro fresh variables with indices are deprecated"
+        macro foo
+          %#{letter}{1} = 2
+        end
+        CRYSTAL
+    end
+  end
+
+  it "doesn't warn on sigils that resemble single-letter macro fresh variables with indices" do
+    VALID_SIGILS.each do |letter|
+      assert_no_parser_warning <<-CRYSTAL
+        macro foo
+          %#{letter}{1}
+        end
+        CRYSTAL
+    end
+  end
+
+  it "doesn't warn on single-letter macro fresh variables without indices" do
+    ('A'..'Z').each do |letter|
+      assert_no_parser_warning <<-CRYSTAL
+        macro foo
+          %#{letter} = 1
+          %#{letter.downcase} = 2
+        end
+        CRYSTAL
+    end
+  end
 end

src/compiler/crystal/syntax/parser.cr

@@ -3281,6 +3281,9 @@ module Crystal
           macro_var_name = @token.value.to_s
           location = @token.location
           if current_char == '{'
+            if macro_var_name.size == 1
+              warnings.add_warning_at @token.location, "single-letter macro fresh variables with indices are deprecated"
+            end
             macro_var_exps = parse_macro_var_exps
           else
             macro_var_exps = nil

src/iterator.cr

@@ -1457,13 +1457,13 @@ module Iterator(T)
     def next
       {% begin %}
         {% for i in 0...Is.size %}
-          %v{i} = @iterators[{{ i }}].next
-          return stop if %v{i}.is_a?(Stop)
+          %value{i} = @iterators[{{ i }}].next
+          return stop if %value{i}.is_a?(Stop)
         {% end %}
 
         Tuple.new(
           {% for i in 0...Is.size %}
-            %v{i},
+            %value{i},
           {% end %}
         )
       {% end %}