Add Process.debugger_present? for Windows and Linux (#16248)

Author: HertzDevil

spec/std/process_spec.cr

@@ -442,6 +442,12 @@ describe Process do
 
   typeof(Process.new(*standing_command).terminate(graceful: false))
 
+  describe ".debugger_present?" do
+    it "compiles" do
+      typeof(Process.debugger_present?)
+    end
+  end
+
   it ".exists?" do
     # On Windows killing a parent process does not reparent its children to
     # another existing process, so the following isn't guaranteed to work

src/crystal/system/process.cr

@@ -56,6 +56,9 @@ struct Crystal::System::Process
   # Restores default handling of interrupt requests.
   # def self.restore_interrupts!
 
+  # Returns whether a debugger is attached to the current process.
+  # def self.debugger_present? : Bool
+
   # Spawns a fiber responsible for executing interrupt handlers on the main
   # thread.
   # def self.start_interrupt_loop

src/crystal/system/unix/process.cr

@@ -100,6 +100,21 @@ struct Crystal::System::Process
     # do nothing; `Crystal::System::Signal.start_loop` takes care of this
   end
 
+  def self.debugger_present? : Bool
+    {% if flag?(:linux) %}
+      ::File.each_line("/proc/self/status") do |line|
+        if tracer_pid = line.lchop?("TracerPid:").try(&.to_i?)
+          return true if tracer_pid != 0
+        end
+      end
+    {% end %}
+
+    # TODO: [Darwin](https://stackoverflow.com/questions/2200277/detecting-debugger-on-mac-os-x)
+    # TODO: other BSDs
+    # TODO: [Solaris](https://docs.oracle.com/cd/E23824_01/html/821-1473/proc-4.html)
+    false
+  end
+
   def self.exists?(pid)
     ret = LibC.kill(pid, 0)
     if ret == 0

src/crystal/system/wasi/process.cr

@@ -68,6 +68,10 @@ struct Crystal::System::Process
   def self.start_interrupt_loop : Nil
   end
 
+  def self.debugger_present? : Bool
+    false
+  end
+
   def self.exists?(pid)
     raise NotImplementedError.new("Process.exists?")
   end

src/crystal/system/win32/process.cr

@@ -3,6 +3,7 @@ require "c/handleapi"
 require "c/jobapi2"
 require "c/synchapi"
 require "c/tlhelp32"
+require "c/debugapi"
 require "process/shell"
 require "crystal/atomic_semaphore"
 
@@ -229,6 +230,10 @@ struct Crystal::System::Process
     end
   end
 
+  def self.debugger_present? : Bool
+    LibC.IsDebuggerPresent != 0
+  end
+
   def self.exists?(pid)
     handle = LibC.OpenProcess(LibC::PROCESS_QUERY_INFORMATION, 0, pid)
     return false unless handle

src/lib_c/x86_64-windows-msvc/c/debugapi.cr

@@ -0,0 +1,5 @@
+require "c/win_def"
+
+lib LibC
+  fun IsDebuggerPresent : BOOL
+end

src/process.cr

@@ -110,6 +110,15 @@ class Process
     Crystal::System::Process.restore_interrupts!
   end
 
+  # Returns whether a debugger is attached to the current process.
+  #
+  # Currently supported on Windows and Linux. Always returns `false` on other
+  # systems.
+  @[Experimental]
+  def self.debugger_present? : Bool
+    Crystal::System::Process.debugger_present?
+  end
+
   # Returns `true` if the process identified by *pid* is valid for
   # a currently registered process, `false` otherwise. Note that this
   # returns `true` for a process in the zombie or similar state.