Add Cab support

Author: RGBCube

languages.toml

@@ -552,6 +552,20 @@ args = { console = "internalConsole", attachCommands = [ "platform select remote
 name = "c"
 source = { git = "https://github.com/tree-sitter/tree-sitter-c", rev = "7175a6dd5fc1cee660dce6fe23f6043d75af424a" }
 
+[[language]]
+name = "cab"
+scope = "source.cab"
+injection-regex = "cab"
+file-types = ["cab"]
+shebangs = []
+comment-token = "#"
+language-servers = []
+indent = { tab-width = 2, unit = "  " }
+
+[[grammar]]
+name = "cab"
+source = { git = "https://github.com/cull-os/tree-sitter-cab", rev = "da2650f1761789e70c716d7c8c7fd6a494facdd6" }
+
 [[language]]
 name = "cpp"
 scope = "source.cpp"

runtime/queries/cab/highlights.scm

@@ -0,0 +1,84 @@
+(singleline_comment) @comment.line
+(multiline_comment) @comment.block
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  ","
+  ";"
+] @punctuation.delimiter
+
+(prefix_operation
+  operator: _ @operator)
+
+(infix_operation
+  operator: _ @operator)
+
+; Not a keyword, but use the colors anyway.
+((identifier) @keyword.control.import
+  (#match? @keyword.control.import "^(import|provide|expect)$")
+  (#is-not? local))
+
+((identifier) @keyword.control.exception
+  (#match? @keyword.control.exception "^error$")
+  (#is-not? local))
+
+((identifier) @type.builtin
+  (#match? @type.builtin "^(list|attributes|string|number)$")
+  (#is-not? local))
+
+((identifier) @variable.builtin
+ (#match? @variable.builtin "^(true|false|null)$")
+ (#is-not? local))
+
+(infix_operation
+  operator: "|>"
+  right: _ @function)
+
+(infix_operation
+  left: _ @function
+  !operator)
+
+(infix_operation
+  left: _ @function
+  operator: "<|")
+
+(infix_operation
+  operator: "."
+  right: (identifier) @variable.other.member)
+
+(suffix_operation
+  operator: _ @operator)
+
+(interpolation
+  "\\(" @punctuation.special
+  ")" @punctuation.special)
+
+[
+  (path)
+  (island)
+] @string.special.path
+
+(pattern_identifier) @variable.parameter
+
+(identifier) @variable
+
+(string) @string
+
+(escape) @constant.character.escape
+
+[
+  "if"
+  "then"
+  "is"
+  "else"
+] @keyword.control.conditional
+
+(number) @constant.numeric

runtime/queries/cab/indents.scm

@@ -0,0 +1,13 @@
+[
+  (parenthesis)
+  (list)
+  (attribute_list)
+  (string)
+] @indent
+
+[
+  ")"
+  "]"
+  "}"
+  (string_end)
+] @outdent