Working on branches

Author: AndreasArvidsson

data/fixtures/scopes/csharp/attribute.scope

@@ -0,0 +1,3 @@
+[Obsolete("Deprecated")]
+void foo() {}
+---

packages/common/src/scopeSupportFacets/csharp.ts

@@ -1,8 +1,7 @@
 import type { LanguageScopeSupportFacetMap } from "./scopeSupportFacets.types";
 import { ScopeSupportFacetLevel } from "./scopeSupportFacets.types";
 
-// eslint-disable-next-line @typescript-eslint/no-unused-vars
-const { supported, unsupported, notApplicable } = ScopeSupportFacetLevel;
+const { supported, notApplicable } = ScopeSupportFacetLevel;
 
 export const csharpScopeSupport: LanguageScopeSupportFacetMap = {
   ifStatement: supported,
@@ -11,6 +10,7 @@ export const csharpScopeSupport: LanguageScopeSupportFacetMap = {
   map: supported,
   list: supported,
   disqualifyDelimiter: supported,
+  attribute: supported,
 
   class: supported,
   "class.iteration.document": supported,
@@ -35,6 +35,15 @@ export const csharpScopeSupport: LanguageScopeSupportFacetMap = {
   "functionName.method": supported,
   "functionName.method.iteration.class": supported,
 
+  "branch.if": supported,
+  "branch.if.iteration": supported,
+  "branch.try": supported,
+  "branch.try.iteration": supported,
+  "branch.switchCase": supported,
+  "branch.switchCase.iteration": supported,
+  "branch.ternary": supported,
+  "branch.loop": supported,
+
   "condition.for": supported,
   "condition.while": supported,
   "condition.doWhile": supported,
@@ -83,5 +92,7 @@ export const csharpScopeSupport: LanguageScopeSupportFacetMap = {
   "argument.formal.method": supported,
   "argument.formal.method.iteration": supported,
 
+  //   Not applicable
+
   regularExpression: notApplicable,
 };

queries/csharp.scm

@@ -50,6 +50,77 @@
 
 (if_statement) @ifStatement
 
+;;!! if () {}
+;;!  ^^^^^^^^
+(
+  (if_statement
+    condition: (_) @condition
+    consequence: (_) @branch.end.endOf @branch.removal.end.endOf
+    alternative: (_)? @branch.removal.end.startOf
+  ) @branch.start.startOf @branch.removal.start.startOf @condition.domain
+  (#not-parent-type? @condition.domain "if_statement")
+)
+
+;;!! else if () {}
+;;!  ^^^^^^^^^^^^^
+(if_statement
+  "else" @branch.start.startOf @condition.domain.start.startOf
+  (if_statement
+    condition: (_) @condition
+    consequence: (_) @branch.end.endOf @condition.domain.end.endOf
+  )
+)
+
+;;!! else {}
+;;!  ^^^^^^^
+(if_statement
+  "else" @branch.start
+  alternative: (block) @branch.end
+)
+
+;;!! if () {} else if () {} else {}
+;;!  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
+(
+  (if_statement) @branch.iteration
+  (#not-parent-type? @branch.iteration "if_statement")
+)
+
+;;!! try () {}
+;;!  ^^^^^^^^^
+(try_statement
+  body: (_) @branch.end.endOf
+) @branch.start.startOf
+
+;;!! catch () {}
+;;!  ^^^^^^^^^^^
+(catch_clause) @branch
+
+;;!! finally {}
+;;!  ^^^^^^^^^^
+(finally_clause) @branch
+
+;;!! try () {} catch () {} finally {}
+;;!  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
+(try_statement) @branch.iteration
+
+[
+  (for_statement)
+  (for_each_statement)
+  (while_statement)
+  (do_statement)
+] @branch
+
+;;!! true ? 0 : 1;
+;;!  ^^^^
+;;!         ^   ^
+(conditional_expression
+  condition: (_) @condition
+  consequence: (_) @branch
+) @condition.domain
+(conditional_expression
+  alternative: (_) @branch
+) @condition.domain
+
 (class_declaration
   name: (identifier) @className
 ) @class @_.domain
@@ -75,10 +146,13 @@
   (string_literal) @string @textFragment
   (#child-range! @textFragment 0 -1 true true)
 )
+
 (comment) @comment @textFragment
 
 (lambda_expression) @anonymousFunction
 
+(attribute) @attribute
+
 [
   (delegate_declaration
     name: (_) @functionName