Update algorithm for "poincare Module" (Macaulay2#4099)

* Update algorithm for "poincare Module"

* Revised update to poincare Module

* Update algorithm for "poincare Module"

* Tests for updated "poincare Module"

* Updated algorithm for "poincare Module", avoiding an infinite loop revealed by the previous test

Author: btotaro

M2/Macaulay2/m2/hilbert.m2

@@ -84,8 +84,21 @@ poincare Module := M -> (
     if (P := computation M) =!= null then return P;
     error("no applicable strategy for computing poincare over ", toString ring M))
 
+-- Use that the Poincare polynomial of a subquotient module M is the difference of the Poincare polynomials of two quotients.
+-- This avoids having to find a presentation of M (unless that has already been done).
 addHook((poincare, Module), Strategy => Default, M -> (
-	new degreesRing ring M from rawHilbert raw leadTerm gb presentation M))
+        hf := if any(select(keys M.cache, Option), o -> o#0 === symbol minimalPresentation) then
+                  rawHilbert raw leadTerm gb relations minimalPresentation M
+              -- We cannot just call "poincare minimalPresentation M", because there are cases (such as M free)
+              -- where both M and minimalPresentation M are cached as having a minimal presentation;
+              -- so that would lead to an infinite loop. 
+              else if not M.?generators then
+                  rawHilbert raw leadTerm gb relations M
+              else if M.cache.?presentation then
+                  rawHilbert raw leadTerm gb M.cache.presentation
+              else (rawHilbert raw leadTerm gb relations M) - (rawHilbert raw leadTerm gb M);
+        new degreesRing ring M from hf
+        ))
 
 -- manually installs the numerator of the reduced Hilbert series for the module
 storefuns#poincare = method()

M2/Macaulay2/tests/normal/poincare3.m2

@@ -0,0 +1,17 @@
+R = QQ[x,y,z]
+M1 = module(ideal(x,y,z))
+hf = poincare M1
+T = (ring hf)_0
+assert(hf == poly"3T-3T2+T3")
+assert(hf == poincare res M1)
+
+M2 = minimalPresentation M1
+assert(hf == poincare M1)
+assert(hf == poincare M2)
+
+R2 = ZZ/101[x0,x1,x2,Degrees=>{1,3,5}]
+M3 = module(ideal(x0,x1))
+pres3 = presentation M3
+hf3 = poincare M3
+U = (ring hf3)_0
+assert(hf3 == poly"U+U3-U4")