Scheme-meta-circular-evaluator/utils.scm at master · daicang/Scheme-meta-circular-evaluator · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
;; utils.scm
;;
;; Handling assignment, definition, lambda and control paths.
;;
;; Require:
;; environment.scm


;; Tagged-list/quote/self-evaluating/variable
(define (tagged-list? exp tag)
  (if (pair? exp)
      (eq? (car exp) tag)
      #f))

(define (quoted? exp)
  (tagged-list? exp 'quote))

(define (text-of-quotation exp) (cadr exp))

(define (self-evaluating? exp)
  (cond ((number? exp) #t)
	((string? exp) #t)
	((or (eq? exp #t) (eq? exp #f)) #t)
	(else #f)))

(define (variable? exp) (symbol? exp))


;; Ture/false
(define (true? x) (not (eq? x #f)))

(define (false? x) (eq? x #f))


;; Sequence
;; ((exp1) (exp2) ..)
(define (sequence->exp seq)
  (cond ((null? seq) seq)
	((last-exp? seq) (first-exp seq))
	(else (make-begin seq))))


;; Assignment
;; (set! a b)
(define (assignment? exp) (tagged-list? exp 'set!))

(define (assignment-variable exp) (cadr exp))

(define (assignment-value exp) (caddr exp))

;; called by eval-assignment
(define (set-variable-value! var val env)
  (define (env-loop env)
    (define (scan vars vals)
      (cond ((null? vars)
	     (env-loop (enclosing-environment env)))
	    ((eq? (car vars) var)
	     (set-car! vals val))
	    (else (scan (cdr vars) (cdr vals)))))
    (if (eq? env the-empty-environment)
	(error "Unbound variable -- set-variable-value!" var)
	(let ((frame (first-frame env)))
	  (scan (frame-variables frame) (frame-values frame)))))
  (env-loop env))


;; Definition
(define (definition? exp) (tagged-list? exp 'define))

;; (define <variable> <body>)
;; or (define (<variable> <parameters>) <body>)
(define (definition-variable exp)
  (if (symbol? (cadr exp))
      (cadr exp)
      (caadr exp)))

(define (definition-value exp)
  (if (symbol? (cadr exp))
      (caddr exp)    ;; Variable definition.
      (make-lambda   ;; Function definition, make it lambda.
       (cdadr exp)   ;; <parameters>
       (cddr exp)))) ;; <body>


;; Lambda expression
;; (lambda (<parameters>) <body>)
(define (lambda? exp) (tagged-list? exp 'lambda))

(define (lambda-parameters exp) (cadr exp))

(define (lambda-body exp) (cddr exp))

(define (make-lambda parameters body)
  (cons 'lambda (cons parameters body)))


;; Control structures

;; if
;; (if <predicate> <consequent> <alternative>)
;; Note <alternative> is optional.
(define (if? exp) (tagged-list? exp 'if))

(define (if-predicate exp) (cadr exp))

(define (if-consequent exp) (caddr exp))

(define (if-alternative exp)
  (if (null? (cdddr exp))
      'false
      (cadddr exp)))

(define (make-if predicate consequent alternative)
  (list 'if predicate consequent alternative))

;; cond
;; (cond ((<predicate1>) <action1>)
;;       ((<predicate2>) <action2>)
;;       (else <action-else>))
(define (cond? exp) (tagged-list? exp 'cond))

(define (cond-clauses exp) (cdr exp))

(define (cond-predicate clause) (car clause))

(define (cond-actions clause) (cdr clause))

(define (cond-else-clause? clause) (eq? (cond-predicate clause) 'else))

(define (cond->if exp)
  (expand-clauses (cond-clauses exp)))

(define (expand-clauses clauses)
  (if (null? clauses)
      'false
      (let ((first (car clauses))
	    (rest (cdr clauses)))
	(if (cond-else-clause? first)
	    (if (null? rest)
		(sequence->exp (cond-actions first))
		(error "else clause isn't last -- cond->if" clause))
	    (make-if (cond-predicate first)
		     (sequence->exp (cond-actions first))
		     (expand-clauses rest))))))


;; begin
(define (begin? exp) (tagged-list? exp 'begin))

(define (begin-actions exp) (cdr exp))

(define (first-exp exp) (car exp))

(define (rest-exps exp) (cdr exp))

(define (last-exp? exp) (null? (cdr exp)))

(define (make-begin exp) (cons 'begin exp))


;; let
;; (let ((<variable1> <value1>) (<variable2> <value2>)) <body>)
;; Note that <body> should be one single expression,
;; use 'begin' if you have multiple expressions.
(define (let? exp) (tagged-list? exp 'let))

(define (let-clauses exp) (cadr exp))

(define (let-body exp) (caddr exp)) ;; Single expression

(define (let-variables clauses)
  (if (null? clauses)
      '()
      (cons (caar clauses)
	    (let-variables (cdr clauses)))))

(define (let-exps clauses)
  (if (null? clauses)
      '()
      (cons (cadar clauses)
	    (let-exps (cdr clauses)))))

;; let handler
;; Make let a lambda application.
;; ((lambda <varibales> <body>) <values>)
(define (let->combination exp)
  (append (list (list 'lambda (let-variables (let-clauses exp)) (let-body exp)))
	  (let-exps (let-clauses exp))))

;; Named let
;;
;; (let <name> ((<variable1> <value1>) ...) <body>)
;;
;; Transform into:
;; (define (<name> <variables>) <body>)(<name> <values>)
(define (named-let? exp) (and (let? exp) (symbol? (cadr exp))))

(define (named-let-name exp) (cadr exp))

(define (named-let-clauses exp) (caddr exp))

(define (named-let-variables exp)
  (map (lambda (x) (car x)) (named-let-clauses exp)))

(define (named-let-values exp)
  (map (lambda (x) (cadr x)) (named-let-clauses exp)))

(define (named-let-body exp) (cadddr exp))

(define (named-let->combination exp)
  (let ((define-part
	  (cons 'define
		(list (cons (named-let-name exp)
			    (named-let-variables exp))
		      (named-let-body exp))))
	(application-part
	 (cons (named-let-name exp)
	       (named-let-values exp))))
    (make-begin (list define-part application-part))))

;; let*
;;
;; (let* ((<variable1> <value1>) (<variable2> <value2>) ...) <actions>)
;;
;; Transform into:
;;
;; (let ((<variable1> <value1>))
;;   (let ((<variable2> <value2>)))
;;     ...
;;     <actions>)
(define (let*? exp) (tagged-list? exp 'let*))

(define (let*-clauses exp) (cadr exp))

(define (let*-actions exp) (caddr exp))

(define (first-clause clauses) (car clauses))

(define (rest-clauses clauses) (cdr clauses))

(define (let*->nested-lets exp)
  (define (loop clauses actions)
    (if (null? clauses)
	actions
	(list 'let
	      (list (first-clause clauses))
	      (loop (rest-clauses clauses) actions))))
  (loop (let*-clauses exp) (let*-actions exp)))

;; letrec
;;
;; (letrec <clauses> <actions>)
;; ((<variable1> <value1>) (<variable2> <value2>) ...)
;;
;; Transform into:
;;
;; (let ((<varibale1> '*unassigned*) (<variable2> '*unassigned*) ...)
;;   (begin
;;     (set! <variable1> <value1>)
;;     (set! <variable2> <value2>)
;;     ...
;;     <actions>))
(define (letrec? exp) (tagged-list? exp 'letrec))

(define (letrec-clauses exp) (cadr exp))

(define (letrec-actions exp) (caddr exp))

(define (letrec->let-and-set exp)
  (let ((let-part
	 (list 'let
	       (map (lambda (x) (list (car x) ''*unassigned*))
		    (letrec-clauses exp))))
	(begin-part
	 (cons 'begin
	       (append (map (lambda (x) (cons 'set! x))
		    (letrec-clauses exp)) (list(letrec-actions exp))))))
    (append let-part (list begin-part))))


;; Application
;; All pairs (none-empty list) are recognized as application.
(define (application? exp) (pair? exp))

(define (operator exp) (car exp))

(define (operands exp) (cdr exp))

(define (no-operands? exp) (null? exp))

(define (first-operand exp) (car exp))

(define (rest-operands exp) (cdr exp))


;; Input from file
(define (load? exp) (tagged-list? exp 'load))

(define (load-file exp) (cadr exp))