Output analog reference voltage from AVREF

[xenos1984]

According to the datasheet, section on "12-bit analog-to-digital converter (ADC)", "Register definition", bit 0 (ADTM) in ADCSRC (ADC Control Status Register C) says:

Test mode, output internal reference voltage from AVREF port

I have set this bit to 1, and I get an output voltage of about 0.611V on AVREF, no matter which reference voltage I select.

The board is a Wavgat Uno with LGT8F328P at Vcc = 3.3V.

Am I missing something? Does anyone have experience getting the internal reference voltage on AVREF?

[hmeijdam]

You may want to share your test sketch, so others can reproduce your test.

[xenos1984]

Sure! Here it is:

#include <avr/io.h>

void setup()
{
    // Set reference voltage.
    analogReference(INTERNAL1V024);

    // Enable reference voltage output.
    ADCSRC |= 0x01;
}

void loop()
{
}

With this I would expect AVREF = 1.024V.

[hmeijdam]

Doesn't work for me as well. Tried a whole bunch of registry options, but never output on AREF.

If I look at the ADC functional diagram I also do not see AREF connected to a mosfet, so that you could turn it on as output. Only connected to the input multiplexer. puzzling me.

[xenos1984]

So you have no output at all? I am puzzled, since for ADTM = 0 I get no output on AVREF (goes on high impedance), but for ADTM = 1 I get around 0.611V. Since this "feature" is not documented in the datasheet, except for one line in the description of ADCSRC, I wonder whether this is even supposed to output IVREF on that pin, or some internal voltage (maybe a diode?) from which the different IVREF are derived when one sets the corresponding VCAL registers. That would also explain why it's not mentioned in the diagram.

[hmeijdam]

Yup. No output whatever I try.

[vklimk]

Try this:

// Следующий скетч  поочерёдно выводит внутренние референсные
// напряжения на вывод AVREF (REF arduino). Можно проконтролировать
// их точным вольтметром, и например учесть в расчётах. Или подкрутить
// заводские калибровочные константы VCAL*

void setup() {
  Serial.begin(115200);
  ADCSRA |= 1<<ADEN | 1<<ADPS2 |1<<ADPS0; // clk/32
  ADCSRB = 0;       // непрерывный режим преобразования
  ADMUX = 0x0D;     // источника входного сигнала АЦП - IVREF
  ADCSRC = 1<<ADTM; // Тестовый режим, внутреннее опорное напряжение от выходного порта AVREF
  DIDR1 = 1<<PE6D;  // Выкл. Функция цифрового входа PE6 (REF arduino)
}

void loop() {
  Serial.print("Set AREF pin -> 4,096v; VCAL3=0x");
  Serial.println(VCAL3, HEX);
  ADCSRD = 1<<BGEN | 1<<IVSEL1;
  VCAL = VCAL3;
  mydelay(); // моя плата выдает 4,084V

  Serial.print("Set AREF pin -> 2,048v; VCAL2=0x");
  Serial.println(VCAL2, HEX);
  ADCSRD = 1<<BGEN | 1<<IVSEL0;
  VCAL = VCAL2;
  mydelay(); // моя плата выдает 2,046V

  Serial.print("Set AREF pin -> 1,024v; VCAL1=0x");
  Serial.println(VCAL1, HEX);
  ADCSRD = 1<<BGEN;
  VCAL = VCAL1;
  mydelay(); // моя плата выдает 1,023V
}

void mydelay(){
  for (byte n=0; n<=5; n++ ){
     Serial.print("."); delay(1000);
  }
  Serial.println();
}

[hmeijdam]

Nicely done. This outputs the 3 different voltages in sequence. Now I need to understand where I missed something.

[xenos1984]

That works for me as well, thanks!

I see that I'm missing at least BGEN in ADCSRD and PE6D in DIDR1, but adding only those to my original code was not enough. Apparently setting ADMUX to IVREF is also necessary - I wouldn't have expected that.