transform to oms order

Author: tamizhvendan

clojure/wheel/.gitignore

@@ -10,3 +10,4 @@ pom.xml.asc
 /.nrepl-port
 .hgignore
 .hg/
+tasks.todo

clojure/wheel/src/wheel/marketplace/tata_cliq/api.clj

@@ -1,6 +1,6 @@
 (ns wheel.marketplace.tata-cliq.api
   (:require [clj-http.client :as http]
-            [wheel.xml :as wheel-xml]))
+            [wheel.marketplace.tata-cliq.order :as tata-cliq-order]))
 
 (defn ranging [{:keys [base-url bearer-token]} channel-id items]
   (let [url         (str base-url "/channels/" channel-id "/ranging")
@@ -9,22 +9,16 @@
                     :content-type :json
                     :headers      {:authorization auth-header}})))
 
-(defn- vectorize [x]
-  (if (vector? x)
-    x
-    (vector x)))
-
 (defn new-orders [{:keys [base-url bearer-token]} channel-id]
   (let [url         (str base-url "/channels/" channel-id "/new-orders")
         auth-header (str "Bearer " bearer-token)]
     (-> (http/get url {:headers {:authorization auth-header}})
         :body
-        wheel-xml/xml-str->map
-        (get-in [:orders :order])
-        vectorize)))
+        tata-cliq-order/parse-new-orders)))
 
 (comment
-
+  (BigDecimal. "1")
+  (Integer/parseInt "600001")
   (new-orders {:base-url     "http://localhost:3000"
                :bearer-token "top-secret!"}
               "UB"))

clojure/wheel/src/wheel/marketplace/tata_cliq/order.clj

@@ -0,0 +1,75 @@
+(ns wheel.marketplace.tata-cliq.order
+  (:require [wheel.oms.order :as order]
+            [clojure.spec.alpha :as s]
+            [clojure.set :as set]
+            [wheel.xml :as w-xml]))
+
+(defn- vectorize [x]
+  (if (vector? x)
+    x
+    (vector x)))
+
+(defn- coarce-new-order-lines [new-order-lines]
+  (map (fn [ol]
+         (update ol :price #(BigDecimal. %))) new-order-lines))
+
+(defn- coarce-new-orders [orders]
+  (map (fn [order]
+         (-> (update-in order [:address-info :billing :pincode] #(Integer/parseInt %))
+             (update-in [:address-info :shipping :pincode] #(Integer/parseInt %))
+             (update-in [:payment-info :payment-cost] #(BigDecimal. %))
+             (assoc :order-lines (coarce-new-order-lines (:order-lines order)))))
+       orders))
+
+(defn- cleanse-new-order [orders]
+  (map #(assoc % :order-lines
+               (vectorize (get-in % [:order-lines :order-line]))) orders))
+
+(defn parse-new-orders [xml-response]
+  (-> (w-xml/xml-str->map xml-response)
+      (get-in [:orders :order])
+      vectorize
+      cleanse-new-order
+      coarce-new-orders))
+
+(defn- to-oms-address [tata-cliq-address]
+  (set/rename-keys tata-cliq-address {:address1 :line1
+                                      :address2 :line2}))
+
+(defn to-oms-order [tata-cliq-order]
+  {:post [(s/assert ::order/order %)]}
+  (let [{:keys [address-info order-no order-lines payment-info]} tata-cliq-order
+        {:keys [shipping billing]}                               address-info
+        {:keys [payment-cost payment-id]}                        payment-info]
+    {:billing     (to-oms-address billing)
+     :shipping    (to-oms-address shipping)
+     :order-no    order-no
+     :payments    [{:amount       payment-cost
+                    :reference-id payment-id}]
+     :order-lines (map (fn [{:keys [article-number price]}]
+                         {:id         article-number
+                          :sale-price price})
+                       order-lines)}))
+
+(comment
+  (s/check-asserts true)
+  (map to-oms-order [{:address-info {:billing  {:address1   "Plot No 222"
+                                                :address2   "Ashok Nagar 42nd Street"
+                                                :city       "Chennai"
+                                                :first-name "Tamizhvendan"
+                                                :last-name  "Sembiyan"
+                                                :pincode    600001
+                                                :state      "TamilNadu"}
+                                     :shipping {:address1   "Plot No 222"
+                                                :address2   "Ashok Nagar 42nd Street"
+                                                :city       "Chennai"
+                                                :first-name "Tamizhvendan"
+                                                :last-name  "Sembiyan"
+                                                :pincode    600001
+                                                :state      "TamilNadu"}}
+                      :order-lines  [{:article-number "200374"
+                                      :price          900.0M
+                                      :transaction-id "200058001702351"}]
+                      :order-no     "181219-001-345786"
+                      :payment-info {:payment-cost 900.0M
+                                     :payment-id   "000000-1545216772601"}}]))

clojure/wheel/src/wheel/oms/address.clj

@@ -0,0 +1,17 @@
+(ns wheel.oms.address
+  (:require [clojure.spec.alpha :as s]
+            [wheel.string :as w-str]))
+
+(s/def ::first-name w-str/not-blank?)
+(s/def ::last-name w-str/not-blank?)
+(s/def ::line1 w-str/not-blank?)
+(s/def ::line2 w-str/not-blank?)
+(s/def ::city w-str/not-blank?)
+(s/def ::state w-str/not-blank?)
+(s/def ::pincode (s/int-in 110001 855118))
+
+(s/def ::address (s/keys :req-un [::first-name ::line1 ::city ::state ::pincode]
+                          :opt-un [::last-name ::line2]))
+
+(s/def ::shipping ::address)
+(s/def ::billing ::address)

clojure/wheel/src/wheel/oms/order.clj

@@ -0,0 +1,33 @@
+(ns wheel.oms.order
+  (:require [clojure.spec.alpha :as s]
+            [wheel.oms.address :as addr]
+            [wheel.oms.payment :as payment]
+            [wheel.oms.order-line :as order-line]
+            [wheel.string :as w-str]))
+
+(s/def ::order-no w-str/not-blank?)
+(s/def ::payments (s/coll-of ::payment/payment :min-count 1))
+(s/def ::order-lines (s/coll-of ::order-line/order-line :min-count 1))
+(s/def ::order (s/keys :req-un [::order-no ::addr/shipping ::addr/billing ::payments
+                                ::order-lines]))
+
+(comment
+  (s/valid? ::order {:order-no "181219-001-345786"
+                     :payments [{:amount 900M
+                                 :reference-id "000000-1545216772601"}]
+                     :order-lines [{:id "200374"
+                                    :sale-price 900M}]
+                     :billing  {:first-name "Tamizhvendan"
+                                :last-name  "Sembiyan"
+                                :line1      "Plot No 222"
+                                :line2      "Ashok Nagar 42nd Street"
+                                :city       "Chennai"
+                                :state      "TamilNadu"
+                                :pincode    600001}
+                     :shipping {:first-name "Tamizhvendan"
+                                :last-name  "Sembiyan"
+                                :line1      "Plot No 222"
+                                :line2      "Ashok Nagar 42nd Street"
+                                :city       "Chennai"
+                                :state      "TamilNadu"
+                                :pincode    600001}}))

clojure/wheel/src/wheel/oms/order_line.clj

@@ -0,0 +1,7 @@
+(ns wheel.oms.order-line
+  (:require [wheel.oms.item :as item]
+            [clojure.spec.alpha :as s]))
+
+(s/def ::sale-price (s/and decimal? pos?))
+
+(s/def ::order-line (s/keys :req-un [::item/id ::sale-price]))

clojure/wheel/src/wheel/oms/payment.clj

@@ -0,0 +1,9 @@
+(ns wheel.oms.payment
+  (:require [clojure.spec.alpha :as s]
+            [wheel.string :as w-str]))
+
+(s/def ::amount (s/and decimal? pos?))
+(s/def ::reference-id w-str/not-blank?)
+
+(s/def ::payment (s/keys :req-un [::amount ::reference-id]))
+

clojure/wheel/src/wheel/string.clj

@@ -0,0 +1,5 @@
+(ns wheel.string
+  (:require [clojure.string :as str]))
+
+(defn not-blank? [s]
+  (and (string? s) (not (str/blank? s))))