finished day 6

Author: devries

README.md

@@ -1,7 +1,7 @@
 # Advent of Code 2025
 
 [![Tests](https://github.com/devries/advent_of_code_2025/actions/workflows/test.yml/badge.svg)](https://github.com/devries/advent_of_code_2025/actions/workflows/test.yml)
-[![Stars: 10](https://img.shields.io/badge/⭐_Stars-10-yellow)](https://adventofcode.com/2025)
+[![Stars: 12](https://img.shields.io/badge/⭐_Stars-12-yellow)](https://adventofcode.com/2025)
 
 This year will be my second year doing Advent of Code in [Gleam](https://gleam.run).
 Last year I was still learning the language, and in the past year I have used it
@@ -40,3 +40,4 @@ information.
 - [Day 3](https://adventofcode.com/2025/day/3): [⭐ ⭐ solution](src/day03/solution.gleam)
 - [Day 4](https://adventofcode.com/2025/day/4): [⭐ ⭐ solution](src/day04/solution.gleam)
 - [Day 5](https://adventofcode.com/2025/day/5): [⭐ ⭐ solution](src/day05/solution.gleam)
+- [Day 6](https://adventofcode.com/2026/day/6): [⭐ ⭐ solution](src/day06/solution.gleam)

inputs

@@ -0,0 +1,111 @@
+import gleam/int
+import gleam/io
+import gleam/list
+import gleam/result
+import gleam/string
+import internal/aoc_utils
+
+pub fn main() {
+  let filename = "inputs/day06.txt"
+
+  let lines_result = aoc_utils.read_lines(from: filename)
+  case lines_result {
+    Ok(lines) -> {
+      // If the file was converting into a list of lines
+      // successfully then run each part of the problem
+      aoc_utils.run_part_and_print("Part 1", fn() { solve_p1(lines) })
+      aoc_utils.run_part_and_print("Part 2", fn() { solve_p2(lines) })
+    }
+    Error(_) -> io.println("Error reading file")
+  }
+}
+
+// Part 1
+pub fn solve_p1(lines: List(String)) -> Result(String, String) {
+  lines
+  |> list.map(fn(line) {
+    line
+    |> string.split(" ")
+    |> list.filter(fn(v) { v != "" })
+  })
+  |> list.transpose
+  |> list.map(perform_calculation)
+  |> int.sum
+  |> int.to_string
+  |> Ok
+}
+
+// Part 2
+pub fn solve_p2(lines: List(String)) -> Result(String, String) {
+  let line_length =
+    list.fold(lines, 0, fn(acc, v) { int.max(acc, string.length(v)) })
+
+  lines
+  |> list.map(fn(line) {
+    let new_line =
+      string.to_graphemes(line)
+      |> list.reverse
+
+    let n = line_length - list.length(new_line)
+    list.append(list.repeat(" ", n), new_line)
+  })
+  |> list.transpose
+  |> list.filter(fn(l) {
+    list.fold_until(l, False, fn(_, v) {
+      case v == " " {
+        True -> list.Continue(False)
+        False -> list.Stop(True)
+      }
+    })
+  })
+  |> list.map(fn(column) {
+    let l = list.length(column)
+    let #(numbers, operation) = list.split(column, l - 1)
+    let assert Ok(value) = string.join(numbers, "") |> string.trim |> int.parse
+    #(value, operation)
+  })
+  |> accumulate_operation(0, [])
+  |> int.to_string
+  |> Ok
+}
+
+fn perform_calculation(parts: List(String)) -> Int {
+  let l = list.length(parts)
+  let #(values, operation) = list.split(parts, l - 1)
+
+  let int_values =
+    values
+    |> list.map(int.parse)
+    |> result.values
+
+  case operation {
+    ["+"] -> int.sum(int_values)
+    ["*"] -> list.fold(int_values, 1, fn(acc, v) { acc * v })
+    _ -> {
+      echo parts
+      panic as "unexpected operation"
+    }
+  }
+}
+
+fn accumulate_operation(
+  tuples: List(#(Int, List(String))),
+  sum: Int,
+  values: List(Int),
+) -> Int {
+  case tuples {
+    [] -> sum
+    [first, ..rest] -> {
+      case first {
+        #(n, [" "]) -> accumulate_operation(rest, sum, [n, ..values])
+        #(n, ["*"]) -> {
+          let product = list.fold([n, ..values], 1, fn(p, v) { p * v })
+          accumulate_operation(rest, sum + product, [])
+        }
+        #(n, ["+"]) ->
+          accumulate_operation(rest, sum + int.sum([n, ..values]), [])
+        _ -> panic as "unexpected tuple"
+      }
+    }
+  }
+}

src/day06/solution.gleam

@@ -0,0 +1,17 @@
+import day06/solution
+import gleam/string
+
+const testinput = "123 328  51 64 
+ 45 64  387 23 
+  6 98  215 314
+*   +   *   +  "
+
+pub fn part1_test() {
+  let lines = string.split(testinput, "\n")
+  assert solution.solve_p1(lines) == Ok("4277556")
+}
+
+pub fn part2_test() {
+  let lines = string.split(testinput, "\n")
+  assert solution.solve_p2(lines) == Ok("3263827")
+}