Fix fontification of composite literals w/ type params.

Fix "foo.Bar" to be fontified as a type in "foo.Bar[int, string]{}".

Author: muirdm

go-mode.el

@@ -506,7 +506,7 @@ statements."
      ("\\(!\\)[^=]" 1 font-lock-negation-char-face)
 
      ;; Composite literal type
-     (,(concat go-type-name-regexp "{") 1 font-lock-type-face)
+     (go--match-composite-literal 1 font-lock-type-face)
 
      ;; Map value type
      (go--match-map-value 1 font-lock-type-face)
@@ -1758,6 +1758,27 @@ We are looking for the right-hand-side of the type alias"
                              (eq (char-after) ?\())))))
     found-match))
 
+(defconst go--match-composite-literal-re (concat go-type-name-regexp "[[{]"))
+
+(defun go--match-composite-literal (end)
+  "Search for composite literals."
+  (let (found-match)
+    (while (and
+            (not found-match)
+            ;; Match "foo{" or "foo[".
+            (re-search-forward go--match-composite-literal-re end t))
+
+      (setq found-match
+            (if (eq (char-before) ?\[)
+                ;; In "foo[" case, skip to closing "]".
+                (progn
+                  (while (go--search-next-comma end ?\]))
+                  ;; See if closing "]" is followed by "{".
+                  (eq (char-after (1+ (point))) ?{))
+              ;; The "foo{" case (definitely composite literal).
+              (eq (char-before) ?{))))
+
+    found-match))
 
 (defconst go--map-value-re
   (concat "\\_<map\\_>\\[\\(?:\\[[^]]*\\]\\)*[^]]*\\]" go-type-name-regexp))

test/go-font-lock-test.el

@@ -124,6 +124,7 @@ KcaseK string:
   (go--should-fontify "TfooT{")
   (go--should-fontify "[]TfooT{")
   (go--should-fontify "Tfoo.ZarT{")
+  (go--should-fontify "Tfoo.ZarT[TintT]{")
   (go--should-fontify "[]Tfoo.ZarT{")
 
   (go--should-fontify "TfooT{CbarC:baz, CquxC: 123}")