How do I turn-off smartparents, I still prefer paredit specially for lisp-interaction-mode, emacs-lisp, clojure, common-lisp?

[touxstone]

I confirm that...

• I searched the FAQ, issue tracker, discussions board, documentation, and wiki, and did not find an answer to my question.

• Any discussions with or conclusions derived from the use of LLMs will be omitted from my question.

What is your question?

Hi, everyone.
Does anyone know how I would go about accomplishing this:

• I want to make lisp-interaction-mode the major mode of the scratch buffer.
• turn-off smartparens, I still prefer paredit specially for the following modes: lisp-interaction-mode, emacs-lisp, clojure, common-lisp
  I tried the following snipet but runnig C-h v ->major-mode in the scratch buffer still shows smartparens in the list, and it interferes with paredit

;; ~/.config/doom/config.el

(use-package! paredit
  :hook ((emacs-lisp-mode
          lisp-mode
          common-lisp-mode
          clojure-mode
          scheme-mode
          lisp-interaction-mode)
         . paredit-mode))


;; to ensure the scratch buffer is lisp-interaction-mode & paredit
(after! smartparens
  (dolist (hook '(emacs-lisp-mode-hook
                  lisp-mode-hook
                  common-lisp-mode-hook
                  clojure-mode-hook
                  scheme-mode-hook
                  lisp-interaction-mode-hook))
    (add-hook hook (lambda () (smartparens-mode -1)))))


(add-hook 'after-change-major-mode-hook
          (lambda ()
            (when (string= (buffer-name) "*scratch*")
              (unless (derived-mode-p 'lisp-interaction-mode)
                (lisp-interaction-mode))
              (when (and (boundp 'smartparens-mode) smartparens-mode)
                (smartparens-mode -1))
              (paredit-mode 1))))
(when (boundp 'doom-scratch-buffer-created-hook)
  (add-hook 'doom-scratch-buffer-created-hook
            (lambda ()
              (lisp-interaction-mode)
              (smartparens-mode -1)
              (paredit-mode 1))))

System information

No response

[hlissner]

;;; add to $DOOMDIR/config.el

;; Enable paredit where you want it
(use-package! paredit
  :hook ((emacs-lisp-mode
          lisp-mode
          common-lisp-mode
          clojure-mode
          scheme-mode
          lisp-interaction-mode)
         . paredit-mode))

;; Change the major mode in...
;; ...Emacs' *scratch* buffer
(setq initial-major-mode 'lisp-interaction-mode)

;; ...Doom's scratch buffer
(setq doom-scratch-initial-major-mode 'lisp-interaction-mode)

;; Either disable smartparens where paredit is active:
(add-hook 'paredit-mode-hook #'turn-off-smartparens-mode)
;; OR disable smartparens globally:
(remove-hook 'doom-first-buffer-hook #'smartparens-global-mode)

Side notes:

• Where initial-major-mode is set in Doom
• Where smartparens-global-mode is enabled in Doom)
• The (when (boundp 'doom-scratch-buffer-created-hook) ...) check is unnecessary for add-hook. Hooks can be added to a hook variable before it is loaded without issue.
• All documentation for functions and variables can be looked up within Emacs using C-h f or C-h v, respectively, followed by the name of the function/variable.
• FYI: Smartparens is slated to be removed from Doom core in v3 (and replaced with electric). I'm already testing this in the feature/remove-smartparens branch.

Hope that helps!

[touxstone]

lisp-interaction-mode gets load in the scratch buffer, and paredit appears in the output list of C-h m but something interferes and it does not work

Debugger entered--Lisp error: (void-function eval-symbol)
   (eval-symbol 'paredit-mode)
   eval-expression((eval-symbol 'paredit-mode) nil nil 127)
   funcall-interactively(eval-expression (eval-symbol 'paredit-mode) nil nil 127)
   command-execute(eval-expression)

[hlissner]

It says you're doing M-x eval-expression RET (eval-symbol 'paredit-mode), but there is no eval-symbol function in Emacs. Just do M-x paredit-mode.

[touxstone]

Oooops. yes, it's true. I apologize for the confusion; I was referring to the M: RET eval (symbol-value 'paredit-mode) function. It's now working, your solution remove-hook 'doom-first-buffer-hook #'smartparens-global-mode has been key, thanks.