reset two snippets

Author: gewarren

snippets/visualbasic/VS_Snippets_Remoting/SchemaImporterExtensionExample/VB/SchemaImporterExtensionExample.vb

@@ -0,0 +1,40 @@
+Imports System.IO
+Imports System.Runtime.Serialization
+Imports System.Xml.Schema
+Imports System.Xml.Serialization
+Imports System.CodeDom
+Imports System.CodeDom.Compiler
+
+Public Class Test
+    Shared Sub Main() 
+        Console.WriteLine("started")
+    
+    End Sub
+End Class
+
+
+' Replace MyFakeAbstract with System.Xml.Serialization.Advanced.SchemaImporterExtension
+' when it becomes integrated into Main. This fake class is only to get the
+' implementation to compile.
+MustInherit Public Class MyFakeAbstract
+    Public Overridable Function ImportschemaType(ByVal name As String, ByVal ns As String, ByVal context As XmlSchemaObject, ByVal schemas As XmlSchemas, ByVal importer As XmlSchemaImporter, ByVal compileUnit As CodeCompileUnit, ByVal mainNamespace As CodeNamespace, ByVal options As CodeGenerationOptions, ByVal codeProvider As CodeDomProvider) As String 
+        Return Nothing
+    End Function 'ImportschemaType 
+End Class
+
+Public Class MyExtension
+    Inherits MyFakeAbstract
+    
+    '<snippet1>
+    Public Overrides Function ImportschemaType(ByVal name As String, ByVal ns As String, ByVal context As XmlSchemaObject, ByVal schemas As XmlSchemas, ByVal importer As XmlSchemaImporter, ByVal compileUnit As CodeCompileUnit, ByVal codeNamespace As CodeNamespace, ByVal options As CodeGenerationOptions, ByVal codeGenerator As CodeDomProvider) As String 
+        If name.Equals("Order") AndAlso ns.Equals("http://orders/") Then
+            compileUnit.ReferencedAssemblies.Add("Order.dll")
+            codeNamespace.Imports.Add(New CodeNamespaceImport("Microsoft.Samples"))           
+            Return "Order"
+        End If 
+        
+        Return Nothing
+    
+    End Function 'ImportschemaType 
+    '</snippet1>
+End Class

snippets/visualbasic/VS_Snippets_Remoting/TransactionScope/vb/ScopeWithSQL.vb

@@ -0,0 +1,100 @@
+Option Explicit On
+Option Strict On
+
+Imports System.Data
+Imports System.Data.SqlClient
+Imports System.Transactions
+
+Module Module1
+
+    Sub Main()
+        Dim connectionString1 As String = GetSQLConnectionString1()
+        Dim connectionString2 As String = GetSQLConnectionString2()
+        Dim string1 As String = "insert into Customers (CustomerID, CompanyName) values ('ZZZZZ', 'ZZZZZ')"
+        Dim string2 As String = "insert into Production.UnitMeasure (UnitMeasureCode, Name) values ('ZZZ', 'ZZZ')"
+        Dim r As Integer = 0
+
+        Try
+            r = CreateTransactionScope(connectionString1, connectionString2, string1, string2)
+        Catch ex As Exception
+            Console.WriteLine("")
+            Console.WriteLine("In calling code: {0}", ex.Message)
+        End Try
+        Console.WriteLine("return value in caller {0}", r)
+        Console.ReadLine()
+    End Sub
+
+    ' <Snippet1>
+    '  This function takes arguments for 2 connection strings and commands to create a transaction 
+    '  involving two SQL Servers. It returns a value > 0 if the transaction is committed, 0 if the 
+    '  transaction is rolled back. To test this code, you can connect to two different databases 
+    '  on the same server by altering the connection string, or to another 3rd party RDBMS  
+    '  by altering the code in the connection2 code block.
+    Public Function CreateTransactionScope( _
+      ByVal connectString1 As String, ByVal connectString2 As String, _
+      ByVal commandText1 As String, ByVal commandText2 As String) As Integer
+
+        ' Initialize the return value to zero and create a StringWriter to display results.
+        Dim returnValue As Integer = 0
+        Dim writer As System.IO.StringWriter = New System.IO.StringWriter
+
+        Try
+        ' Create the TransactionScope to execute the commands, guaranteeing
+        '  that both commands can commit or roll back as a single unit of work.
+            Using scope As New TransactionScope()
+                Using connection1 As New SqlConnection(connectString1)
+                    ' Opening the connection automatically enlists it in the 
+                    ' TransactionScope as a lightweight transaction.
+                    connection1.Open()
+
+                    ' Create the SqlCommand object and execute the first command.
+                    Dim command1 As SqlCommand = New SqlCommand(commandText1, connection1)
+                    returnValue = command1.ExecuteNonQuery()
+                    writer.WriteLine("Rows to be affected by command1: {0}", returnValue)
+
+                    ' If you get here, this means that command1 succeeded. By nesting
+                    ' the using block for connection2 inside that of connection1, you
+                    ' conserve server and network resources as connection2 is opened
+                    ' only when there is a chance that the transaction can commit.   
+                    Using connection2 As New SqlConnection(connectString2)
+                        ' The transaction is escalated to a full distributed
+                        ' transaction when connection2 is opened.
+                        connection2.Open()
+
+                        ' Execute the second command in the second database.
+                        returnValue = 0
+                        Dim command2 As SqlCommand = New SqlCommand(commandText2, connection2)
+                        returnValue = command2.ExecuteNonQuery()
+                        writer.WriteLine("Rows to be affected by command2: {0}", returnValue)
+                    End Using
+                End Using
+
+            ' The Complete method commits the transaction. If an exception has been thrown,
+            ' Complete is called and the transaction is rolled back.
+            scope.Complete()
+            End Using
+        Catch ex As TransactionAbortedException
+            writer.WriteLine("TransactionAbortedException Message: {0}", ex.Message)
+        End Try
+
+        ' Display messages.
+        Console.WriteLine(writer.ToString())
+
+        Return returnValue
+    End Function
+    ' </Snippet1>
+
+    Private Function GetSQLConnectionString1() As String
+        ' To avoid storing the connection string in your code,  
+        ' you can retrieve it from a configuration file.
+        Return "Integrated Security=true;database=Northwind;server=(local)"
+    End Function
+
+    Private Function GetSQLConnectionString2() As String
+        ' To avoid storing the connection string in your code,  
+        ' you can retrieve it from a configuration file.
+        Return "Integrated Security=true;database=AdventureWorks;server=(local)"
+    End Function
+
+End Module
+