Quotation tests

Author: Smaug123

tests/FSharp.Core.UnitTests/FSharp.Core/Microsoft.FSharp.Quotations/FSharpQuotations.fs

@@ -5,6 +5,8 @@
 namespace FSharp.Core.UnitTests.Quotations
 
 open System
+open FSharp.Core.UnitTests
+open FSharp.Core.UnitTests.Collections
 open FSharp.Core.UnitTests.LibraryTestFx
 open Xunit
 open FSharp.Quotations
@@ -139,4 +141,122 @@ type FSharpQuotationsTests() =
         let expr = Expr.NewTuple [ <@@ 1 @@>; <@@ "" @@> ]
         match expr with
         | NewStructTuple _ -> Assert.Fail()
-        | _ -> ()
+        | _ -> ()
+
+/// This fixture is here to test handling of EqualityConditionalOn and ComparisonConditionalOn.
+/// We don't generate witnesses for equality and comparison if they're conditional; the tests
+/// assert that code gen doesn't fail in those cases.
+[<RequireQualifiedAccess>]
+module TestConditionalConstraints =
+    open FSharp.Linq.RuntimeHelpers
+
+    let eval q = LeafExpressionConverter.EvaluateQuotation q
+
+    type DiscriminatedUnionWithGeneric<'a> =
+        | Case of 'a
+
+    [<NoComparison>]
+    type ThingWithNoComparison =
+        | NoComparison
+
+    [<NoEquality ; NoComparison>]
+    type ThingWithNoEquality =
+        | NoEquality
+
+        override this.ToString () =
+            "NoEquality"
+
+    let inline compare< ^T when ^T : comparison> (x : ^T) (y : ^T) : bool =
+        x < y
+
+    let inline equate< ^T when ^T : equality> (x : ^T) (y : ^T) : bool =
+        x = y
+
+    [<Fact>]
+    let ``SRTP quotations can consume conditionally constrained types `` () =
+        // Just normal calls, no quotation
+        Assert.False (equate (DiscriminatedUnionWithGeneric.Case 3) (DiscriminatedUnionWithGeneric.Case 4))
+        Assert.True (equate (DiscriminatedUnionWithGeneric.Case 3) (DiscriminatedUnionWithGeneric.Case 3))
+        Assert.True (compare (DiscriminatedUnionWithGeneric.Case 3) (DiscriminatedUnionWithGeneric.Case 4))
+
+        // Typed quotation, int
+        <@ equate (DiscriminatedUnionWithGeneric.Case 3) (DiscriminatedUnionWithGeneric.Case 4) @>
+        |> eval
+        |> unbox<bool>
+        |> Assert.False
+
+        <@ equate (DiscriminatedUnionWithGeneric.Case 3) (DiscriminatedUnionWithGeneric.Case 3) @>
+        |> eval
+        |> unbox<bool>
+        |> Assert.True
+
+        <@ compare (DiscriminatedUnionWithGeneric.Case 3) (DiscriminatedUnionWithGeneric.Case 4) @>
+        |> eval
+        |> unbox<bool>
+        |> Assert.True
+
+        // Untyped quotation, int
+        <@@ equate (DiscriminatedUnionWithGeneric.Case 3) (DiscriminatedUnionWithGeneric.Case 4) @@>
+        |> eval
+        |> unbox<bool>
+        |> Assert.False
+
+        <@@ equate (DiscriminatedUnionWithGeneric.Case 3) (DiscriminatedUnionWithGeneric.Case 3) @@>
+        |> eval
+        |> unbox<bool>
+        |> Assert.True
+
+        <@@ compare (DiscriminatedUnionWithGeneric.Case 3) (DiscriminatedUnionWithGeneric.Case 4) @@>
+        |> eval
+        |> unbox<bool>
+        |> Assert.True
+
+        // Typed and untyped quotation, ThingWithNoComparison
+        <@ equate ThingWithNoComparison.NoComparison ThingWithNoComparison.NoComparison @>
+        |> eval
+        |> unbox<bool>
+        |> Assert.True
+
+        <@@ equate ThingWithNoComparison.NoComparison ThingWithNoComparison.NoComparison @@>
+        |> eval
+        |> unbox<bool>
+        |> Assert.True
+
+        // Typed and untyped quotation, ThingWithNoEquality
+        <@ (fun x -> x.ToString ()) ThingWithNoEquality.NoEquality @>
+        |> eval
+        |> unbox<string>
+        |> fun s -> Assert.AreEqual (s, "NoEquality")
+
+        <@@ (fun x -> x.ToString ()) ThingWithNoEquality.NoEquality @@>
+        |> eval
+        |> unbox<string>
+        |> fun s -> Assert.AreEqual (s, "NoEquality")
+
+    // This test isn't quotation-related, but it *is* closely related to the quotation test: both are checking
+    // we can cope without witnesses.
+    [<Fact>]
+    let ``Reflective invocations of conditionally constrained types throw with a reasonable error`` () =
+        let compare = typeof<ThingWithNoComparison>.DeclaringType.GetMethod "compare"
+        let compare = compare.MakeGenericMethod([| typeof<ThingWithNoComparison> |])
+        let exc =
+            try
+                compare.Invoke (null, [|ThingWithNoComparison.NoComparison ; ThingWithNoComparison.NoComparison|])
+                |> ignore<obj>
+                None
+            with
+            | exc ->
+                Some exc
+
+        Assert.Contains ("does not implement the System.IComparable interface", exc.Value.InnerException.Message, StringComparison.Ordinal)
+
+    // This test isn't quotation-related, but it *is* closely related to the quotation test: both are checking
+    // we can cope without witnesses.
+    [<Fact>]
+    let ``We still use Object.ReferenceEquals for non-equatable methods when reflectively invoked`` () =
+        let equate = typeof<ThingWithNoComparison>.DeclaringType.GetMethod "equate"
+        let equate = equate.MakeGenericMethod([| typeof<ThingWithNoEquality> |])
+        let anotherOne = Activator.CreateInstance (typeof<ThingWithNoEquality>, nonPublic=true)
+        equate.Invoke (null, [| ThingWithNoEquality.NoEquality ; anotherOne |])
+        |> unbox<bool>
+        |> Assert.False