feat: redirect legacy URLs with parameters

- redirect /index.html to / with parameters q, action and map type parameter to where
- redirect /browse.html to /browse with parameters w3c, extensions and appmodules
- redirect /view.html to /view with parameters location, uri and function
- add tests for redirects

Author: line-o

src/main/xar-resources/controller.xq

@@ -13,6 +13,20 @@ declare variable $local:method := lower-case(request:get-method());
 declare variable $local:is-get := $local:method eq 'get';
 declare variable $local:user := login:set-user("org.exist.login", (), false());
 
+declare function local:map-type-to-where ($type as xs:string?) as xs:string {
+    (
+        map:get(
+            map {
+                "name": "everywhere",
+                "signature": "signature",
+                "desc": "description"
+            },
+            $type
+        ),
+        'everywhere'
+    )[1]
+};
+
 declare function local:render-view($view as xs:string) {
     <dispatch xmlns="http://exist.sourceforge.net/NS/exist">
         <forward url="templates/pages/{$view}.html"/>
@@ -25,10 +39,58 @@ declare function local:render-view($view as xs:string) {
     </dispatch>
 };
 
-if ($exist:path eq '') then (
+declare function local:render-parameters ($parameters as map(*)) {
+    map:for-each($parameters, function ($k, $v) {
+        if (empty($v)) then () else (
+            $k || '=' || escape-uri($v, true())
+        )
+    })
+    => string-join('&amp;')
+};
+
+(: redirects :)
+if ($local:is-get and $exist:path eq '') then (
     <dispatch xmlns="http://exist.sourceforge.net/NS/exist">
         <redirect url="{concat(request:get-uri(), '/')}"/>
     </dispatch>
+) else if ($local:is-get and $exist:path eq '/index.html') then (
+    let $url := substring-before(request:get-uri(), 'index.html')
+
+    let $parameters := map{
+        'q': request:get-parameter('q', ()),
+        'action': 'search',
+        'where': local:map-type-to-where(request:get-parameter('type', ()))
+    }
+
+    return
+        <dispatch xmlns="http://exist.sourceforge.net/NS/exist">
+            <redirect url="{$url}?{local:render-parameters($parameters)}" />
+        </dispatch>
+) else if ($local:is-get and $exist:path eq '/view.html') then (
+    let $url := substring-before(request:get-uri(), '.html')
+    let $parameters := map{
+        'location': request:get-parameter('location', ()),
+        'uri': request:get-parameter('uri', ()),
+        'function': request:get-parameter('function', ())
+    }
+
+    return
+        <dispatch xmlns="http://exist.sourceforge.net/NS/exist">
+            <redirect url="{$url}?{local:render-parameters($parameters)}" />
+        </dispatch>
+
+) else if ($local:is-get and $exist:path eq '/browse.html') then (
+    let $url := substring-before(request:get-uri(), '.html')
+    let $parameters := map{
+        'w3c': request:get-parameter('w3c', ()),
+        'extensions': request:get-parameter('extensions', ()),
+        'appmodules': request:get-parameter('appmodules', ())
+    }
+
+    return
+        <dispatch xmlns="http://exist.sourceforge.net/NS/exist">
+            <redirect url="{$url}?{local:render-parameters($parameters)}" />
+        </dispatch>
 ) else if ($local:is-get and $exist:path eq "/") then (
     local:render-view('index')
 ) else if ($local:is-get and $exist:path eq "/view") then (

src/main/xar-resources/modules/app.xqm

@@ -414,7 +414,7 @@ declare
     %templates:default("appmodules", "false")
 function app:showmodules(
     $node as node(), $model as map(*),
-    $w3c as xs:boolean, $extensions as xs:boolean, $appmodules as xs:boolean
+    $w3c as xs:boolean?, $extensions as xs:boolean?, $appmodules as xs:boolean?
 ) as element(tr)* {
     for $module in $app:data
     let $uri := $module/xqdoc:module/xqdoc:uri

src/test/cypress/integration/redirect_spec.cy.js

@@ -0,0 +1,17 @@
+/* global cy */
+/// <reference types="cypress" />
+
+context('Visiting a legacy URL', () => {
+    it('redirects to the new index route', () => {
+      cy.visit('index.html?action=search&type=name&q=tei')
+      cy.url().should('equal', 'http://localhost:8080/exist/apps/fundocs/?action=search&where=everywhere&q=tei')
+    })
+    it('redirects to the new view route', () => {
+      cy.visit('view.html?uri=http://exist-db.org/xquery/file&function=file:sync&arity=3&location=java:org.exist.xquery.modules.file.FileModule')
+      cy.url().should('equal', 'http://localhost:8080/exist/apps/fundocs/view?location=java%3Aorg.exist.xquery.modules.file.FileModule&uri=http%3A%2F%2Fexist-db.org%2Fxquery%2Ffile&function=file%3Async')
+    })
+    it('redirects to the new browse URL', () => {
+      cy.visit('browse.html?w3c=true&appmodules=true')
+      cy.url().should('equal', 'http://localhost:8080/exist/apps/fundocs/browse?w3c=true&appmodules=true')
+    })
+})