Adafruit SSD1306 Library not working with arduino-pico

[1PY1]

I have a problem compiling the example from Adafruit SSD1306 with the arduino-pico board
See attached code:

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 32 // OLED display height, in pixels

#define OLED_RESET     4 // Reset pin # (or -1 if sharing Arduino reset pin)
#define SCREEN_ADDRESS 0x3C ///< See datasheet for Address; 0x3D for 128x64, 0x3C for 128x32
#define PIN_WIRE_SDA        (6u)
#define PIN_WIRE_SCL        (7u)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define NUMFLAKES     10 // Number of snowflakes in the animation example

#define LOGO_HEIGHT   16
#define LOGO_WIDTH    16
static const unsigned char PROGMEM logo_bmp[] =
{ 0b00000000, 0b11000000,
  0b00000001, 0b11000000,
  0b00000001, 0b11000000,
  0b00000011, 0b11100000,
  0b11110011, 0b11100000,
  0b11111110, 0b11111000,
  0b01111110, 0b11111111,
  0b00110011, 0b10011111,
  0b00011111, 0b11111100,
  0b00001101, 0b01110000,
  0b00011011, 0b10100000,
  0b00111111, 0b11100000,
  0b00111111, 0b11110000,
  0b01111100, 0b11110000,
  0b01110000, 0b01110000,
  0b00000000, 0b00110000 };

void setup() {
  Serial.begin(9600);

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }

  // Show initial display buffer contents on the screen --
  // the library initializes this with an Adafruit splash screen.
  display.display();
  delay(2000); // Pause for 2 seconds

  // Clear the buffer
  display.clearDisplay();

  // Draw a single pixel in white
  display.drawPixel(10, 10, SSD1306_WHITE);

  // Show the display buffer on the screen. You MUST call display() after
  // drawing commands to make them visible on screen!
  display.display();
  delay(2000);
  // display.display() is NOT necessary after every single drawing command,
  // unless that's what you want...rather, you can batch up a bunch of
  // drawing operations and then update the screen all at once by calling
  // display.display(). These examples demonstrate both approaches...

  testdrawline();      // Draw many lines
  // Invert and restore display, pausing in-between
  display.invertDisplay(true);
  delay(1000);
  display.invertDisplay(false);
  delay(1000);

  testanimate(logo_bmp, LOGO_WIDTH, LOGO_HEIGHT); // Animate bitmaps
}

void loop() {
}

void testdrawline() {
  int16_t i;

  display.clearDisplay(); // Clear display buffer

  for(i=0; i<display.width(); i+=4) {
    display.drawLine(0, 0, i, display.height()-1, SSD1306_WHITE);
    display.display(); // Update screen with each newly-drawn line
    delay(1);
  }
  for(i=0; i<display.height(); i+=4) {
    display.drawLine(0, 0, display.width()-1, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  delay(250);

  display.clearDisplay();

  for(i=0; i<display.width(); i+=4) {
    display.drawLine(0, display.height()-1, i, 0, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  for(i=display.height()-1; i>=0; i-=4) {
    display.drawLine(0, display.height()-1, display.width()-1, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  delay(250);

  display.clearDisplay();

  for(i=display.width()-1; i>=0; i-=4) {
    display.drawLine(display.width()-1, display.height()-1, i, 0, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  for(i=display.height()-1; i>=0; i-=4) {
    display.drawLine(display.width()-1, display.height()-1, 0, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  delay(250);

  display.clearDisplay();

  for(i=0; i<display.height(); i+=4) {
    display.drawLine(display.width()-1, 0, 0, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  for(i=0; i<display.width(); i+=4) {
    display.drawLine(display.width()-1, 0, i, display.height()-1, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000); // Pause for 2 seconds
}

When I try to compile I get the following error:

C:\Users\Rick.000\Documents\Arduino\libraries\Adafruit_SSD1306\Adafruit_SSD1306.cpp:45:6: error: expected unqualified-id before 'const'

45 | (*(const unsigned char *)(addr)) ///< PROGMEM workaround for non-AVR

C:\Users\Rick.000\AppData\Local\Arduino15\packages\rp2040\hardware\rp2040\2.3.2\cores\rp2040/api/deprecated-avr-comp/avr/pgmspace.h:116:29: note: in expansion of macro 'pgm_read_byte'

116 | static inline unsigned char pgm_read_byte(const void *addr) {

C:\Users\Rick.000\Documents\Arduino\libraries\Adafruit_SSD1306\Adafruit_SSD1306.cpp:45:6: error: expected ')' before 'const'

45 | (*(const unsigned char *)(addr)) ///< PROGMEM workaround for non-AVR

C:\Users\Rick.000\AppData\Local\Arduino15\packages\rp2040\hardware\rp2040\2.3.2\cores\rp2040/api/deprecated-avr-comp/avr/pgmspace.h:116:29: note: in expansion of macro 'pgm_read_byte'

116 | static inline unsigned char pgm_read_byte(const void *addr) {

C:\Users\Rick.000\Documents\Arduino\libraries\Adafruit_SSD1306\Adafruit_SSD1306.cpp:45:6: error: expected ')' before 'const'

45 | (*(const unsigned char *)(addr)) ///< PROGMEM workaround for non-AVR

C:\Users\Rick.000\AppData\Local\Arduino15\packages\rp2040\hardware\rp2040\2.3.2\cores\rp2040/api/deprecated-avr-comp/avr/pgmspace.h:116:29: note: in expansion of macro 'pgm_read_byte'

116 | static inline unsigned char pgm_read_byte(const void *addr) {

exit status 1

Error compiling for board Raspberry Pi Pico.

Any help would be appreciated

[dhalbert]

The relevant code from the latest version of the library
is

#ifdef __AVR__
#include <avr/pgmspace.h>
#elif defined(ESP8266) || defined(ESP32) || defined(ARDUINO_ARCH_RP2040)
#include <pgmspace.h>
#else
#define pgm_read_byte(addr)                                                    \
  (*(const unsigned char *)(addr)) ///< PROGMEM workaround for non-AVR
#endif

Make sure your Adafruit SSD1306 library is up to date, at least 2.5.2, and preferably 2.5.6, the latest as of this writing. We (Adafruit) added the defined(ARDUINO_ARCH_RP2040) about 4 months ago to fix this problem:
https://forums.adafruit.com/viewtopic.php?f=57&t=189849
adafruit/Adafruit_SSD1306#239
adafruit/Adafruit_SSD1306#240

tagging @caternuson for reference

[1PY1]

Thank you very much, that was the answer. Everything works now.