firmware update to a WIZnet W5100S-EVB-Pico other Ethernet

[kendo55]

Has anyone updated the firmware to a WIZnet W5100S-EVB-Pico successfully other Ethernet, with the Arduino and Earle's core? (like OTA)
If so, please point me to the example/library or method that worked for you...
Prefered is the WebUpdate initialisized over a WebBrowser.
With the Pi Pico-W board, I implemented OTA like the following example.

#include <WiFi.h>
#include <WiFiClient.h>
#include <WebServer.h>
#include <LittleFS.h>

#define MDNS_ON   0
  
#if MDNS_ON
  #include <LEAmDNS.h>
  const char* host = "picow-webupdate";
#endif
#ifndef STASSID
#define STASSID "aaaa....."
#define STAPSK "bbbbbb...."
#endif


const char* ssid = STASSID;
const char* password = STAPSK;

WebServer webserver(80);
const char* serverIndex = "<form method='POST' action='/update' enctype='multipart/form-data'><input type='file' name='update'><input type='submit' value='Update'></form>";

void ini_ota_pico(void){
//-------------------------
    #if MDNS_ON
      MDNS.begin(host);
    #endif
    webserver.on("/", HTTP_GET, []() {
      webserver.sendHeader("Connection", "close");
      webserver.send(200, "text/html", serverIndex);
    });
    // Upload file
    // - first callback is called after the request has ended with all parsed arguments
    // - second callback handles file upload at that location
    webserver.on(
    "/update", HTTP_POST, []() {
      webserver.sendHeader("Connection", "close");
      webserver.send(200, "text/plain", (Update.hasError()) ? "FAIL" : "OK");
      rp2040.restart();
    },
    []() {
      HTTPUpload& upload = webserver.upload();
      if (upload.status == UPLOAD_FILE_START) {
        WiFiUDP::stopAll();
        Serial.printf("Update: %s\n", upload.filename.c_str());
        FSInfo64 i;
        LittleFS.begin();
        LittleFS.info64(i);
        uint32_t maxSketchSpace = i.totalBytes - i.usedBytes;
        if (!Update.begin(maxSketchSpace)) {  // start with max available size
          Update.printError(Serial);
        }
      } else if (upload.status == UPLOAD_FILE_WRITE) {
        if (Update.write(upload.buf, upload.currentSize) != upload.currentSize) {
          Update.printError(Serial);
        }
      } else if (upload.status == UPLOAD_FILE_END) {
        if (Update.end(true)) {  // true to set the size to the current progress
          Serial.printf("Update Success: %u\nRebooting...\n", upload.totalSize);
        } else {
          Update.printError(Serial);
        }
      }
    });
    webserver.begin();

    #if MDNS_ON
      MDNS.addService("http", "tcp", 80);
      Serial.printf("Ready! Open http://%s.local in your browser\n", host);
    #endif
    Serial.println("Neue Version2...");

}

void setup(void) {
//-------------------------
  Serial.begin(115200);
  while (!Serial) {}  // wait for serial port to connect. Needed for native USB
  Serial.println();
  Serial.println("Booting Sketch...");
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  if (WiFi.waitForConnectResult() == WL_CONNECTED) {
    Serial.print("local IP: "); Serial.println( WiFi.localIP());
    
    ini_ota_pico();
  } else {
    Serial.println("WiFi Failed");
  }

}

void loop(void) {
  webserver.handleClient();
  #if MDNS_ON
    MDNS.update();
  #endif
}

[JAndrassy]

you can use my ArduinoOTA library with the Arduino Ethernet library

[ZinnerC]

@kendo55 have you been successful. I tried the same and was not able to get it working. Do you might give me a hint?

[kendo55]

@ZinnerC
Sorry for the late reply!
I had to reactivate this project.
The ArduinoOTA library does not work!

I was going back to my first idea, using Earle's Update Class
what I use since a long time with the Picow and the Webserser class.

https://github.com/earlephilhower/arduino-pico/blob/0847d3dbb0ce2a3d33f3e864a0fab716a4861d4d/libraries/HTTPUpdate/src/HTTPUpdate.h

With ETH we have to use the EthernetWebServer Class from Khoi Hoang

https://github.com/khoih-prog/EthernetWebServer/tree/master

I based my tests on his Example: EthernetWebServer.ino

https://github.com/khoih-prog/EthernetWebServer/tree/master/examples/FS_EthernetWebServer

unfortunately the /edit page doesn't run for me.
Very very slow!

Bat that's not the point now.
Please use my modified example with the link:
http://192.168.1.178/
and the Update form will appears.

surely you still have to adjust the fixed IP:
search for "// muths" in the file: FS_EthernetWebServerHS2.ino

#if HS_OTA_PICO
#include <Updater.h>
#define WIZNET_Pico   1


const char* serverIndex = "<form method='POST' action='/update' enctype='multipart/form-data'><input type='file' name='update'><input type='submit' value='Update'></form>";
  // --> könnte noch in FS abgeschoben werden


void ini_ota_pico(void){
//-------------------------

    server.on("/", HTTP_GET, []() {
      server.sendHeader("Connection", "close");
      server.send(200, "text/html", serverIndex);
    });
    // Upload file
    // - first callback is called after the request has ended with all parsed arguments
    // - second callback handles file upload at that location
    server.on(
    "/update", HTTP_POST, []() {
      server.sendHeader("Connection", "close");
      server.send(200, "text/plain", (Update.hasError()) ? "FAIL" : "OK");
      rp2040.restart();
    },
    []() {
      #if WIZNET_Pico
        ethernetHTTPUpload& upload = server.upload();
      #else
        HTTPUpload& upload = server.upload();
      #endif
      if (upload.status == UPLOAD_FILE_START) {
        #if ! WIZNET_Pico
          WiFiUDP::stopAll();
        #endif
        Serial.printf("Update: %s\n", upload.filename.c_str());
        FSInfo64 i;
        LittleFS.begin();
        LittleFS.info64(i);
        uint32_t maxSketchSpace = i.totalBytes - i.usedBytes;
        Serial.printf(" maxSketchSpace = %u\n",  maxSketchSpace);
        if (!Update.begin(maxSketchSpace)) {  // start with max available size
          Update.printError(Serial);
        }
      } else if (upload.status == UPLOAD_FILE_WRITE) {
        if (Update.write(upload.buf, upload.currentSize) != upload.currentSize) {
          Update.printError(Serial);
        }
      } else if (upload.status == UPLOAD_FILE_END) {
        if (Update.end(true)) {  // true to set the size to the current progress
          Serial.printf("Update Success: %u\nRebooting...\n", upload.totalSize);
        } else {
          Update.printError(Serial);
        }
      }
    });
    
    // wird in setup bereits gestartet
    //  server.begin();

    Serial.print("WebServer ready! http://");
    Serial.print(Ethernet.localIP());  
}

FS_EthernetWebServerHS2.zip

[ZinnerC]

@kendo55 Thank you very much.

I have your modified example running up to some point.
Basically it is looping in void loop.
How do I get it now to accept new firmware over Ethernet?

When I go to ip/edit or ip/update the server gives me the response "FileNotFound"

[ZinnerC]

The "FileNotFound" issue has been solved by uploading "data" with https://arduino-pico.readthedocs.io/en/latest/fs.html.
The uploading of firmware remains still a question.

/edit keeps loading for ever

[kendo55]

in my example I defined

void ini_ota_pico(void){
//-------------------------
server.on("/", HTTP_GET, {
server.sendHeader("Connection", "close");
server.send(200, "text/html", serverIndex);
});

therefore you have to call the main page of the server wuth ip/
It was an experimental test.

FS_EthernetWebServerHS2.zip

YES its the better way you call the update with the ip/update as usually.
For that you have to change this statement in the function void ini_ota_pico()

server.on("/update", HTTP_GET, []() {
  server.sendHeader("Connection", "close");
  server.send(200, "text/html", serverIndex);

[ZinnerC]

Thank you for your response. I will test this when I have again access to the hardware.

[ZinnerC]

I tried both of these uploaders but they tell my that either file system does not work.

LittleFS Not Supported on rp2040 or SPIFFS not supported on rp2040

https://github.com/earlephilhower/arduino-esp8266littlefs-plugin
https://github.com/esp8266/arduino-esp8266fs-plugin/

@kendo55 have you ever been able to use your sketch for OTA?
If YES, how? I somehow don't manage. Might oversee something simple.

[earlephilhower]

LittleFS is the built-in FS for the core so it most definitely is supported. You need to install the right uploader https://github.com/earlephilhower/arduino-pico-littlefs-plugin and use the 1.8 IDE (2.x doesn't support plugins).

[earlephilhower]

FWIW, see #1703 (comment) which, with latest git head lets the W5100S run everything the WiFi can, including OTA updater/etc. w/o add'l libraries.

[kendo55]

Thanks!