chore: libcluster config

Adds libcluster configs to scale edgehog horizontally.

This allows edgehog to manage the workload among different replicas for
- campaign execution
- notifications
- reconciliation tasks

New environment vairables have been introduced, to allow different edgehog nodes
to see eachother based on the deployment strategy.

- `EDGEHOG_CLUSTERING_STRATEGY`: one of `none`, `docker-compose` or
  `kubernetes`. This chooses the strategy edgehog will use to lookup other nodes
  in the cluster.

- `EDGEHOG_CLUSTERING_KUBERNETES_SELECTOR`: The endpoint label to get other
  edgehog instances. This defaults to `app=edgehog`.

- `EDGEHOG_CLUSTERING_KUBERNETES_NAMESPACE` the kubernetes namespace to find
  other edgehog instances. This defaults to `edgehog`.

Signed-off-by: Luca Zaninotto <luca.zaninotto@secomind.com>

Author: lusergit

REUSE.toml

@@ -86,3 +86,9 @@ path = ".github/CODEOWNERS"
 precedence = "aggregate"
 SPDX-FileCopyrightText = "2026 Seco Mind Srl"
 SPDX-License-Identifier = "Apache-2.0"
+
+[[annotations]]
+path = "backend/rel/env.sh.eex"
+precedence = "aggregate"
+SPDX-FileCopyrightText = "2026 Seco Mind Srl"
+SPDX-License-Identifier = "Apache-2.0"

backend/lib/edgehog/application.ex

@@ -45,11 +45,15 @@ defmodule Edgehog.Application do
       Router.Helpers.astarte_trigger_url(Endpoint, :process_event, slug)
     end
 
+    clustering_opts = [Config.clustering_topologies!(), [name: Edgehog.Cluster.Supervisor]]
+
     children = [
       # Prometheus metrics
       Edgehog.PromEx,
       # Start the Ecto repository
       Edgehog.Repo,
+      # Clustering supervisor
+      {Cluster.Supervisor, clustering_opts},
       # Start the Telemetry supervisor
       EdgehogWeb.Telemetry,
       # Start the PubSub system

backend/lib/edgehog/config.ex

@@ -24,6 +24,7 @@ defmodule Edgehog.Config do
   """
   use Skogsra
 
+  alias Edgehog.Config.ClusteringStrategy
   alias Edgehog.Config.GeocodingProviders
   alias Edgehog.Config.GeolocationProviders
   alias Edgehog.Config.JWTPublicKeyPEMType
@@ -96,6 +97,26 @@ defmodule Edgehog.Config do
     type: GeocodingProviders,
     default: [GoogleGeocoding]
 
+  @envdoc "The Erlang cluster strategy to use. One of `none`, `kubernetes`, `docker-compose`. Defaults to `none`."
+  app_env :clustering_strategy, :edgehog, :clustering_strategy,
+    os_env: "EDGEHOG_CLUSTERING_STRATEGY",
+    type: ClusteringStrategy,
+    default: :none
+
+  @envdoc "The endpoint label to query to get other edgehog instances. Defaults to `app=edgehog`."
+  app_env :edgehog_clustering_kubernetes_selector,
+          :edgehog,
+          :edgehog_clustering_kubernetes_selector,
+          os_env: "EDGEHOG_CLUSTERING_KUBERNETES_SELECTOR",
+          type: :binary,
+          default: "app=edgehog"
+
+  @envdoc "The Kubernetes namespace to use when `kubernetes` Erlang clustering strategy is used. Defaults to `edgehog`."
+  app_env :clustering_kubernetes_namespace, :edgehog, :clustering_kubernetes_namespace,
+    os_env: "EDGEHOG_CLUSTERING_KUBERNETES_NAMESPACE",
+    type: :binary,
+    default: "edgehog"
+
   @doc """
   Returns true if edgehog should use an ssl connection with the database.
   """
@@ -190,4 +211,40 @@ defmodule Edgehog.Config do
     admin_jwk!()
     :ok
   end
+
+  @doc """
+  The clustering topology to use. The topology sets up node discovery.
+  """
+  def clustering_topologies! do
+    case clustering_strategy!() do
+      :none ->
+        []
+
+      :kubernetes ->
+        [
+          edgehog_k8s: [
+            strategy: Cluster.Strategy.Kubernetes,
+            config: [
+              mode: :ip,
+              kubernetes_node_basename: "edgehog",
+              kubernetes_selector: edgehog_clustering_kubernetes_selector!(),
+              kubernetes_namespace: clustering_kubernetes_namespace!(),
+              polling_interval: 10_000
+            ]
+          ]
+        ]
+
+      :docker_compose ->
+        [
+          edgehog: [
+            strategy: Cluster.Strategy.DNSPoll,
+            config: [
+              polling_interval: 5_000,
+              query: "edgehog-backend",
+              node_basename: "edgehog"
+            ]
+          ]
+        ]
+    end
+  end
 end

backend/lib/edgehog/config/clustering_strategy.ex

@@ -0,0 +1,46 @@
+#
+# This file is part of Edgehog.
+#
+# Copyright 2026 SECO Mind Srl
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#    http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+# SPDX-License-Identifier: Apache-2.0
+#
+
+defmodule Edgehog.Config.ClusteringStrategy do
+  @moduledoc """
+  The clustering strategy that the node should use to discover other nodes.
+  """
+
+  use Skogsra.Type
+
+  @strategies [:none, :kubernetes, :docker_compose]
+  @allowed_strategies ~w(none kubernetes docker-compose)
+  @strategy_map @allowed_strategies |> Enum.zip(@strategies) |> Map.new()
+
+  @impl Skogsra.Type
+  def cast(value) when is_binary(value) do
+    Map.fetch(@strategy_map, value)
+  end
+
+  @impl Skogsra.Type
+  def cast(value) when value in @strategies do
+    {:ok, value}
+  end
+
+  @impl Skogsra.Type
+  def cast(_) do
+    :error
+  end
+end

backend/rel/env.sh.eex

@@ -0,0 +1,11 @@
+#!/bin/sh
+
+export RELEASE_DISTRIBUTION=name
+
+if [ -z "$MY_POD_IP" ]
+then
+    HOSTNAME=`hostname -i`
+    export RELEASE_NODE="<%= @release.name %>@$HOSTNAME"
+else
+    export RELEASE_NODE="<%= @release.name %>@$MY_POD_IP"
+fi