Support defaultModel in custom providers

Author: ericdallo

CHANGELOG.md

@@ -2,6 +2,8 @@
 
 ## Unreleased
 
+- Support defaultModel in custom providers.
+
 ## 0.6.0
 
 - Add usage tokens + cost to chat messages.

docs/configuration.md

@@ -114,7 +114,8 @@ It's possible to configure ECA to be aware of custom LLM providers if they follo
        "api": "openai",
        "urlEnv": "MY_COMPANY_API_URL", // or "url": "https://litellm.my-company.com",
        "keyEnv": "MY_COMPANY_API_KEY", // or "key": "123",
-       "models": ["gpt-4.1", "deepseek-r1"]
+       "models": ["gpt-4.1", "deepseek-r1"],
+       "defaultModel": "deepseek-r1"
     }
   }
 }
@@ -141,6 +142,7 @@ interface Config {
     customProviders: {[key: string]: {
         api: 'openai' | 'anthropic';
         models: string[];
+        defaultModel?: string;
         url?: string;
         urlEnv?: string;
         key?: string;

src/eca/handlers.clj

@@ -14,12 +14,14 @@
   (when-let [custom-providers (seq (:customProviders config))]
     (swap! db* update :models merge
            (reduce
-            (fn [models [provider {provider-models :models}]]
+            (fn [models [provider {provider-models :models default-model :defaultModel}]]
               (reduce
                (fn [m model]
                  (assoc m
                         (str (name provider) "/" model)
-                        {:tools true}))
+                        {:tools true
+                         :custom-provider? true
+                         :default-model? (= model default-model)}))
                models
                provider-models))
             {}

src/eca/llm_api.clj

@@ -24,7 +24,7 @@
       (config/get-env "ANTHROPIC_API_KEY")))
 
 (defn ^:private anthropic-api-url []
-  (or (System/getenv "ANTHROPIC_API_URL")
+  (or (config/get-env "ANTHROPIC_API_URL")
       llm-providers.anthropic/base-url))
 
 (defn ^:private openai-api-key [config]
@@ -37,17 +37,26 @@
 
 (defn default-model
   "Returns the default LLM model checking this waterfall:
+  - Any custom provider with defaultModel set
   - Anthropic api key set
   - Openai api key set
   - Ollama first model if running
   - Anthropic default model."
   [db config]
-  (let [[decision model] (or (first (filter #(string/starts-with? % config/ollama-model-prefix) (vals (:models db))))
-                             (when (anthropic-api-key config)
-                               [:api-key-found "claude-sonnet-4-0"])
-                             (when (openai-api-key config)
-                               [:api-key-found "o4-mini"])
-                             [:default "claude-sonnet-4-0"])]
+  (let [[decision model]
+        (or (when-let [custom-provider-default-model (first (keep (fn [[model config]]
+                                                                    (when (and (:custom-provider? config)
+                                                                               (:default-model? config))
+                                                                      model))
+                                                                  (:models db)))]
+              [:custom-provider-default-model custom-provider-default-model])
+            (when-let [ollama-model (first (filter #(string/starts-with? % config/ollama-model-prefix) (keys (:models db))))]
+              [:ollama-running ollama-model])
+            (when (anthropic-api-key config)
+              [:api-key-found "claude-sonnet-4-0"])
+            (when (openai-api-key config)
+              [:api-key-found "o4-mini"])
+            [:default "claude-sonnet-4-0"])]
     (logger/info logger-tag (format "Default LLM model '%s' decision '%s'" model decision))
     model))
 

test/eca/llm_api_test.clj

@@ -0,0 +1,53 @@
+(ns eca.llm-api-test
+  (:require
+   [clojure.test :refer [deftest is testing]]
+   [eca.config :as config]
+   [eca.llm-api :as llm-api]
+   [eca.test-helper :as h]))
+
+(h/reset-components-before-test)
+
+(deftest default-model-test
+  (testing "Custom provider default-model? present"
+    (with-redefs [config/get-env (constantly nil)]
+      (let [db {:models {"my-model" {:custom-provider? true :default-model? true}}}
+            config {}]
+        (is (= "my-model" (llm-api/default-model db config))))))
+
+  (testing "Ollama running model present"
+    (with-redefs [config/get-env (constantly nil)]
+      (let [db {:models {"ollama/foo" {:tools true}
+                         "gpt-4.1" {:tools true}
+                         "other-model" {:tools true}}}
+            config {}]
+        (is (= "ollama/foo" (llm-api/default-model db config))))))
+
+  (testing "Anthropic API key present in config"
+    (with-redefs [config/get-env (constantly nil)]
+      (let [db {:models {}}
+            config {:anthropicApiKey "something"}]
+        (is (= "claude-sonnet-4-0" (llm-api/default-model db config))))))
+
+  (testing "Anthropic API key present in ENV"
+    (with-redefs [config/get-env (fn [k] (when (= k "ANTHROPIC_API_KEY") "env-anthropic"))]
+      (let [db {:models {}}
+            config {}]
+        (is (= "claude-sonnet-4-0" (llm-api/default-model db config))))))
+
+  (testing "OpenAI API key present in config"
+    (with-redefs [config/get-env (constantly nil)]
+      (let [db {:models {}}
+            config {:openaiapikey "yes!"}]
+        (is (= "o4-mini" (llm-api/default-model db config))))))
+
+  (testing "OpenAI API key present in ENV"
+    (with-redefs [config/get-env (fn [k] (when (= k "OPENAI_API_KEY") "env-openai"))]
+      (let [db {:models {}}
+            config {}]
+        (is (= "o4-mini" (llm-api/default-model db config))))))
+
+  (testing "Fallback default (no keys anywhere)"
+    (with-redefs [config/get-env (constantly nil)]
+      (let [db {:models {}}
+            config {}]
+        (is (= "claude-sonnet-4-0" (llm-api/default-model db config)))))))