Title: refactor: extract cache logic to eca.cache namespace

Moves cache directory resolution and workspace hashing from `eca.db` to a new `eca.cache` namespace.
Centralizes file path management and allows other components (hooks) to acess cache paths.
Avoids circular dependencies on the database namespace.

Author: zikajk

src/eca/cache.clj

@@ -0,0 +1,37 @@
+(ns eca.cache
+  "Cache directory and file management utilities."
+  (:require
+   [babashka.fs :as fs]
+   [clojure.java.io :as io]
+   [clojure.string :as string]))
+
+(set! *warn-on-reflection* true)
+
+(defn global-dir
+  "Returns the File object for ECA's global cache directory."
+  []
+  (let [cache-home (or (System/getenv "XDG_CACHE_HOME")
+                       (io/file (System/getProperty "user.home") ".cache"))]
+    (io/file cache-home "eca")))
+
+(defn workspaces-hash
+  "Returns an 8-char base64 (URL-safe, no padding) hash key for the given workspace set."
+  [workspaces uri->filename-fn]
+  (let [paths (->> workspaces
+                   (map #(str (fs/absolutize (fs/file (uri->filename-fn (:uri %))))))
+                   (distinct)
+                   (sort))
+        joined (string/join ":" paths)
+        md (java.security.MessageDigest/getInstance "SHA-256")
+        digest (.digest (doto md (.update (.getBytes joined "UTF-8"))))
+        encoder (-> (java.util.Base64/getUrlEncoder)
+                    (.withoutPadding))
+        key (.encodeToString encoder digest)]
+    (subs key 0 (min 8 (count key)))))
+
+(defn workspace-cache-file
+  "Returns a File object for a workspace-specific cache file."
+  [workspaces filename uri->filename-fn]
+  (io/file (global-dir)
+           (workspaces-hash workspaces uri->filename-fn)
+           filename))

src/eca/db.clj

@@ -2,9 +2,8 @@
   (:require
    [babashka.fs :as fs]
    [clojure.java.io :as io]
-   [clojure.string :as string]
    [cognitect.transit :as transit]
-   [eca.config :as config :refer [get-env get-property]]
+   [eca.cache :as cache]
    [eca.logger :as logger]
    [eca.metrics :as metrics]
    [eca.shared :as shared])
@@ -123,32 +122,11 @@
         (proxy-super flush)
         (proxy-super close)))))
 
-(defn ^:private global-cache-dir []
-  (let [cache-home (or (get-env "XDG_CACHE_HOME")
-                       (io/file (get-property "user.home") ".cache"))]
-    (io/file cache-home "eca")))
-
-(defn ^:private workspaces-hash
-  "Return an 8-char base64 (URL-safe, no padding) key for the given
-   workspace set."
-  [workspaces]
-  (let [paths (->> workspaces
-                   (map #(str (fs/absolutize (fs/file (shared/uri->filename (:uri %))))))
-                   (distinct)
-                   (sort))
-        joined (string/join ":" paths)
-        md (java.security.MessageDigest/getInstance "SHA-256")
-        digest (.digest (doto md (.update (.getBytes joined "UTF-8"))))
-        encoder (-> (java.util.Base64/getUrlEncoder)
-                    (.withoutPadding))
-        key (.encodeToString encoder digest)]
-    (subs key 0 (min 8 (count key)))))
+(defn ^:private transit-global-db-file []
+  (io/file (cache/global-dir) "db.transit.json"))
 
 (defn ^:private transit-global-by-workspaces-db-file [workspaces]
-  (io/file (global-cache-dir) (workspaces-hash workspaces)  "db.transit.json"))
-
-(defn ^:private transit-global-db-file []
-  (io/file (global-cache-dir) "db.transit.json"))
+  (cache/workspace-cache-file workspaces "db.transit.json" shared/uri->filename))
 
 (defn ^:private read-cache [cache-file metrics]
   (try