Improve eca_shell_command to handle better error outputs.

Author: ericdallo

CHANGELOG.md

@@ -2,6 +2,8 @@
 
 ## Unreleased
 
+- Improve `eca_shell_command` to handle better error outputs.
+
 ## 0.21.1
 
 - Default to gpt-5 instead of o4-mini when openai-api-key found.

src/eca/diff.clj

@@ -23,26 +23,35 @@
 
 (defn diff
   ([original revised file]
-   (let [patch (DiffUtils/diff (lines original) (lines revised))
+   (let [original-lines (lines original)
+         revised-lines (lines revised)
+         patch (DiffUtils/diff original-lines revised-lines)
          deltas (.getDeltas patch)
-         added (->> deltas
-                    (filter #(instance? InsertDelta %))
-                    (mapcat (fn [^InsertDelta delta]
-                              (.getLines (.getRevised delta))))
-                    count)
-         changed (->> deltas
-                      (filter #(instance? ChangeDelta %))
-                      (mapcat (fn [^ChangeDelta delta]
+         new-file? (= "" original)
+         added (if new-file?
+                 (count revised-lines)
+                 (->> deltas
+                      (filter #(instance? InsertDelta %))
+                      (mapcat (fn [^InsertDelta delta]
                                 (.getLines (.getRevised delta))))
-                      count)
-         removed (->> deltas
-                      (filter #(instance? DeleteDelta %))
-                      (mapcat (fn [^DeleteDelta delta]
-                                (.getLines (.getOriginal delta))))
-                      count)]
+                      count))
+         changed (if new-file?
+                   0
+                   (->> deltas
+                        (filter #(instance? ChangeDelta %))
+                        (mapcat (fn [^ChangeDelta delta]
+                                  (.getLines (.getRevised delta))))
+                        count))
+         removed (if new-file?
+                   0
+                   (->> deltas
+                        (filter #(instance? DeleteDelta %))
+                        (mapcat (fn [^DeleteDelta delta]
+                                  (.getLines (.getOriginal delta))))
+                        count))]
      {:added (+ added changed)
       :removed (+ removed changed)
       :diff
-      (->> (DiffUtils/generateUnifiedDiff file file (lines original) patch 3)
+      (->> (DiffUtils/generateUnifiedDiff file file original-lines patch 3)
            (drop 2) ;; removes file header
            unlines)})))

src/eca/features/tools/shell.clj

@@ -27,10 +27,12 @@
                                    :uri
                                    shared/uri->filename)
                            (config/get-property "user.home"))
-              command-and-opts (concat ["bash -c"] command-args [:dir work-dir])
-              _ (logger/debug logger-tag "Running command:" command-and-opts)
+              _ (logger/debug logger-tag "Running command:" command-args)
               result (try
-                       (p/shell {:dir work-dir :out :string :err :string} "bash -c" command-args)
+                       (p/shell {:dir work-dir
+                                 :out :string
+                                 :err :string
+                                 :continue true} "bash -c" command-args)
                        (catch Exception e
                          {:exit 1 :err (.getMessage e)}))
               err (some-> (:err result) string/trim)

test/eca/diff_test.clj

@@ -0,0 +1,48 @@
+(ns eca.diff-test
+  (:require
+   [clojure.string :as string]
+   [clojure.test :refer [deftest is testing]]
+   [eca.diff :as diff]))
+
+(defn- split-diff-lines [s]
+  (when s (string/split-lines s)))
+
+(deftest diff-test
+  (testing "adding new lines"
+    (let [original (string/join "\n" ["a" "b"])
+          revised  (string/join "\n" ["a" "b" "c" "d"])
+          {:keys [added removed diff]} (diff/diff original revised "file.txt")
+          lines (split-diff-lines diff)]
+      (is (= 2 added) "two lines added")
+      (is (= 0 removed) "no lines removed")
+      (is (some #{"+c"} lines) "diff should include +c line")
+      (is (some #{"+d"} lines) "diff should include +d line")))
+
+  (testing "changing an existing line counts as one added and one removed"
+    (let [original (string/join "\n" ["a" "b" "c"])
+          revised  (string/join "\n" ["a" "B" "c"])
+          {:keys [added removed diff]} (diff/diff original revised "file.txt")
+          lines (split-diff-lines diff)]
+      (is (= 1 added) "one line added due to change")
+      (is (= 1 removed) "one line removed due to change")
+      (is (some #{"-b"} lines) "diff should include -b line")
+      (is (some #{"+B"} lines) "diff should include +B line")))
+
+  (testing "removing lines"
+    (let [original (string/join "\n" ["a" "b" "c"])
+          revised  (string/join "\n" ["a"])
+          {:keys [added removed diff]} (diff/diff original revised "file.txt")
+          lines (split-diff-lines diff)]
+      (is (= 0 added) "no lines added")
+      (is (= 2 removed) "two lines removed")
+      (is (some #{"-b"} lines) "diff should include -b line")
+      (is (some #{"-c"} lines) "diff should include -c line")))
+
+  (testing "new file"
+    (let [revised  (string/join "\n" ["a" "b" "c" "d"])
+          {:keys [added removed diff]} (diff/diff "" revised "file.txt")
+          lines (split-diff-lines diff)]
+      (is (= 4 added) "two lines added")
+      (is (= 0 removed) "no lines removed")
+      (is (some #{"+c"} lines) "diff should include +c line")
+      (is (some #{"+d"} lines) "diff should include +d line"))))