Add checksum to manifest files

Closes elixir-lang#14866.

Author: josevalim

lib/mix/lib/mix/compilers/elixir.ex

@@ -311,7 +311,8 @@ defmodule Mix.Compilers.Elixir do
   """
   def read_manifest(manifest) do
     try do
-      manifest |> File.read!() |> :erlang.binary_to_term()
+      {:ok, contents} = Mix.Task.Compiler.read_checksumed_file(manifest)
+      :erlang.binary_to_term(contents)
     rescue
       _ -> {[], []}
     else
@@ -888,7 +889,8 @@ defmodule Mix.Compilers.Elixir do
   # Similar to read_manifest, but for internal consumption and with data migration support.
   defp parse_manifest(manifest, compile_path) do
     try do
-      manifest |> File.read!() |> :erlang.binary_to_term()
+      {:ok, contents} = Mix.Task.Compiler.read_checksumed_file(manifest)
+      :erlang.binary_to_term(contents)
     rescue
       _ ->
         @default_manifest
@@ -958,7 +960,7 @@ defmodule Mix.Compilers.Elixir do
        project_mtime, config_mtime, protocols_and_impls}
 
     manifest_data = :erlang.term_to_binary(term, [:compressed])
-    File.write!(manifest, manifest_data)
+    :ok = Mix.Task.Compiler.write_checksumed_file(manifest, manifest_data)
     File.touch!(manifest, timestamp)
     delete_checkpoints(manifest)
 

lib/mix/lib/mix/task.compiler.ex

@@ -370,4 +370,51 @@ defmodule Mix.Task.Compiler do
     Mix.Task.reenable("compile.all")
     Enum.each(compilers, &Mix.Task.reenable("compile.#{&1}"))
   end
+
+  @checksum_version 1
+
+  @doc """
+  Reads a checksumed file.
+
+  This function is useful to read files with checksums
+  and validate they won't get corrupted with time.
+  """
+  def read_checksumed_file(path) do
+    case File.read(path) do
+      {:ok, <<@checksum_version, size::64, checksum::binary-size(size), contents::binary>>} ->
+        if checksum(contents) == checksum do
+          {:ok, contents}
+        else
+          {:error, :echecksum}
+        end
+
+      {:error, reason} ->
+        {:error, reason}
+    end
+  end
+
+  @doc """
+  Writes a checksumed file.
+
+  This function is useful to write compilation manifests
+  and validate they won't get corrupted with time.
+  """
+  def write_checksumed_file(path, contents) do
+    checksum = checksum(contents)
+
+    File.write(
+      path,
+      <<@checksum_version, byte_size(checksum)::64, checksum::binary, contents::binary>>
+    )
+  end
+
+  defp checksum(contents) do
+    case :erlang.system_info(:wordsize) do
+      8 -> :crypto.hash(:blake2b, contents)
+      _ -> :crypto.hash(:blake2s, contents)
+    end
+  rescue
+    # Blake may not be available on all OpenSSL distribution
+    _ -> :erlang.md5(contents)
+  end
 end

lib/mix/test/mix/tasks/compile.elixir_test.exs

@@ -653,11 +653,13 @@ defmodule Mix.Tasks.Compile.ElixirTest do
 
       manifest = "_build/dev/lib/sample/.mix/compile.elixir"
 
-      File.read!(manifest)
+      {:ok, contents} = Mix.Task.Compiler.read_checksumed_file(manifest)
+
+      contents
       |> :erlang.binary_to_term()
       |> put_elem(0, 9)
       |> :erlang.term_to_binary()
-      |> then(&File.write!(manifest, &1))
+      |> then(&Mix.Task.Compiler.write_checksumed_file(manifest, &1))
 
       Mix.Task.clear()
       assert Mix.Task.run("compile", ["--verbose"]) == {:ok, []}