Fix remaining test errors after the update, and introduce test cases for complex anchor scenarios.

cotti · cotti · commit 9322d4ac1e8b · 2025-05-23T09:10:26.000-03:00
diff --git a/src/Elastic.Markdown/Links/CrossLinks/CrossLinkResolver.cs b/src/Elastic.Markdown/Links/CrossLinks/CrossLinkResolver.cs
@@ -52,7 +52,7 @@ public static bool TryResolve(
 
 		if (!fetchedCrossLinks.LinkReferences.TryGetValue(crossLinkUri.Scheme, out var sourceLinkReference))
 		{
-			errorEmitter($"'{crossLinkUri.Scheme}' was not found in the cross link index.");
+			errorEmitter($"'{crossLinkUri.Scheme}' was not found in the cross link index");
 			return false;
 		}
 
diff --git a/tests/authoring/Framework/CrossLinkResolverAssertions.fs b/tests/authoring/Framework/CrossLinkResolverAssertions.fs
@@ -0,0 +1,123 @@
+// Licensed to Elasticsearch B.V under one or more agreements.
+// Elasticsearch B.V licenses this file to you under the Apache 2.0 License.
+// See the LICENSE file in the project root for more information
+
+namespace authoring
+
+open System
+open System.Collections.Generic
+open System.Collections.Frozen
+open System.IO.Abstractions.TestingHelpers
+open Elastic.Documentation.Diagnostics
+open Elastic.Documentation.Links
+open Elastic.Markdown.Links.CrossLinks
+open Elastic.Documentation
+open Swensen.Unquote
+open Elastic.Documentation.Configuration.Builder
+open authoring
+
+module CrossLinkResolverAssertions =
+
+    let private parseRedirectsYaml (redirectsYamlContent: string) (collector: IDiagnosticsCollector) =
+        let mockFileSystem = MockFileSystem()
+        let fullYaml = sprintf "redirects:\n%s" (redirectsYamlContent.Replace("\r\n", "\n").Replace("\n", "\n  "))
+        let mockRedirectsFilePath = "mock_redirects.yml"
+        mockFileSystem.AddFile(mockRedirectsFilePath, MockFileData(fullYaml))
+        let mockRedirectsFile = mockFileSystem.FileInfo.New(mockRedirectsFilePath)
+
+        let docContext =
+            { new IDocumentationContext with
+                member _.Collector = collector
+                member _.DocumentationSourceDirectory = mockFileSystem.DirectoryInfo.New("/docs")
+                member _.Git = GitCheckoutInformation.Unavailable
+                member _.ReadFileSystem = mockFileSystem
+                member _.WriteFileSystem = mockFileSystem
+                member _.ConfigurationPath = mockFileSystem.FileInfo.New("mock_docset.yml")
+            }
+        let redirectFileParser = RedirectFile(mockRedirectsFile, docContext)
+        redirectFileParser.Redirects
+
+    // Helper to create FetchedCrossLinks
+    let private createFetchedCrossLinks (redirectsYamlSnippet: string) (linksData: IDictionary<string, LinkMetadata>) repoName =
+        let collector = TestDiagnosticsCollector() :> IDiagnosticsCollector
+        let redirectRules = parseRedirectsYaml redirectsYamlSnippet collector
+
+        if collector.Errors > 0 then
+            failwithf $"Failed to parse redirects YAML: %A{collector}"
+
+        let linkReference =
+            LinkReference(
+              Origin = GitCheckoutInformation.Unavailable,
+              UrlPathPrefix = null,
+              Links = Dictionary(linksData),
+              CrossLinks = Array.empty<string>,
+              Redirects = redirectRules
+            )
+
+        let declaredRepos = HashSet<string>()
+        declaredRepos.Add(repoName) |> ignore
+
+        FetchedCrossLinks(
+            DeclaredRepositories = declaredRepos,
+            LinkReferences = FrozenDictionary.ToFrozenDictionary(dict [repoName, linkReference]),
+            FromConfiguration = true,
+            LinkIndexEntries = FrozenDictionary<string, LinkRegistryEntry>.Empty
+        )
+
+    let private redirectsYaml = """
+  # test scenario 1
+  'testing/redirects/multi-topic-page-1-old.md':
+    to: 'testing/redirects/multi-topic-page-1-new-anchorless.md'
+    anchors: { "!": null }
+    many:
+      - to: 'testing/redirects/multi-topic-page-1-new-topic-a-subpage.md'
+        anchors: {'topic-a-intro': null, 'topic-a-details': 'details-anchor'}
+      - to: 'testing/redirects/multi-topic-page-1-new-topic-b-subpage.md'
+        anchors: {'topic-b-main': 'main-anchor'}
+      - to: 'testing/redirects/multi-topic-page-1-old.md'
+        anchors: {'topic-c-main': 'topic-c-main'}
+  # test scenario 2
+  'testing/redirects/multi-topic-page-2-old.md':
+    to: 'testing/redirects/multi-topic-page-2-old.md'
+    anchors: {} # This means pass through any anchor for the default 'to'
+    many:
+      - to: 'testing/redirects/multi-topic-page-2-new-topic-a-subpage.md'
+        anchors: {'topic-a-intro': 'introduction', 'topic-a-details': null}
+      - to: 'testing/redirects/multi-topic-page-2-new-topic-b-subpage.md'
+        anchors: {'topic-b-main': 'summary', 'topic-b-config': null}
+"""
+
+    let private mockLinksData =
+        dict [
+            ("testing/redirects/multi-topic-page-1-new-anchorless.md", LinkMetadata(Anchors = null, Hidden = false))
+            ("testing/redirects/multi-topic-page-1-new-topic-a-subpage.md", LinkMetadata(Anchors = [| "details-anchor"; "introduction" |], Hidden = false))
+            ("testing/redirects/multi-topic-page-1-new-topic-b-subpage.md", LinkMetadata(Anchors = [| "main-anchor" |], Hidden = false))
+            ("testing/redirects/multi-topic-page-1-old.md", LinkMetadata(Anchors = [| "topic-c-main"; "unmatched-anchor" |], Hidden = false))
+            ("testing/redirects/multi-topic-page-2-old.md", LinkMetadata(Anchors = [| "unmatched-anchor"; "topic-c-main"; "topic-a-intro"; "topic-a-details"; "topic-b-main"; "topic-b-config" |], Hidden = false))
+            ("testing/redirects/multi-topic-page-2-new-topic-a-subpage.md", LinkMetadata(Anchors = [| "introduction"; "summary" |], Hidden = false))
+            ("testing/redirects/multi-topic-page-2-new-topic-b-subpage.md", LinkMetadata(Anchors = [| "summary" |], Hidden = false))
+        ] :> IDictionary<_,_>
+
+
+    let private repoName = "docs-content"
+    let private fetchedLinks = createFetchedCrossLinks redirectsYaml mockLinksData repoName
+    let private uriResolver = IsolatedBuildEnvironmentUriResolver() :> IUriEnvironmentResolver
+    let private baseExpectedUrl = $"https://docs-v3-preview.elastic.dev/elastic/{repoName}/tree/main"
+
+    let resolvesTo (inputUrl: string) (expectedPathWithOptionalAnchor: string) =
+        let mutable errors = List.empty
+        let errorEmitter (msg: string) = errors <- msg :: errors
+        let inputUri = Uri(inputUrl)
+        let mutable resolvedUri : Uri = Unchecked.defaultof<Uri>
+
+        let success = CrossLinkResolver.TryResolve(Action<_>(errorEmitter), fetchedLinks, uriResolver, inputUri, &resolvedUri)
+
+        if not errors.IsEmpty then
+            failwithf $"Resolution for '%s{inputUrl}' failed with errors: %A{errors}"
+
+        test <@ success @>
+        match box resolvedUri with
+        | null -> failwithf $"Resolved URI was null for input '%s{inputUrl}' even though TryResolve returned true."
+        | _ ->
+            let expectedFullUrl = baseExpectedUrl + expectedPathWithOptionalAnchor
+            test <@ resolvedUri.ToString() = expectedFullUrl @>
diff --git a/tests/authoring/Inline/CrossLinkRedirectAnchors.fs b/tests/authoring/Inline/CrossLinkRedirectAnchors.fs
@@ -0,0 +1,61 @@
+// Licensed to Elasticsearch B.V under one or more agreements.
+// Elasticsearch B.V licenses this file to you under the Apache 2.0 License.
+// See the LICENSE file in the project root for more information
+
+module ``inline elements``.``complex anchors``
+
+open Xunit
+open authoring.CrossLinkResolverAssertions
+
+type ``scenario 1``() =
+
+    [<Fact>]
+    let ``No anchor redirects to new-anchorless page``() =
+        resolvesTo ("docs-content://testing/redirects/multi-topic-page-1-old.md") "/testing/redirects/multi-topic-page-1-new-anchorless"
+
+    [<Fact>]
+    let ``Unmatched anchor for '!' rule redirects to new-anchorless page and drops anchor``() =
+        resolvesTo ("docs-content://testing/redirects/multi-topic-page-1-old.md#unmatched-anchor") "/testing/redirects/multi-topic-page-1-new-anchorless"
+
+    [<Fact>]
+    let ``topic-a-intro redirects to topic-a-subpage and drops anchor (null target)``() =
+        resolvesTo ("docs-content://testing/redirects/multi-topic-page-1-old.md#topic-a-intro") "/testing/redirects/multi-topic-page-1-new-topic-a-subpage"
+
+    [<Fact>]
+    let ``topic-a-details redirects to topic-a-subpage with new anchor``() =
+        resolvesTo ("docs-content://testing/redirects/multi-topic-page-1-old.md#topic-a-details") "/testing/redirects/multi-topic-page-1-new-topic-a-subpage#details-anchor"
+
+    [<Fact>]
+    let ``topic-b-main redirects to topic-b-subpage with new anchor``() =
+        resolvesTo ("docs-content://testing/redirects/multi-topic-page-1-old.md#topic-b-main") "/testing/redirects/multi-topic-page-1-new-topic-b-subpage#main-anchor"
+
+    [<Fact>]
+    let ``topic-c-main redirects to old page and keeps anchor``() =
+        resolvesTo ("docs-content://testing/redirects/multi-topic-page-1-old.md#topic-c-main") "/testing/redirects/multi-topic-page-1-old#topic-c-main"
+
+
+type ``Scenario 2``() =
+
+    [<Fact>]
+    let ``No anchor redirects to old page (self)``() =
+        resolvesTo ("docs-content://testing/redirects/multi-topic-page-2-old.md") "/testing/redirects/multi-topic-page-2-old"
+
+    [<Fact>]
+    let ``Unmatched anchor for '{}' rule redirects to old page (self) and keeps anchor``() =
+        resolvesTo ("docs-content://testing/redirects/multi-topic-page-2-old.md#unmatched-anchor") "/testing/redirects/multi-topic-page-2-old#unmatched-anchor"
+
+    [<Fact>]
+    let ``topic-a-intro redirects to topic-a-subpage with new anchor``() =
+        resolvesTo ("docs-content://testing/redirects/multi-topic-page-2-old.md#topic-a-intro") "/testing/redirects/multi-topic-page-2-new-topic-a-subpage#introduction"
+
+    [<Fact>]
+    let ``topic-a-details redirects to topic-a-subpage and drops anchor (null target)``() =
+        resolvesTo ("docs-content://testing/redirects/multi-topic-page-2-old.md#topic-a-details") "/testing/redirects/multi-topic-page-2-new-topic-a-subpage"
+
+    [<Fact>]
+    let ``topic-b-main redirects to topic-b-subpage with new anchor``() =
+        resolvesTo ("docs-content://testing/redirects/multi-topic-page-2-old.md#topic-b-main") "/testing/redirects/multi-topic-page-2-new-topic-b-subpage#summary"
+
+    [<Fact>]
+    let ``topic-b-config redirects to topic-b-subpage and drops anchor (null target)``() =
+        resolvesTo ("docs-content://testing/redirects/multi-topic-page-2-old.md#topic-b-config") "/testing/redirects/multi-topic-page-2-new-topic-b-subpage"
diff --git a/tests/authoring/Inline/CrossLinks.fs b/tests/authoring/Inline/CrossLinks.fs
@@ -38,7 +38,7 @@ type ``error when using wrong scheme`` () =
     [<Fact>]
     let ``error on bad scheme`` () =
         markdown
-        |> hasError "'docs-x' is not declared as valid cross link repository in docset.yml under cross_links"
+        |> hasError "'docs-x' was not found in the cross link index"
 
     [<Fact>]
     let ``has no warning`` () = markdown |> hasNoWarnings
@@ -89,14 +89,14 @@ type ``link to repository that does not resolve yet`` () =
     let ``validate HTML`` () =
         markdown |> convertsToHtml """
             <p><a
-                href="https://docs-v3-preview.elastic.dev/elastic/elasticsearch/tree/main/">
+                href="elasticsearch:/index.md">
                 Elasticsearch Documentation
                 </a>
             </p>
         """
 
     [<Fact>]
-    let ``has no errors`` () = markdown |> hasNoErrors
+    let ``error when not found in links.json`` () = markdown |> hasError("'elasticsearch' was not found in the cross link index")
 
     [<Fact>]
     let ``has no warning`` () = markdown |> hasNoWarnings
@@ -133,14 +133,14 @@ type ``link to repository that does not resolve yet using double slashes`` () =
     let ``validate HTML`` () =
         markdown |> convertsToHtml """
             <p><a
-                href="https://docs-v3-preview.elastic.dev/elastic/elasticsearch/tree/main/">
+                href="elasticsearch://index.md">
                 Elasticsearch Documentation
                 </a>
             </p>
         """
 
     [<Fact>]
-    let ``has no errors`` () = markdown |> hasNoErrors
+    let ``error when not found in links.json`` () = markdown |> hasError("'elasticsearch' was not found in the cross link index")
 
     [<Fact>]
     let ``has no warning`` () = markdown |> hasNoWarnings
diff --git a/tests/authoring/authoring.fsproj b/tests/authoring/authoring.fsproj
@@ -38,6 +38,7 @@
     <Compile Include="Framework\HtmlAssertions.fs"/>
     <Compile Include="Framework\ErrorCollectorAssertions.fs"/>
     <Compile Include="Framework\MarkdownDocumentAssertions.fs"/>
+    <Compile Include="Framework\CrossLinkResolverAssertions.fs" />
     <Compile Include="Inline\Substitutions.fs"/>
     <Compile Include="Inline\InlineAnchors.fs"/>
     <Compile Include="Inline\Comments.fs"/>
@@ -47,6 +48,7 @@
     <Compile Include="Inline\CrossLinks.fs" />
     <Compile Include="Inline\CrossLinksRedirects.fs" />
     <Compile Include="Inline\RelativeLinks.fs" />
+    <Compile Include="Inline\CrossLinkRedirectAnchors.fs" />
     <Compile Include="Container\DefinitionLists.fs"/>
     <Compile Include="Generator\LinkReferenceFile.fs"/>
     <Compile Include="Blocks\CodeBlocks\CodeBlocks.fs"/>

Original file line number	Diff line number	Diff line change
`@@ -52,7 +52,7 @@ public static bool TryResolve(`
`52`	`52`
`53`	`53`	`if (!fetchedCrossLinks.LinkReferences.TryGetValue(crossLinkUri.Scheme, out var sourceLinkReference))`
`54`	`54`	`{`
`55`		`- errorEmitter($"'{crossLinkUri.Scheme}' was not found in the cross link index.");`
	`55`	`+ errorEmitter($"'{crossLinkUri.Scheme}' was not found in the cross link index");`
`56`	`56`	`return false;`
`57`	`57`	`}`
`58`	`58`