Create a process that runs migrations and then shuts down (#482)

Author: Jason S

lib/ecto/migrator.ex

@@ -77,6 +77,21 @@ defmodule Ecto.Migrator do
       $ bin/my_app eval "MyApp.Release.migrate"
       $ bin/my_app eval "MyApp.Release.rollback(MyApp.Repo, 20190417140000)"
 
+  ## Example: Running migrations on application startup
+
+  Add the following to the top of your application children spec:
+
+      {Ecto.Migrator,
+       repos: Application.fetch_env!(:my_app, :ecto_repos),
+       skip: System.get_env("SKIP_MIGRATIONS") == "true"}
+
+  To skip migrations you can also pass `skip: true` or as in the example 
+  set the environment variable `SKIP_MIGRATIONS` to a truthy value.
+
+  To roll back you'd do it normally: 
+
+      $ mix ecto.rollback
+
   """
 
   require Logger
@@ -451,6 +466,38 @@ defmodule Ecto.Migrator do
     |> collect_migrations(directories)
     |> Enum.sort_by(fn {_, version, _} -> version end)
   end
+  
+  use GenServer
+
+  @doc """
+  Runs migrations as part of your supervision tree.
+
+  ## Options
+
+    * `:repos` - Required option to tell the migrator which Repo's to 
+      migrate. Example: `repos: [MyApp.Repo]`
+    * `:skip` - Option to skip migrations.
+      Defaults to `false`.
+  """
+  def start_link(opts) do
+    GenServer.start_link(__MODULE__, opts, name: __MODULE__)
+  end
+
+  @impl true
+  def init(opts) do
+    repos = Keyword.fetch!(opts, :repos)
+
+    skip? = Keyword.get(opts, :skip, false)
+    migrator = Keyword.get(opts, :migrator, &Ecto.Migrator.run/3)
+
+    unless skip? do
+      for repo <- repos do
+        {:ok, _, _} = with_repo(repo, &migrator.(&1, :up, all: true))
+      end
+    end
+
+    :ignore
+  end
 
   defp collect_migrations(versions, migration_source) do
     ups_with_file =

test/ecto/migrator_test.exs

@@ -861,5 +861,35 @@ defmodule Ecto.MigratorTest do
     end
   end
 
+  describe "gen_server" do 
+    test "runs the migrator with repos config" do
+      migrator = fn repo, _, _ ->
+        assert TestRepo == repo
+        []
+      end
+
+      assert {:ok, :undefined} = start_supervised({Ecto.Migrator, [repos: [TestRepo], migrator: migrator]})
+    end
+
+    test "skip is set" do
+      migrator = fn repo, _, _ ->
+        refute TestRepo == repo
+        []
+      end
+
+      assert {:ok, :undefined} = start_supervised({Ecto.Migrator, [repos: [TestRepo], migrator: migrator, skip: true]})
+    end
+
+    test "migrations fail" do
+      migrator = fn repo, _, _ ->
+        assert TestRepo == repo
+        raise "boom"
+        []
+      end
+
+      assert {:error, {{%RuntimeError{message: "boom"}, _}, _}} = start_supervised({Ecto.Migrator, [repos: [TestRepo], migrator: migrator]})
+    end
+  end
+
   defp last_command(), do: Process.get(:last_command)
 end