Add depends_on/0 callback to Task behaviour

Author: am-kantox

lib/mix/lib/mix/task.compiler.ex

@@ -175,7 +175,18 @@ defmodule Mix.Task.Compiler do
   """
   @callback clean() :: any
 
-  @optional_callbacks clean: 0, manifests: 0, diagnostics: 0
+  @doc """
+  A compiler task (as well as a regular task) may return a list of
+  dependent tasks if they are to be re-enabled when this task gets
+  re-enabled.
+
+  For instance, if task `"foo"` executes `"bar"` with
+  `Mix.Task.run("bar")` from `run/1`, this method should be
+  implemented to return `["bar"]`.
+  """
+  @callback depends_on :: [binary]
+
+  @optional_callbacks clean: 0, manifests: 0, depends_on: 0
 
   @doc """
   Adds a callback that runs after a given compiler.

lib/mix/lib/mix/task.ex

@@ -131,6 +131,18 @@ defmodule Mix.Task do
   """
   @callback run(command_line_args :: [binary]) :: any
 
+  @doc """
+  A task may return a list of dependent tasks
+  if they are to be re-enabled when this task gets re-enabled.
+
+  For instance, if task `"foo"` executes `"bar"` with
+  `Mix.Task.run("bar")` from `run/1`, this method should be implemented
+  to return `["bar"]`.
+  """
+  @callback depends_on :: [binary]
+
+  @optional_callbacks depends_on: 0
+
   @doc false
   defmacro __using__(_opts) do
     quote do
@@ -613,10 +625,25 @@ defmodule Mix.Task do
   child projects.
   """
   @spec reenable(task_name) :: :ok
-  def reenable(task) when is_binary(task) or is_atom(task) do
-    task = to_string(task)
+  def reenable(task) when is_atom(task) do
+    task |> to_string() |> reenable()
+  end
+
+  def reenable(task) when is_binary(task) do
+    module = get(task)
+
+    # it’s safe against `no_return` because otherwise `run/1`
+    #   would be `no_return` as well
+    if module && function_exported?(module, :depends_on, 0) do
+      Enum.each(module.depends_on(), &reenable/1)
+    end
+
+    do_reenable(task, module)
+  end
+
+  defp do_reenable(task, module) do
     proj = Mix.Project.get()
-    recursive = (module = get(task)) && recursive(module)
+    recursive = module && recursive(module)
 
     Mix.TasksServer.delete_many([{:task, task, proj}, {:alias, task, proj}])
 

lib/mix/lib/mix/tasks/compile.all.ex

@@ -89,6 +89,14 @@ defmodule Mix.Tasks.Compile.All do
     result
   end
 
+  @impl true
+  @doc false
+  def depends_on do
+    Mix.Project.config()
+    |> Mix.Tasks.Compile.compilers()
+    |> Enum.map(&"compile.#{&1}")
+  end
+
   defp compile([], _, status, diagnostics) do
     {status, diagnostics}
   end

lib/mix/lib/mix/tasks/compile.ex

@@ -174,6 +174,11 @@ defmodule Mix.Tasks.Compile do
     {res, diagnostics}
   end
 
+  @impl true
+  def depends_on do
+    ["loadpaths", "compile.all"]
+  end
+
   defp format(expression, args) do
     :io_lib.format(expression, args) |> IO.iodata_to_binary()
   end

lib/mix/test/mix/tasks/compile.elixir_test.exs

@@ -855,6 +855,33 @@ defmodule Mix.Tasks.Compile.ElixirTest do
     end)
   end
 
+  test "recompiles newly created files" do
+    in_fixture("no_mixfile", fn ->
+      Mix.Project.push(MixTest.Case.Sample)
+
+      assert Mix.Tasks.Compile.Elixir.run(["--verbose"]) == {:ok, []}
+      assert_received {:mix_shell, :info, ["Compiled lib/a.ex"]}
+      assert_received {:mix_shell, :info, ["Compiled lib/b.ex"]}
+
+      Mix.shell().flush()
+
+      File.write!("lib/z.ex", """
+      defmodule Z do
+        def ok, do: :ok
+      end
+      """)
+
+      Mix.Task.reenable("compile.elixir")
+      assert {:ok, []} = Mix.Tasks.Compile.Elixir.run(["--verbose"])
+
+      assert_received {:mix_shell, :info, ["Compiled lib/z.ex"]}
+      refute_received {:mix_shell, :info, ["Compiled lib/a.ex"]}
+      refute_received {:mix_shell, :info, ["Compiled lib/b.ex"]}
+
+      assert File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+    end)
+  end
+
   test "recompiles dependent changed modules" do
     in_fixture("no_mixfile", fn ->
       Mix.Project.push(MixTest.Case.Sample)

lib/mix/test/mix/tasks/compile_test.exs

@@ -112,6 +112,24 @@ defmodule Mix.Tasks.CompileTest do
     end)
   end
 
+  test "recompiles newly created files" do
+    in_fixture("no_mixfile", fn ->
+      assert Mix.Tasks.Compile.run(["--verbose"]) == {:ok, []}
+      Mix.shell().flush()
+
+      File.write!("lib/z.ex", """
+      defmodule Z do
+        def ok, do: :ok
+      end
+      """)
+
+      Mix.Task.reenable("compile")
+      assert {:ok, []} = Mix.Task.run("compile")
+
+      assert File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+    end)
+  end
+
   test "recompiles app cache if manifest changes" do
     in_fixture("no_mixfile", fn ->
       Mix.Tasks.Compile.run(["--force"])