Add System.tmp_dir, System.cwd and System.user_home

Author: José Valim

CHANGELOG.md

@@ -17,6 +17,7 @@
   * [Mix] `mix escriptize` only generates escript if necessary and accept `--force` and `--no-compile` as options
   * [Path] Introduce `Path` module to hold filesystem paths related functions
   * [String] Add `String.capitalize` and `String.slice`
+  * [System] Add `System.tmp_dir`, `System.cwd` and `System.user_home`
 
 * bug fix
   * [Kernel] `import` with `only` accepts functions starting with underscore

lib/elixir/lib/path.ex

@@ -1,7 +1,4 @@
 defmodule Path do
-  defexception NoHomeError,
-    message: "could not find the user home, please set the HOME environment variable"
-
   @moduledoc """
   This module provides conveniences for manipulating or
   retrieving filesystem paths.
@@ -322,35 +319,19 @@ defmodule Path do
 
   ## Helpers
 
-  defp get_home do
-    get_unix_home || get_windows_home || raise NoHomeError
-  end
-
-  defp get_unix_home do
-    System.get_env("HOME")
-  end
-
-  defp get_windows_home do
-    System.get_env("USERPROFILE") || (
-      hd = System.get_env("HOMEDRIVE")
-      hp = System.get_env("HOMEPATH")
-      hd && hp && hd <> hp
-    )
-  end
-
-  defp get_cwd(path) when is_list(path), do: File.cwd! |> binary_to_list
-  defp get_cwd(_), do: File.cwd!
+  defp get_cwd(path) when is_list(path), do: System.cwd! |> binary_to_list
+  defp get_cwd(_), do: System.cwd!
 
   # Normalize the given path by expanding "..", "." and "~".
 
   defp normalize(path), do: do_normalize(FN.split(path))
 
   defp do_normalize(["~"|t]) do
-    do_normalize t, [get_home]
+    do_normalize t, [System.user_home!]
   end
 
   defp do_normalize(['~'|t]) do
-    do_normalize t, [get_home |> binary_to_list]
+    do_normalize t, [System.user_home! |> binary_to_list]
   end
 
   defp do_normalize(t) do

lib/elixir/lib/system.ex

@@ -1,4 +1,13 @@
 defmodule System do
+  defexception NoHomeError,
+    message: "could not find the user home, please set the HOME environment variable"
+
+  defexception NoTmpDirError,
+    message: "could not get a writable temporary directory, please set the TMPDIR environment variable"
+
+  defexception NoAccessCwdError,
+    message: "could not get a current working directory, the current location is not accessible"
+
   @moduledoc """
   The System module provides access to some variables used or
   maintained by the VM and to functions that interact strongly
@@ -44,6 +53,94 @@ defmodule System do
     :gen_server.call(:elixir_code_server, :argv)
   end
 
+  @doc """
+  Returns the current working directory or nil if one
+  is not available.
+  """
+  def cwd do
+    case :file.get_cwd do
+      { :ok, list } -> list_to_binary(list)
+      _ -> nil
+    end
+  end
+
+  @doc """
+  Returns the current working directory or raises `System.NoAccessCwdError`.
+  """
+  def cwd! do
+    cwd || raise NoAccessCwdError
+  end
+
+  @doc """
+  Returns the user home (platform independent).
+  It returns nil if no user home is set.
+  """
+  def user_home do
+    get_unix_home || get_windows_home
+  end
+
+  @doc """
+  Same as `user_home` but raises `System.NoHomeError`
+  instead of returning nil if no user home is set.
+  """
+  def user_home! do
+    user_home || raise NoHomeError
+  end
+
+  defp get_unix_home do
+    get_env("HOME")
+  end
+
+  defp get_windows_home do
+    get_env("USERPROFILE") || (
+      hd = get_env("HOMEDRIVE")
+      hp = get_env("HOMEPATH")
+      hd && hp && hd <> hp
+    )
+  end
+
+  @doc %B"""
+  Returns a writable temporary directory.
+  It searches for directories in the following order:
+
+  1. The directory named by the TMPDIR environment variable
+  2. The directory named by the TEMP environment variable
+  3. The directory named by the TMP environment variable
+  4. `C:\TMP` on Windows or `/tmp` on Unix
+  5.  As a last resort, the current working directory
+
+  Returns nil if none of the above are writable.
+  """
+  def tmp_dir do
+    write_env_tmp_dir('TMPDIR') ||
+      write_env_tmp_dir('TEMP')  ||
+      write_env_tmp_dir('TMP') ||
+      write_tmp_dir("/tmp")     ||
+      ((cwd = cwd()) && write_tmp_dir(cwd))
+  end
+
+  @doc """
+  Same as `tmp_dir` but raises `System.NoTmpDirError`
+  instead of returning nil if no temp dir is set.
+  """
+  def tmp_dir! do
+    tmp_dir || raise NoTmpDirError
+  end
+
+  defp write_env_tmp_dir(env) do
+    case System.get_env(env) do
+      nil -> nil
+      tmp -> write_tmp_dir tmp
+    end
+  end
+
+  defp write_tmp_dir(dir) do
+    case File.stat(dir) do
+      { :ok, File.Stat[type: :directory, access: access] } when access in [:read_write, :write] -> dir
+      { :error, _ } -> nil
+    end
+  end
+
   @doc """
   Registers a function that will be invoked
   at the end of program execution. Useful for

lib/elixir/test/elixir/system_test.exs

@@ -12,6 +12,21 @@ defmodule SystemTest do
     assert not nil?(System.build_info[:date])
   end
 
+  test :cwd do
+    assert is_binary System.cwd
+    assert is_binary System.cwd!
+  end
+
+  test :user_home do
+    assert is_binary System.user_home
+    assert is_binary System.user_home!
+  end
+
+  test :tmp_dir do
+    assert is_binary System.tmp_dir
+    assert is_binary System.tmp_dir!
+  end
+
   test :argv do
     list = elixir('-e "IO.inspect System.argv" -- -o opt arg1 arg2 --long-opt 10')
     { args, _ } = Code.eval list, []