Start new records API

Author: José Valim

lib/elixir/lib/record.ex

@@ -1,24 +1,78 @@
 defmodule Record do
   @doc """
-  Extract record information from an Erlang file.
+  Extracts record information from an Erlang file.
 
   Returns the fields as a list of tuples.
 
   ## Examples
 
-      Record.extract(:file_info, from_lib: "kernel/include/file.hrl")
-      #=> [size: :undefined, type: :undefined, access: :undefined, atime: :undefined,
-           mtime: :undefined, ctime: :undefined, mode: :undefined, links: :undefined,
-           major_device: :undefined, minor_device: :undefined, inode: :undefined,
-           uid: :undefined, gid: :undefined]
-
-      defrecord FileInfo, Record.extract(:file_info, from_lib: "kernel/include/file.hrl")
+      iex> Record.extract(:file_info, from_lib: "kernel/include/file.hrl")
+      [size: :undefined, type: :undefined, access: :undefined, atime: :undefined,
+       mtime: :undefined, ctime: :undefined, mode: :undefined, links: :undefined,
+       major_device: :undefined, minor_device: :undefined, inode: :undefined,
+       uid: :undefined, gid: :undefined]
 
   """
   def extract(name, opts) do
     Record.Extractor.extract(name, opts)
   end
 
+  @doc """
+  Checks if the given `data` is a record of `kind`.
+
+  This is implemented as a macro so it can be used in guard clauses.
+
+  ## Examples
+
+      iex> Record.record?({ User, "jose", 27 }, User)
+      true
+
+  """
+  defmacro record?(data, kind) do
+    case __CALLER__.in_guard? do
+      true ->
+        quote do
+          is_tuple(unquote(data)) and tuple_size(unquote(data)) > 0
+            and :erlang.element(1, unquote(data)) == unquote(kind)
+        end
+      false ->
+        quote do
+          result = unquote(data)
+          is_tuple(result) and tuple_size(result) > 0
+            and :erlang.element(1, result) == unquote(kind)
+        end
+    end
+  end
+
+  @doc """
+  Checks if the given `data` is a record.
+
+  This is implemented as a macro so it can be used in guard clauses.
+
+  ## Examples
+
+      iex> Record.record?({ User, "jose", 27 })
+      true
+      iex> Record.record?(13)
+      false
+
+  """
+  defmacro record?(data) do
+    case __CALLER__.in_guard? do
+      true ->
+        quote do
+          is_tuple(unquote(data)) and tuple_size(unquote(data)) > 0
+            and is_atom(:erlang.element(1, unquote(data)))
+        end
+      false ->
+        quote do
+          result = unquote(data)
+          is_tuple(result) and tuple_size(result) > 0
+            and is_atom(:erlang.element(1, result))
+        end
+    end
+  end
+
   @doc false
   def defmacros(name, values, env, tag \\ nil) do
     Record.Deprecated.defmacros(name, values, env, tag)
@@ -33,4 +87,4 @@ defmodule Record do
   def deffunctions(values, env) do
     Record.Deprecated.deffunctions(values, env)
   end
-end
+end

lib/elixir/test/doc_test.exs

@@ -24,6 +24,7 @@ defmodule KernelTest do
   doctest Path
   doctest Protocol.Consolidation
   doctest Range
+  doctest Record
   doctest Regex
   doctest Stream
   doctest String

lib/elixir/test/elixir/record_test.exs

@@ -0,0 +1,43 @@
+Code.require_file "test_helper.exs", __DIR__
+
+defmodule RecordTest do
+  use ExUnit.Case, async: true
+
+  require Record
+
+  test "extract/2 extracts information from an Erlang file" do
+    assert Record.extract(:file_info, from_lib: "kernel/include/file.hrl") ==
+           [size: :undefined, type: :undefined, access: :undefined, atime: :undefined,
+            mtime: :undefined, ctime: :undefined, mode: :undefined, links: :undefined,
+            major_device: :undefined, minor_device: :undefined, inode: :undefined,
+            uid: :undefined, gid: :undefined]
+  end
+
+  test "extract/2 handles nested records too" do
+    namespace = Record.extract(:xmlElement, from_lib: "xmerl/include/xmerl.hrl")[:namespace]
+    assert is_tuple(namespace)
+    assert elem(namespace, 0) == :xmlNamespace
+  end
+
+  # We need indirection to avoid warnings
+  defp record?(data, kind) do
+    Record.record?(data, kind)
+  end
+
+  test "record?/2" do
+    assert record?({ User, "jose", 27 }, User)
+    refute record?({ User, "jose", 27 }, Author)
+    refute record?(13, Author)
+  end
+
+  # We need indirection to avoid warnings
+  defp record?(data) do
+    Record.record?(data)
+  end
+
+  test "record?/1" do
+    assert record?({ User, "jose", 27 })
+    refute record?({ "jose", 27 })
+    refute record?(13)
+  end
+end