Add :migrate_call_parens_on_pipe formatter option

Author: sabiwara

lib/elixir/lib/code.ex

@@ -696,6 +696,13 @@ defmodule Code do
       modifiers, where `<<foo::custom_type>>` becomes `<<foo::custom_type()>>`.
       Defaults to the value of the `:migrate` option. This option changes the AST.
 
+    * `:migrate_call_parens_on_pipe` (since v1.19.0) - when `true`,
+      formats local calls on the right-hand side of the pipe operator to always
+      include parentheses, for example `foo |> bar` becomes `foo |> bar()`.
+      Parentheses are always added for qualified calls like `foo |> Bar.bar`
+      disregarding of this option.
+      Defaults to the value of the `:migrate` option. This option changes the AST.
+
     * `:migrate_charlists_as_sigils` (since v1.18.0) - when `true`,
       formats charlists as [`~c`](`Kernel.sigil_c/2`) sigils, for example
       `'foo'` becomes `~c"foo"`.

lib/elixir/lib/code/formatter.ex

@@ -191,6 +191,7 @@ defmodule Code.Formatter do
     sigils = Keyword.get(opts, :sigils, [])
     migrate = Keyword.get(opts, :migrate, false)
     migrate_bitstring_modifiers = Keyword.get(opts, :migrate_bitstring_modifiers, migrate)
+    migrate_call_parens_on_pipe = Keyword.get(opts, :migrate_call_parens_on_pipe, migrate)
     migrate_charlists_as_sigils = Keyword.get(opts, :migrate_charlists_as_sigils, migrate)
     migrate_unless = Keyword.get(opts, :migrate_unless, migrate)
     syntax_colors = Keyword.get(opts, :syntax_colors, [])
@@ -218,6 +219,7 @@ defmodule Code.Formatter do
       sigils: sigils,
       file: file,
       migrate_bitstring_modifiers: migrate_bitstring_modifiers,
+      migrate_call_parens_on_pipe: migrate_call_parens_on_pipe,
       migrate_charlists_as_sigils: migrate_charlists_as_sigils,
       migrate_unless: migrate_unless,
       inspect_opts: %Inspect.Opts{syntax_colors: syntax_colors}
@@ -487,7 +489,16 @@ defmodule Code.Formatter do
     binary_op_to_algebra(:in, "not in", meta, left, right, context, state)
   end
 
-  # disable migrate_unless within defmacro
+  # disable migrate_call_parens_on_pipe within defmacro
+  defp quoted_to_algebra(
+         {atom, _, [{:|>, _, _}, _]} = ast,
+         context,
+         %{migrate_call_parens_on_pipe: true} = state
+       )
+       when atom in [:defmacro, :defmacrop] do
+    quoted_to_algebra(ast, context, %{state | migrate_call_parens_on_pipe: false})
+  end
+
   defp quoted_to_algebra(
          {atom, _, [{:unless, _, _}, _]} = ast,
          context,
@@ -832,6 +843,20 @@ defmodule Code.Formatter do
     {wrap_in_parens(doc), state}
   end
 
+  defp binary_operand_to_algebra(
+         {var, meta, atom},
+         context,
+         %{migrate_call_parens_on_pipe: true} = state,
+         :|>,
+         _parent_info,
+         :right,
+         _nesting
+       )
+       when is_atom(var) and is_atom(atom) do
+    operand = {var, meta, []}
+    quoted_to_algebra(operand, context, state)
+  end
+
   defp binary_operand_to_algebra(operand, context, state, parent_op, parent_info, side, nesting) do
     {parent_assoc, parent_prec} = parent_info
 

lib/elixir/test/elixir/code_formatter/migration_test.exs

@@ -27,6 +27,24 @@ defmodule Code.Formatter.MigrationTest do
     end
   end
 
+  describe "migrate_call_parens_on_pipe: true" do
+    @opts [migrate_call_parens_on_pipe: true]
+
+    test "adds parentheses on the right operand" do
+      assert_format "x |> y", "x |> y()", @opts
+      assert_format "x |> y |> z", "x |> y() |> z()", @opts
+    end
+
+    test "does nothing within defmacro" do
+      assert_same "defmacro left |> right, do: ...", @opts
+    end
+
+    test "does nothing without the migrate_unless option" do
+      assert_same "x |> y"
+      assert_same "x |> y |> z"
+    end
+  end
+
   describe "migrate_charlists_as_sigils: true" do
     @opts [migrate_charlists_as_sigils: true]
 
@@ -281,6 +299,14 @@ defmodule Code.Formatter.MigrationTest do
       assert_format "<<foo::binary()>>", "<<foo::binary>>", migrate: true
     end
 
+    test "enables :migrate_call_parens_on_pipe" do
+      bad = "x |> y"
+
+      good = "x |> y()"
+
+      assert_format bad, good, migrate: true
+    end
+
     test "enables :migrate_charlists_as_sigils" do
       assert_format ~S['abc'], ~S[~c"abc"], migrate: true
     end