Support :config and :system_env in Mix.install/2

Closes #11250.

Author: josevalim

lib/mix/lib/mix.ex

@@ -563,13 +563,38 @@ defmodule Mix do
     * `:elixir` - if set, ensures the current Elixir version matches the given
       version requirement (Default: `nil`)
 
+    * `:config` (since v1.13.0) - a keyword list of keyword lists with application
+      configuration to be set before the apps loaded. The configuration is part of
+      the `Mix.install/2` cache, so different configurations will lead to different
+      apps
+
+    * `:system_env` (since v1.13.0) - a map of system environment variable names as
+      binary keys and their respective values as binaries. The system environment is
+      made part of the `Mix.install/2` cache, so different configurations will lead
+      to different apps
+
   ## Examples
 
+  To install `:decimal` and `:jason`:
+
       Mix.install([
         :decimal,
         {:jason, "~> 1.0"}
       ])
 
+  Using `:nx`, `:exla`, and configure the underlying applications
+  and environment variables:
+
+      Mix.install(
+        [:nx, :exla],
+        config: [
+          nx: [default_backend: EXLA]
+        ],
+        system_env: [
+          {"XLA_TARGET", "cuda111"}
+        ]
+      )
+
   ## Limitations
 
   There is one limitation to `Mix.install/2`, which is actually an Elixir
@@ -636,29 +661,39 @@ defmodule Mix do
           other
       end)
 
+    config = Keyword.get(opts, :config, [])
+    system_env = Keyword.get(opts, :system_env, [])
+
+    id =
+      {deps, config, system_env}
+      |> :erlang.term_to_binary()
+      |> :erlang.md5()
+      |> Base.encode16(case: :lower)
+
     force? = !!opts[:force]
 
     case Mix.State.get(:installed) do
       nil ->
         :ok
 
-      ^deps when not force? ->
+      ^id when not force? ->
         :ok
 
       _ ->
         Mix.raise("Mix.install/2 can only be called with the same dependencies in the given VM")
     end
 
+    Application.put_all_env(config, persistent: true)
+    System.put_env(system_env)
+
     installs_root =
-      System.get_env("MIX_INSTALL_DIR") ||
-        Path.join(Mix.Utils.mix_cache(), "installs")
+      System.get_env("MIX_INSTALL_DIR") || Path.join(Mix.Utils.mix_cache(), "installs")
 
-    id = deps |> :erlang.term_to_binary() |> :erlang.md5() |> Base.encode16(case: :lower)
     version = "elixir-#{System.version()}-erts-#{:erlang.system_info(:version)}"
     dir = Path.join([installs_root, version, id])
 
     if opts[:verbose] do
-      Mix.shell().info("using #{dir}")
+      Mix.shell().info("Mix.install/2 using #{dir}")
     end
 
     if force? do
@@ -701,7 +736,7 @@ defmodule Mix do
         Application.ensure_all_started(app)
       end
 
-      Mix.State.put(:installed, deps)
+      Mix.State.put(:installed, id)
       :ok
     after
       Mix.ProjectStack.pop()

lib/mix/test/mix_test.exs

@@ -47,7 +47,7 @@ defmodule MixTest do
       assert apply(InstallTest, :hello, []) == :world
     end
 
-    test "call with same deps in the same VM", %{tmp_dir: tmp_dir} do
+    test "works with same deps twice", %{tmp_dir: tmp_dir} do
       Mix.install([
         {:install_test, path: Path.join(tmp_dir, "install_test")}
       ])
@@ -57,7 +57,7 @@ defmodule MixTest do
       ])
     end
 
-    test "can't call with Elixir version mismatch", %{tmp_dir: tmp_dir} do
+    test "errors on Elixir version mismatch", %{tmp_dir: tmp_dir} do
       assert_raise Mix.Error, ~r"Mix.install/2 declared it supports only Elixir ~> 2.0", fn ->
         Mix.install(
           [
@@ -68,7 +68,7 @@ defmodule MixTest do
       end
     end
 
-    test "can't call with same deps and force", %{tmp_dir: tmp_dir} do
+    test "errors with same deps and force", %{tmp_dir: tmp_dir} do
       Mix.install([
         {:install_test, path: Path.join(tmp_dir, "install_test")}
       ])
@@ -83,7 +83,7 @@ defmodule MixTest do
       end
     end
 
-    test "can't call with different deps in the same VM", %{tmp_dir: tmp_dir} do
+    test "errors with different deps in the same VM", %{tmp_dir: tmp_dir} do
       Mix.install([
         {:install_test, path: Path.join(tmp_dir, "install_test")}
       ])
@@ -121,6 +121,22 @@ defmodule MixTest do
       refute Protocol.consolidated?(InstallTest.Protocol)
     end
 
+    test "config and system_env", %{tmp_dir: tmp_dir} do
+      Mix.install(
+        [
+          {:install_test, path: Path.join(tmp_dir, "install_test")}
+        ],
+        config: [unknown_app: [foo: :bar]],
+        system_env: %{"MIX_INSTALL_FOO" => "BAR"}
+      )
+
+      assert Application.fetch_env!(:unknown_app, :foo) == :bar
+      assert System.fetch_env!("MIX_INSTALL_FOO") == "BAR"
+    after
+      System.delete_env("MIX_INSTALL_FOO")
+      Application.delete_env(:unknown_app, :foo, persistent: true)
+    end
+
     defp test_project(%{tmp_dir: tmp_dir}) do
       path = :code.get_path()