Add Task.start/1 and Task.start/3

Author: José Valim

lib/elixir/lib/task.ex

@@ -119,6 +119,30 @@ defmodule Task do
     Task.Supervised.start_link(get_info(self), {mod, fun, args})
   end
 
+  @doc """
+  Starts a task.
+
+  This is only used when the task is used for side-effects
+  (i.e. no interest in its return result) and it should not
+  be linked to the current process.
+  """
+  @spec start(fun) :: {:ok, pid}
+  def start(fun) do
+    start(:erlang, :apply, [fun, []])
+  end
+
+  @doc """
+  Starts a task.
+
+  This is only used when the task is used for side-effects
+  (i.e. no interest in its return result) and it should not
+  be linked to the current process.
+  """
+  @spec start(module, atom, [term]) :: {:ok, pid}
+  def start(mod, fun, args) do
+    Task.Supervised.start(get_info(self), {mod, fun, args})
+  end
+
   @doc """
   Starts a task that can be awaited on.
 

lib/elixir/lib/task/supervised.ex

@@ -1,6 +1,10 @@
 defmodule Task.Supervised do
   @moduledoc false
 
+  def start(info, fun) do
+    {:ok, :proc_lib.spawn(__MODULE__, :noreply, [info, fun])}
+  end
+
   def start_link(info, fun) do
     {:ok, :proc_lib.spawn_link(__MODULE__, :noreply, [info, fun])}
   end

lib/elixir/test/elixir/task_test.exs

@@ -61,6 +61,37 @@ defmodule TaskTest do
     assert_receive :done
   end
 
+  test "start/1" do
+    parent = self()
+    fun = fn -> wait_and_send(parent, :done) end
+    {:ok, pid} = Task.start(fun)
+
+    {:links, links} = Process.info(self, :links)
+    refute pid in links
+
+    receive do: (:ready -> :ok)
+
+    {:name, fun_name} = :erlang.fun_info(fun, :name)
+    assert {__MODULE__, fun_name, 0} === :proc_lib.translate_initial_call(pid)
+
+    send pid, true
+    assert_receive :done
+  end
+
+  test "start/3" do
+    {:ok, pid} = Task.start(__MODULE__, :wait_and_send, [self(), :done])
+
+    {:links, links} = Process.info(self, :links)
+    refute pid in links
+
+    receive do: (:ready -> :ok)
+
+    assert {__MODULE__, :wait_and_send, 2} === :proc_lib.translate_initial_call(pid)
+
+    send pid, true
+    assert_receive :done
+  end
+
   test "start_link/1" do
     parent = self()
     fun = fn -> wait_and_send(parent, :done) end