Consider mix alises in umbrella projects (#12576)

Previously, when an alias existed within an umbrella child, running this
from the umbrella root would result in an error that the mix task was
not found.

This commit checks the aliases of the children, and if any of the
children have the alias then it will be executed in the children. Any
children that do not have the alias will be skipped.

Author: Gazler

lib/mix/lib/mix/task.ex

@@ -367,6 +367,14 @@ defmodule Mix.Task do
       alias && Mix.TasksServer.run({:alias, task, proj}) ->
         run_alias(List.wrap(alias), args, proj, task, apps, :ok)
 
+      Mix.Project.umbrella?() && umbrella_child_alias?(task) ->
+        Mix.ProjectStack.recur(fn ->
+          recur(
+            fn _ -> Mix.Project.config()[:aliases][String.to_atom(task)] && run(task, args) end,
+            apps
+          )
+        end)
+
       !Mix.TasksServer.get({:task, task, proj}) ->
         run_task(proj, task, args, apps)
 
@@ -375,6 +383,18 @@ defmodule Mix.Task do
     end
   end
 
+  defp umbrella_child_alias?(task) do
+    umbrella_deps =
+      Mix.Dep.Umbrella.cached()
+      |> Enum.filter(& &1.opts[:from_umbrella])
+
+    Enum.find(umbrella_deps, fn %Mix.Dep{app: app, opts: opts} ->
+      Mix.Project.in_project(app, opts[:path], [inherit_parent_config_files: true], fn _ ->
+        !!Mix.Project.config()[:aliases][String.to_atom(task)]
+      end)
+    end)
+  end
+
   defp run_task(proj, task, args, apps) do
     # 1. If the task is available, we run it.
     # 2. Otherwise we compile and load dependencies

lib/mix/test/fixtures/umbrella_test/apps/bar/mix.exs

@@ -8,7 +8,8 @@ defmodule Bar.MixProject do
       # Choose something besides *_test.exs so that these test files don't
       # get accidentally swept up into the actual Mix test suite.
       test_pattern: "*_tests.exs",
-      test_coverage: [ignore_modules: [Bar, ~r/Ignore/]]
+      test_coverage: [ignore_modules: [Bar, ~r/Ignore/]],
+      aliases: [mytask: ["cmd echo bar_running"]]
     ]
   end
 end

lib/mix/test/fixtures/umbrella_test/apps/foo/mix.exs

@@ -7,7 +7,8 @@ defmodule Foo.MixProject do
       version: "0.1.0",
       # Choose something besides *_test.exs so that these test files don't
       # get accidentally swept up into the actual Mix test suite.
-      test_pattern: "*_tests.exs"
+      test_pattern: "*_tests.exs",
+      aliases: [mytask: ["cmd echo foo_running"]]
     ]
   end
 end

lib/mix/test/mix/task_test.exs

@@ -160,6 +160,40 @@ defmodule Mix.TaskTest do
     end)
   end
 
+  test "aliases considered for umbrella apps" do
+    in_fixture("umbrella_test", fn ->
+      Mix.Project.in_project(:umbrella, ".", fn _ ->
+        File.mkdir_p!("apps/baz/lib/")
+
+        File.write!("apps/baz/mix.exs", """
+        defmodule Baz.MixProject do
+          use Mix.Project
+
+          def project do
+            [
+              app: :baz,
+              version: "0.1.0"
+            ]
+          end
+        end
+        """)
+
+        File.write!("apps/baz/lib/baz.ex", """
+        defmodule Baz do
+          def hello do
+            :world
+          end
+        end
+        """)
+
+        assert [:ok, nil, :ok] = Mix.Task.run("mytask")
+
+        assert_received {:mix_shell, :run, ["foo_running" <> _]}
+        assert_received {:mix_shell, :run, ["bar_running" <> _]}
+      end)
+    end)
+  end
+
   test "reenable/1 for recursive inside umbrella child" do
     in_fixture("umbrella_dep/deps/umbrella", fn ->
       Mix.Project.in_project(:umbrella, ".", fn _ ->