Add Macro.postwalker/1

Author: josevalim

CHANGELOG.md

@@ -149,7 +149,7 @@ Finally, the `Code` module has also been augmented with two functions: `Code.str
   * [Keyword] Add `Keyword.validate/2`
   * [Keyword] Implement `Keyword.filter/2` and `Keyword.map/2`
   * [List] Add `List.keyfind!/3`
-  * [Macro] Add `Macro.prewalker/1`
+  * [Macro] Add `Macro.prewalker/1` and `Macro.postwalker/1`
   * [Macro.Env] Add the following reflection functions: `required?/2`, `lookup_import/2`, `fetch_alias/2`, and `fetch_macro_alias/2`
   * [Map] Implement `Map.filter/2` and `Map.map/2`
   * [Module] Support `:nillify_clauses` in `Module.get_definition/3`

lib/elixir/lib/macro.ex

@@ -773,6 +773,67 @@ defmodule Macro do
     prewalker(tail, fun.(head, acc), fun)
   end
 
+  @doc """
+  Returns an enumerable that traverses the  `ast` in depth-first,
+  post-order traversal.
+
+  ## Examples
+
+      iex> ast = quote do: foo(1, "abc")
+      iex> Enum.map(Macro.postwalker(ast), & &1)
+      [1, "abc", {:foo, [], [1, "abc"]}]
+
+  """
+  def postwalker(ast) do
+    &postwalker([ast], make_ref(), &1, &2)
+  end
+
+  defp postwalker(_buffer, _ref, {:halt, acc}, _fun) do
+    {:halted, acc}
+  end
+
+  defp postwalker(buffer, ref, {:suspend, acc}, fun) do
+    {:suspended, acc, &postwalker(buffer, ref, &1, fun)}
+  end
+
+  defp postwalker([], _ref, {:cont, acc}, _fun) do
+    {:done, acc}
+  end
+
+  defp postwalker([{ref, head} | tail], ref, {:cont, acc}, fun) do
+    postwalker(tail, ref, fun.(head, acc), fun)
+  end
+
+  defp postwalker([{left, right} = node | tail], ref, {:cont, acc}, fun) do
+    postwalker([right, {ref, node} | tail], ref, fun.(left, acc), fun)
+  end
+
+  defp postwalker([{left, meta, right} = node | tail], ref, {:cont, acc}, fun)
+       when is_atom(left) and is_list(meta) do
+    if is_atom(right) do
+      postwalker(tail, ref, fun.(node, acc), fun)
+    else
+      postwalker(right ++ [{ref, node} | tail], ref, {:cont, acc}, fun)
+    end
+  end
+
+  defp postwalker([{left, meta, right} = node | tail], ref, cont_acc, fun)
+       when is_list(meta) do
+    if is_atom(right) do
+      postwalker([left, {ref, node} | tail], ref, cont_acc, fun)
+    else
+      postwalker([left | right] ++ [{ref, node} | tail], ref, cont_acc, fun)
+    end
+  end
+
+  defp postwalker([list | tail], ref, cont_acc, fun) when is_list(list) do
+    postwalker(list ++ [{ref, list} | tail], ref, cont_acc, fun)
+  end
+
+  defp postwalker([head | tail], ref, {:cont, acc}, fun) do
+    postwalker(tail, ref, fun.(head, acc), fun)
+  end
+
   @doc ~S"""
   Unescapes the given chars.
 

lib/elixir/test/elixir/macro_test.exs

@@ -1024,13 +1024,41 @@ defmodule MacroTest do
              {:five, [], MacroTest}
            ]
 
+    assert map == ast |> Macro.prewalk([], &{&1, [&1 | &2]}) |> elem(1) |> Enum.reverse()
     assert Enum.zip(Macro.prewalker(ast), []) == Enum.zip(map, [])
 
     for i <- 0..(length(map) + 1) do
       assert Enum.take(Macro.prewalker(ast), i) == Enum.take(map, i)
     end
   end
 
+  test "postwalker/1" do
+    ast = quote do: :mod.foo(bar({1, 2}), [3, 4, five])
+    map = Enum.map(Macro.postwalker(ast), & &1)
+
+    assert map == [
+             :mod,
+             :foo,
+             {:., [], [:mod, :foo]},
+             1,
+             2,
+             {1, 2},
+             {:bar, [], [{1, 2}]},
+             3,
+             4,
+             {:five, [], MacroTest},
+             [3, 4, {:five, [], MacroTest}],
+             {{:., [], [:mod, :foo]}, [], [{:bar, [], [{1, 2}]}, [3, 4, {:five, [], MacroTest}]]}
+           ]
+
+    assert map == ast |> Macro.postwalk([], &{&1, [&1 | &2]}) |> elem(1) |> Enum.reverse()
+    assert Enum.zip(Macro.postwalker(ast), []) == Enum.zip(map, [])
+
+    for i <- 0..(length(map) + 1) do
+      assert Enum.take(Macro.postwalker(ast), i) == Enum.take(map, i)
+    end
+  end
+
   test "operator?/2" do
     assert Macro.operator?(:+, 2)
     assert Macro.operator?(:+, 1)