Add Mix.Task.Compiler.run/2

Author: josevalim

lib/iex/lib/iex/helpers.ex

@@ -175,7 +175,7 @@ defmodule IEx.Helpers do
 
   defp reenable_tasks(config) do
     compilers = config[:compilers] || Mix.compilers()
-    Mix.Task.Compiler.reenable(compilers: compilers)
+    Mix.Task.Compiler.reenable(compilers)
   end
 
   @doc """

lib/mix/lib/mix/task.compiler.ex

@@ -268,9 +268,39 @@ defmodule Mix.Task.Compiler do
     end)
   end
 
-  # Normalize the compiler result to a diagnostic tuple.
-  @doc false
-  def normalize(result, name) do
+  @doc """
+  Runs the given list of compilers with the given arguments.
+
+  It returns a `{status, diagnostics}` tuple. If a compiler
+  errors, following compilers do not run.
+  """
+  @doc since: "1.19.0"
+  def run(compilers, args) do
+    run(compilers, args, :noop, [])
+  end
+
+  defp run([], _, status, diagnostics) do
+    {status, diagnostics}
+  end
+
+  defp run([compiler | rest], args, status, diagnostics) do
+    {new_status, new_diagnostics} = run_compiler(compiler, args)
+    diagnostics = diagnostics ++ new_diagnostics
+
+    case new_status do
+      :error -> {:error, diagnostics}
+      :ok -> run(rest, args, :ok, diagnostics)
+      :noop -> run(rest, args, status, diagnostics)
+    end
+  end
+
+  defp run_compiler(compiler, args) do
+    result = normalize(Mix.Task.run("compile.#{compiler}", args), compiler)
+    Enum.reduce(Mix.ProjectStack.pop_after_compiler(compiler), result, & &1.(&2))
+  end
+
+  # Normalize the compiler result to a diagnostic tuple
+  defp normalize(result, name) do
     case result do
       {status, diagnostics} when status in [:ok, :noop, :error] and is_list(diagnostics) ->
         {status, diagnostics}
@@ -328,10 +358,10 @@ defmodule Mix.Task.Compiler do
   re-enables `"compile"` and `"compile.all"`.
   """
   @doc since: "1.19.0"
-  @spec reenable(compilers: compilers) :: :ok when compilers: :all | [atom()]
-  def reenable(opts \\ []) do
+  @spec reenable(compilers) :: :ok when compilers: :all | [atom()]
+  def reenable(compilers \\ :all) do
     compilers =
-      case Keyword.get(opts, :compilers, :all) do
+      case compilers do
         :all -> Mix.Task.Compiler.compilers()
         list when is_list(list) -> list
       end

lib/mix/lib/mix/tasks/compile.all.ex

@@ -62,7 +62,7 @@ defmodule Mix.Tasks.Compile.All do
     compile_path = to_charlist(Mix.Project.compile_path())
     Code.prepend_path(compile_path)
 
-    result =
+    {status, diagnostics} =
       if "--no-compile" in args do
         Mix.Task.reenable("compile.all")
         {:noop, []}
@@ -72,9 +72,13 @@ defmodule Mix.Tasks.Compile.All do
 
         config
         |> Mix.Task.Compiler.compilers()
-        |> compile(args, :noop, [])
+        |> Mix.Task.Compiler.run(args)
       end
 
+    if status == :error and "--return-errors" not in args do
+      exit({:shutdown, 1})
+    end
+
     if app_cache do
       Mix.AppLoader.write_cache(app_cache, Map.new(loaded_modules))
     end
@@ -90,38 +94,9 @@ defmodule Mix.Tasks.Compile.All do
       end
     end
 
-    result
-  end
-
-  defp compile([], _, status, diagnostics) do
     {status, diagnostics}
   end
 
-  defp compile([compiler | rest], args, status, diagnostics) do
-    {new_status, new_diagnostics} = run_compiler(compiler, args)
-    diagnostics = diagnostics ++ new_diagnostics
-
-    case new_status do
-      :error ->
-        if "--return-errors" not in args do
-          exit({:shutdown, 1})
-        end
-
-        {:error, diagnostics}
-
-      :ok ->
-        compile(rest, args, :ok, diagnostics)
-
-      :noop ->
-        compile(rest, args, status, diagnostics)
-    end
-  end
-
-  defp run_compiler(compiler, args) do
-    result = Mix.Task.Compiler.normalize(Mix.Task.run("compile.#{compiler}", args), compiler)
-    Enum.reduce(Mix.ProjectStack.pop_after_compiler(compiler), result, & &1.(&2))
-  end
-
   def project_apps(config) do
     project = Mix.Project.get!()
 

lib/mix/lib/mix/tasks/compile.ex

@@ -140,7 +140,12 @@ defmodule Mix.Tasks.Compile do
     {res, diagnostics} =
       Mix.Task.run("compile.all", args)
       |> List.wrap()
-      |> Enum.map(&Mix.Task.Compiler.normalize(&1, :all))
+      |> Enum.map(
+        &case &1 do
+          :noop -> {:noop, []}
+          {status, diagnostics} -> {status, diagnostics}
+        end
+      )
       |> Enum.reduce({:noop, []}, &merge_diagnostics/2)
 
     config = Mix.Project.config()

lib/mix/test/mix/tasks/compile_test.exs

@@ -133,11 +133,11 @@ defmodule Mix.Tasks.CompileTest do
       assert {:noop, []} = Mix.Task.run("compile")
       refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z1.beam")
 
-      assert :ok = Mix.Task.Compiler.reenable(compilers: [])
+      assert :ok = Mix.Task.Compiler.reenable([])
       assert {:noop, []} = Mix.Task.run("compile")
       refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z1.beam")
 
-      assert :ok = Mix.Task.Compiler.reenable(compilers: ["erlang"])
+      assert :ok = Mix.Task.Compiler.reenable(["erlang"])
       assert {:noop, []} = Mix.Task.run("compile")
       refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z1.beam")
 
@@ -151,11 +151,11 @@ defmodule Mix.Tasks.CompileTest do
       end
       """)
 
-      assert :ok = Mix.Task.Compiler.reenable(compilers: [:erlang])
+      assert :ok = Mix.Task.Compiler.reenable([:erlang])
       assert {:noop, []} = Mix.Task.run("compile")
       refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z2.beam")
 
-      assert :ok = Mix.Task.Compiler.reenable(compilers: [:elixir])
+      assert :ok = Mix.Task.Compiler.reenable([:elixir])
       assert {:ok, []} = Mix.Task.run(:compile)
       assert File.regular?("_build/dev/lib/sample/ebin/Elixir.Z2.beam")
     end)