Add Kernel.struct/2

Author: José Valim

lib/elixir/lib/enum.ex

@@ -1211,6 +1211,10 @@ defmodule Enum do
     :lists.foldl(fun, acc, collection)
   end
 
+  def reduce(collection, acc, fun) when is_map(collection) do
+    :maps.fold(fn k, v, acc -> fun.({ k, v }, acc) end, acc, collection)
+  end
+
   def reduce(collection, acc, fun) do
     Enumerable.reduce(collection, { :cont, acc },
                       fn x, acc -> { :cont, fun.(x, acc) } end) |> elem(1)

lib/elixir/lib/kernel.ex

@@ -1479,6 +1479,55 @@ defmodule Kernel do
     :erlang.setelement(index + 1, tuple, value)
   end
 
+  @doc """
+  Creates and updates structs.
+
+  The struct argument may be an atom (which defines `defstruct`)
+  or a struct itself. The second argument is any Enumerable that
+  emits two-item tuples (key-value) during enumeration.
+
+  If one of the keys in the Enumerable does not exist in the struct,
+  they are automatically discarded.
+
+  This function is useful for dynamically creating and updating
+  structs.
+
+  ## Example
+
+      defmodule User do
+        defstruct name: "jose"
+      end
+
+      struct(User)
+      #=> %User{name: "jose"}
+
+      opts = [name: "eric"]
+      user = struct(User, opts)
+      #=> %User{name: "eric"}
+
+      struct(user, unknown: "value")
+      #=> %User{name: "eric"}
+
+  """
+  def struct(struct, kv \\ [])
+
+  def struct(struct, []) when is_atom(struct) do
+    apply(struct, :__struct__, [])
+  end
+
+  def struct(struct, kv) when is_atom(struct) do
+    struct(apply(struct, :__struct__, []), kv)
+  end
+
+  def struct(%{ __struct__: _ } = struct, kv) do
+    Enum.reduce(kv, struct, fn { k, v }, acc ->
+      case :maps.is_key(k, acc) do
+        true  -> :maps.put(k, v, acc)
+        false -> acc
+      end
+    end)
+  end
+
   ## Implemented in Elixir
 
   @doc """
@@ -3197,7 +3246,7 @@ defmodule Kernel do
   end
 
   @doc """
-  Defines the current module as a struct.
+  Defines a struct for the current module.
 
   A struct is a tagged map that allows developers to provide
   default values for keys, tags to be used in polymorphic
@@ -3208,6 +3257,9 @@ defmodule Kernel do
   structs field. This macro is a convenience for doing such
   function and a type `t` in one pass.
 
+  For more information about structs, please check
+  `Kernel.SpecialForms.%/2`.
+
   ## Examples
 
       defmodule MyRange do

lib/elixir/lib/kernel/special_forms.ex

@@ -148,7 +148,9 @@ defmodule Kernel.SpecialForms do
   argument is a struct, failing with `BadStructError` otherwise.
 
   Check `Kernel.defprotocol/2` for more information on how structs
-  can be used with protocols for polymorphic dispatch.
+  can be used with protocols for polymorphic dispatch. Also,
+  see `Kernel.struct/2` for examples on how to create and update
+  structs dynamically.
   """
   defmacro unquote(:%)(struct, map)
 

lib/elixir/test/elixir/kernel_test.exs

@@ -157,6 +157,20 @@ defmodule KernelTest do
     refute binding() == [x: 2]
   end
 
+  defmodule User do
+    defstruct name: "jose"
+  end
+
+  test :struct do
+    assert struct(User) == %User{name: "josé"}
+
+    user = struct(User, name: "eric")
+    assert user == %User{ name: "eric" }
+
+    assert struct(user, unknown: "key") == user
+    assert struct(user, name: "jose") == %User{ name: "josé" }
+  end
+
   defmodule Conversions do
     use ExUnit.Case, async: true