Merge pull request #1300 from jdrexler/issue-1285

Added chgrp!, chown!, and chmod! to module File

Author: José Valim

lib/elixir/lib/file.ex

@@ -1019,6 +1019,66 @@ defmodule File do
     end
   end
 
+  @doc """
+  Changes the unix file `mode` for a given `file`. 
+  Returns `:ok` on success, or `{:error, reason}` 
+  on failure.  
+  """
+  def chmod(file, mode) do
+    F.change_mode(file, mode)
+  end
+
+  @doc """
+  Same as `chmod/2`, but raises an exception in case of failure. Otherwise `:ok`.
+  """
+  def chmod!(file, mode) do
+    case chmod(file, mode) do
+      :ok -> :ok
+      { :error, reason } ->
+        raise File.Error, reason: reason, action: "change mode for", path: :unicode.characters_to_binary(file)
+    end
+  end
+
+  @doc """
+  Changes the user group given by the group id `gid` 
+  for a given `file`. Returns `:ok` on success, or 
+  `{:error, reason}` on failure.  
+  """
+  def chgrp(file, gid) do
+    F.change_group(file, gid)
+  end
+
+  @doc """
+  Same as `chgrp/2`, but raises an exception in case of failure. Otherwise `:ok`.
+  """
+  def chgrp!(file, gid) do
+    case chgrp(file, gid) do
+      :ok -> :ok
+      { :error, reason } ->
+        raise File.Error, reason: reason, action: "change group for", path: :unicode.characters_to_binary(file)
+    end
+  end
+
+  @doc """
+  Changes the owner given by the user id `gid` 
+  for a given `file`. Returns `:ok` on success, 
+  or `{:error, reason}` on failure.  
+  """
+  def chown(file, uid) do 
+    F.change_owner(file, uid)
+  end
+
+  @doc """
+  Same as `chown/2`, but raises an exception in case of failure. Otherwise `:ok`.
+  """
+  def chown!(file, gid) do
+    case chown(file, gid) do
+      :ok -> :ok
+      { :error, reason } ->
+        raise File.Error, reason: reason, action: "change owner for", path: :unicode.characters_to_binary(file)
+    end
+  end
+
   ## Helpers
 
   defp open_defaults([:charlist|t], _add_binary) do

lib/elixir/test/elixir/file_test.exs

@@ -1115,6 +1115,92 @@ defmodule FileTest do
     end
   end
 
+  test :chmod_with_success do
+    fixture = tmp_path("tmp_test.txt")
+
+    File.touch(fixture)
+    try do
+      assert File.chmod(fixture, 0100666) == :ok
+      stat = File.stat!(fixture)
+      assert stat.mode == 0100666
+
+      assert File.chmod(fixture, 0100777) == :ok
+      stat = File.stat!(fixture)
+      assert stat.mode == 0100777
+    after
+      File.rm(fixture)
+    end
+  end
+
+  test :chmod_with_success! do
+    fixture = tmp_path("tmp_test.txt")
+
+    File.touch(fixture)
+    try do
+      assert File.chmod!(fixture, 0100666) == :ok
+      stat = File.stat!(fixture)
+      assert stat.mode == 0100666
+
+      assert File.chmod!(fixture, 0100777) == :ok
+      stat = File.stat!(fixture)
+      assert stat.mode == 0100777
+    after
+      File.rm(fixture)
+    end
+  end
+
+  test :chmod_with_failue do
+    fixture = tmp_path("tmp_test.txt")
+    File.rm(fixture)
+
+    assert File.chmod(fixture, 0100777) == {:error,:enoent}
+  end
+
+  test :chmod_with_failue! do
+    fixture = tmp_path("tmp_test.txt")
+    File.rm(fixture)
+
+    message = %r"could not change mode for #{escape fixture}: no such file or directory"
+    assert_raise File.Error, message, fn ->
+      File.chmod!(fixture, 0100777)
+    end
+  end
+
+  test :chgrp_with_failue do
+    fixture = tmp_path("tmp_test.txt")
+    File.rm(fixture)
+
+    assert File.chgrp(fixture, 1) == {:error,:enoent}
+  end
+
+  test :chgrp_with_failue! do
+    fixture = tmp_path("tmp_test.txt")
+    File.rm(fixture)
+
+    message = %r"could not change group for #{escape fixture}: no such file or directory"
+    assert_raise File.Error, message, fn ->
+      File.chgrp!(fixture, 1)
+    end
+  end
+
+  test :chown_with_failue do
+    fixture = tmp_path("tmp_test.txt")
+    File.rm(fixture)
+
+    assert File.chown(fixture, 1) == {:error,:enoent}    
+  end
+
+  test :chown_with_failue! do
+    fixture = tmp_path("tmp_test.txt")
+    File.rm(fixture)
+
+    message = %r"could not change owner for #{escape fixture}: no such file or directory"
+    assert_raise File.Error, message, fn ->
+      File.chown!(fixture, 1)
+    end
+  end
+
+
   defp last_year do
     last_year :calendar.local_time
   end