Type timeouts in receive

Author: josevalim

lib/elixir/lib/module/types/expr.ex

@@ -239,10 +239,16 @@ defmodule Module.Types.Expr do
         {:do, clauses}, context ->
           of_clauses(clauses, stack, context)
 
-        {:after, [{:->, _meta, [head, body]}]}, context ->
-          {_type, context} = of_expr(head, stack, context)
-          {_type, context} = of_expr(body, stack, context)
-          context
+        {:after, [{:->, meta, [[timeout], body]}]}, context ->
+          {timeout_type, context} = of_expr(timeout, stack, context)
+          {_body_type, context} = of_expr(body, stack, context)
+
+          if integer_type?(timeout_type) do
+            context
+          else
+            error = {:badtimeout, timeout_type, timeout, context}
+            error(__MODULE__, error, meta, stack, context)
+          end
       end)
 
     {dynamic(), context}
@@ -530,4 +536,25 @@ defmodule Module.Types.Expr do
         ])
     }
   end
+
+  def format_diagnostic({:badtimeout, type, expr, context}) do
+    traces = collect_traces(expr, context)
+
+    %{
+      details: %{typing_traces: traces},
+      message:
+        IO.iodata_to_binary([
+          """
+          expected "after" timeout given to receive to be an integer:
+
+              #{expr_to_string(expr) |> indent(4)}
+
+          but got type:
+
+              #{to_quoted_string(type) |> indent(4)}
+          """,
+          format_traces(traces)
+        ])
+    }
+  end
 end

lib/elixir/test/elixir/module/types/expr_test.exs

@@ -764,6 +764,32 @@ defmodule Module.Types.ExprTest do
     end
   end
 
+  describe "receive" do
+    test "errors on bad timeout" do
+      assert typeerror!(
+               [x = :timeout],
+               receive do
+               after
+                 x -> :ok
+               end
+             ) == ~l"""
+             expected "after" timeout given to receive to be an integer:
+
+                 x
+
+             but got type:
+
+                 dynamic(:timeout)
+
+             where "x" was given the type:
+
+                 # type: dynamic(:timeout)
+                 # from: types_test.ex:770
+                 x = :timeout
+             """
+    end
+  end
+
   describe "try" do
     test "warns on undefined exceptions" do
       assert typewarn!(